---

Hallo,

ich versuche hier per Makro die Bauteile einer Baugruppe umzubenennen und die Referenzen gleich zu aktualisieren.

Es soll quasi die Funktion: "Rechtsklick im Featuremanager auf das Bauteil > Teil umbenennen" haben.
Welche Methode wäre das? Ein paar habe ich schon versucht (z.B. RenameDocument).

------------------
gruß,
Markus

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Servus,

einfachste Lösung, Datei unter neuen Namen abspeichern und dann die alte Datei löschen. Davor aber abfragen, ob die Datei nicht schreibgeschützt ist. SW setzt dann die Reverenzen in allen offenen Teilen automatisch um.

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Hallo Markus,

das müsste doch so funktionieren:

https://help.solidworks.com/2024/english/api/sldworksapi/rename_components_and_save_assembly_example_vb.htm

Alternativ kann ich mir noch die SaveAs3-Methode vorstellen:

https://help.solidworks.com/2024/english/api/sldworksapi/SolidWorks.Interop.sldworks~SolidWorks.Interop.sldworks.IModelDocExtension~SaveAs3.html

------------------
==========
Gruß
Andreas
==========

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Das Problem beim Umbenennen in der Baugruppe ist, du nimmst da eine eventuelle Zeichnung nicht mit. Wenn du, wie ich bei dir sehe, PDM zur Verfügung hast, kannst du doch einfach die Dateien im PDM umbenennen. Alles einchecken und dann im PDM - Explorer umbenennen.

------------------
"Wir ertrinken in Informationen, aber wir hungern nach Wissen..." John Naisbitt

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Mein Nummerngenerator funktioniert so:

1. Suchen der Zeichnung im Verzeichnis. Da sind String Operationen nötig. Endung wegschneiden, andere Endung ran und suchen.
2. Prüfen ob Zeichnung offen, wenn nein öffnen der Zeichnung.
3. Zeichnung unter neuen Namen speichern.
3. Modell unter neuen Namen speichern.
4. Zeichnung nochmal speichern wegen der Reverenzen
5. War die Zeichnung offen, dann nichts, ansonsten Zeichnung schließen.
6. Prüfen ob alte Zeichnung schreibgeschützt ist, wenn nein löschen
7. Prüfen ob altes Modell schreibgeschützt ist, wenn nein löschen.

Warum ich die Zeichnung als erstes umbenenne, weiß ich nicht mehr. Das hatte einen Grund. Abgeguckt habe ich das in einer Firma mit PDM. Da kam ich erst auf die Idee die Zeichnung mitzunehmen.

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Zitat:

---

Original erstellt von ad_man:
das müsste doch so funktionieren:

https://help.solidworks.com/2024/english/api/sldworksapi/rename_components_and_save_assembly_example_vb.htm

---

Das sieht gut aus. Hat in meinem Test auch geklappt.

@Holger.S

Ich muss das für einen Export machen (also raus aus dem PDM). Es soll ein CustomProperty mit in den Dateinamen. Bei meinem damaligen Versuch mit pack and go bin ich nicht weitergekommen (auch, wenn es hier schon ein ähnliches Makro gab).

------------------
gruß,
Markus

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

So ist übrigens der aktuelle Status.

Funktioniert scheinbar 
Für mein erstes Mal bin ich ganz zufrieden.

Code:

---

Option Explicit

Dim swApp As SldWorks.SldWorks
Dim swModel As SldWorks.ModelDoc2
Dim refSettings As Boolean

Sub main()
' Ändert den Dateinamen von Bauteilen/Baugruppen/Zeichnungen nach bestimmten Properties
' Ausschluss von Dateien, welche nicht den Status Freigegeben haben
' Root-Baugruppe wird aktuell noch nicht umbenannt
' Root-Baugruppe muss offen sein

    Dim swConf As SldWorks.Configuration
    Dim swRootComp As SldWorks.Component2
    Dim bRet As Boolean
    Dim swModelDocExt As SldWorks.ModelDocExtension
    Dim fileerror As Long
    Dim filewarning As Long
    Dim value As Boolean
   
    ' Aktuelle Datei holen
    Set swApp = Application.SldWorks
    Set swModel = swApp.ActiveDoc
   
    ' Liest und Setzt die Einstellung für Externe Referenzen: "Komponentennamen aktualisieren, wenn Dokumente ersetzt werden auf" true
    refSettings = swApp.GetUserPreferenceToggle(swExtRefUpdateCompNames)
    swApp.SetUserPreferenceToggle swExtRefUpdateCompNames, True
   
    ' Wenn kein Model geöffnet ist, nichts tun
    If swModel Is Nothing Then
        MsgBox "Kein Dokument geöffnet!", vbExclamation
        Exit Sub
    End If
   
    ' Root-Komponente des Assemblies als Ausgangspunkt festmachen
    Set swConf = swModel.GetActiveConfiguration
    Set swRootComp = swConf.GetRootComponent3(True)
   
    ' Durch alle Unterbaugruppen
    TraverseComponent swModelDocExt, swRootComp
   
    ' Root-Baugruppe neu aufbauen und mit allen Referenzen speichern
    swModel.ForceRebuild3 (False)
    value = swModel.Save3(swSaveAsOptions_SaveReferenced, fileerror, filewarning)
   
    ' setzt die Einstellung für Externe Referenzen wieder auf den ursprünglichen Wert
    swApp.SetUserPreferenceToggle swExtRefUpdateCompNames, refSettings
   
    Debug.Print ""
    Debug.Print "FERTIG"
   
End Sub

Sub TraverseComponent(swModelDocExt As SldWorks.ModelDocExtension, swComp As SldWorks.Component2)
    Dim bRet As Boolean
    Dim DrawingPath As String
    Dim DrawingPathNew As String
    Dim FileDir As String
    Dim FileNameNew As String
    Dim FilePath As String
    Dim FilePathNew As String
    Dim errorsRename As Long
    Dim i As Long
    Dim Prop_dokumentenstatus As String
    Dim Prop_drawingNumber As String
    Dim Prop_revision As String
    Dim resolvedValOut As String
    Dim swChildComp As SldWorks.Component2
    Dim swChildModel As SldWorks.ModelDoc2
    Dim swChildModelDocExt As SldWorks.ModelDocExtension
    Dim swSelData As SldWorks.SelectData
    Dim swSelMgr As SldWorks.SelectionMgr
    Dim valOut As String
    Dim vChildComp As Variant
    Dim swCustProp As CustomPropertyManager

    vChildComp = swComp.GetChildren
    For i = 0 To UBound(vChildComp)
        Set swChildComp = vChildComp(i)
       

        Set swChildModel = swChildComp.GetModelDoc2
        If Not swChildModel Is Nothing Then
       
            Set swChildModelDocExt = swChildModel.Extension
           
            ' holt sich die benötigten benutzerdefinierten Eigenschaften
            Set swCustProp = swChildModelDocExt.CustomPropertyManager("")
            swCustProp.Get4 "Zeichnungsnummer", False, valOut, resolvedValOut
            Prop_drawingNumber = resolvedValOut
           
            swCustProp.Get4 "Dokumentenstatus", False, valOut, resolvedValOut
            Prop_dokumentenstatus = resolvedValOut
           
            swCustProp.Get4 "Revision", False, valOut, resolvedValOut
            Prop_revision = resolvedValOut
               
            ' Nur Freigegebene Dateien sollen geändert werden.
            If LCase(Trim(Prop_dokumentenstatus)) <> "freigegeben" Then
    '            Debug.Print "Nicht freigegeben, übersprungen: " & Prop_drawingNumber
                GoTo Weiter
            End If
               
            ' Virtuelle Teile überspringen
            If swChildComp.IsVirtual Then
                'Debug.Print "Virtuelles Teil:" & swChildModel.GetPathName
                GoTo Weiter
            End If
           
            ' selectiert die entsprechende Komponente. Notwendig für das Umbenennen mit swModelDocExt.RenameDocument
            Set swSelMgr = swModel.SelectionManager
            Set swSelData = swSelMgr.CreateSelectData
            bRet = swChildComp.Select4(False, swSelData, False)
           
            ' Neuen Dateinamen zusammenbauen
            FilePath = swChildModel.GetPathName
            FileDir = Left(FilePath, InStrRev(FilePath, "\") - 1)
            DrawingPath = FileDir & "\" & Prop_drawingNumber & ".slddrw"
            Debug.Print FilePath
            FileNameNew = Prop_drawingNumber & "." & Prop_revision
    '        Debug.Print FileNameNew
   
            If swChildModel.GetType = swDocPART Then
                FilePathNew = FileDir & "\" & FileNameNew & ".sldprt"
            ElseIf swChildModel.GetType = swDocASSEMBLY Then
                FilePathNew = FileDir & "\" & FileNameNew & ".sldasm"
            End If
           

            ' Umbenennprozess für sldprt/sldasm und slddrw mit Umbiegen der Referenz in der Zeichnung
            Set swModelDocExt = swModel.Extension
            If Not Dir(FilePathNew) <> "" Then
                errorsRename = swModelDocExt.RenameDocument(FileNameNew)
                errorsRename = swApp.ReplaceReferencedDocument(DrawingPath, FilePath, FilePathNew)
                DrawingPathNew = FileDir & "\" & FileNameNew & ".SLDDRW"
                If Dir(DrawingPath) <> "" Then
                    If Not Dir(DrawingPathNew) <> "" Then
                        Name DrawingPath As DrawingPathNew
                    End If
                End If
            End If
           
    '        Debug.Print swChildComp.Name2 & " - " & errorsRename
    '        Debug.Print
        End If
Weiter:
        ' nächster Durchlauf
        TraverseComponent swModelDocExt, swChildComp
    Next i
End Sub

---

vermutlich kommt aber gleich jemand und sagt: Gibts schon 

------------------
gruß,
Markus

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP