---

2024-07-26-001498.jpg

Hallo Zusammen

Ich versuche ein Makro zu schreiben das mir beim Ausschreiben der Zeichnung den Index hinter den Dateiname schreibt.
z.B. ist der Dateiname 1020-Führung, beim PDF hätte ich aber gerne diesen Dateiname 1020-Führung-IDX01, wobei die 01 aus der aktuellen Revision der Dateieigenschaften gelesen wird.

Für folgende Schritte fehlt mir der Ansatz:
1. In den Dateiinformationen - Benutzerdefiniert die Zeile Revision mit dem Wert $PLMPRP:"revision" einzufügen.
wenn ich folgendes Eingebe, gibt es einen Fehler wegen den ""
    Dim strRev As String
    strRev = "$PLMPRP:"revision""

2. Der evaluierte Wert wird ausgelesen und als Index abrufbar, damit er im Dateiname eingefügt werden kann.

Kann mir hier jemand weiterhelfen.

Gruss Markus

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Hallo Markus,

zu deinem Problem mit den Anführungszeichen kannst du dir den String
"zusammenbasteln"

Code:

---

Dim strRev as string
strRev =  "$PLMPRP:" & CHR$(34) & "revision" & CHR$(34)

---

Beim zweiten Punkt verstehe ich nicht, was du machen möchtest.
Evtl. kannst du das ganze Makro mal posten, dann wird es einfacher   

------------------
==========
Gruß
Andreas
==========

[Diese Nachricht wurde von ad_man am 27. Jul. 2024 editiert.]

[Diese Nachricht wurde von ad_man am 27. Jul. 2024 editiert.]

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Hallo Markus,

ev. ist es das was Du suchst

Sub AddProp()
  Dim swApp    As SldWorks.SldWorks
  Dim swmod    As SldWorks.ModelDoc2
  Dim swpropmgr As SldWorks.CustomPropertyManager
  Dim retvalue  As Integer
 
  Set swApp = Application.SldWorks
 
  Set swmod = swApp.ActiveDoc
  If swmod.GetType <> swDocumentTypes_e.swDocDRAWING Then
    MsgBox "Datei ist keine Zeichnung", vbOKOnly, "Meldung"
    Exit Sub
  End If
 
  Set swpropmgr = swmod.Extension.CustomPropertyManager("")
  retvalue = swpropmgr.Add3("Revision", swCustomInfoType_e.swCustomInfoText, "$PLMPRP:" & Chr$(34) & "revision" & Chr$(34), swCustomPropertyAddOption_e.swCustomPropertyDeleteAndAdd)
 
  If retvalue <> 0 Then
    MsgBox "Fehler beim Hinzufügen der Eigenschaft", vbOKOnly, "Meldung"
  End If
End Sub

Function GetIndex() As String
  Dim swApp    As SldWorks.SldWorks
  Dim swmod    As SldWorks.ModelDoc2
  Dim swpropmgr As SldWorks.CustomPropertyManager
  Dim retvalue  As Integer
  Dim Vout      As String
  Dim Vrout    As String
  Dim Vsolved  As Boolean
 
 
  Set swApp = Application.SldWorks
 
  Set swmod = swApp.ActiveDoc
 
  Set swpropmgr = swmod.Extension.CustomPropertyManager("")
 
  retvalue = swpropmgr.Get6("Revision", False, Vout, Vrout, Vsolved, False)
   
  If retvalue <> swCustomInfoGetResult_e.swCustomInfoGetResult_ResolvedValue Then
    MsgBox "Fehler beim Lesen der Eigenschaft", vbOKOnly, "Meldung"
    GetIndex = ""
    Exit Function
  End If
 
  GetIndex = Vrout
End Function

Sub main()
  Dim idx As String
 
  AddProp
 
  idx = GetIndex
End Sub

------------------
Grüße
Heinz

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP