---

Hallo zusammen,

ich bin gerade auf der Suche nach einer Möglichkeit einen von Hand in den Dateieigenschaften eingetragenen Werkstoff zu ersetzen.
Den Wert über Makro zu ändern klappt super. jetzt ist die Schwierigkeit, dass dort nun der Werkstoff aus der SolidworksDatenbank eingetragen werden soll.

Wie kann ich die Werkstoffdatenbank und daraus einen bestimmten Werkstoff ansprechen und einen Werkstoff zuweisen?
im Anschluss soll natürlich das Gewicht/die Dichte über den Werkstoff ermittelt werden...

Habt ihr da eine Idee. ich glaube, dass ich da gerade für die Suche nicht die richtigen Worte gefunden Hatte. hab nämlich nichts gefunden.

Ich danke euch vielmals für eure Hilfe!! :-)

Vielen Dank

Gruß Pete

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Hallo Pete

Das Material kannst du mit SetMaterialPropertyName2 Method (IPartDoc) zuweisen.

Code:

---

bRet = swModel.SetMaterialPropertyName2(vConfNameArr(i), "c:\SWX-Material\MaterialDB.sldmat", "Stahl")

---

Gegebenenfalls musst du die Benutzerdefinierten/Konfigurationsspezifischen Eigenschafen auf  "SW-Material@Teilename.sldprt" ändern.

Code:

---

swCustProp.Add3 "Material", swCustomInfoText, Chr(34) + "SW-Material" & "@" & swModel.GetTitle & ".SLDPRT" & Chr(34), 1

---

Gruss Andreas

------------------
21 ist nur die halbe Antwort.

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Moin,

das hat ja schon mal super funktioniert.

Musste es nur einmal umschreiben um einen Erfolg zu sehen.

Wie kann ich denn die Werkstoffelemente die in der Materialdatenbank stehen in ein Array schreiben?

bis jetzt sieht es so aus

Code:

---

If Prop = "Material" Or Prop = "Werkstoff" Then
       
        PropNameNeu = "Werkstoff"
        ProPTexT1 = Chr(34) & "SW-Material" & "@" & ModelDoc.GetTitle & Chr(34)
               
        bRet = ModelDoc.SetMaterialPropertyName2(ActConfName, "Materials_Solidworks", "1.0037 (S235JR)")

---

Danke und Gruß

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Hallo zusammen,

wisst Ihr, wie man den momentan gesetzten Werkstoff im Strukturbaum per Makro auslesen kann?

Danke schonmal :-)

Gruß Pete

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Hallo Pete

das macht man mit GetMaterialPropertyName2 Method (IPartDoc)

Code:

---

Option Explicit

Sub main()

    Dim swApp As SldWorks.SldWorks
    Dim swModel As SldWorks.ModelDoc2
    Dim swPart As SldWorks.PartDoc
    Dim dbs As Variant
    Dim sMatName As String
    Dim sMatDB As String

    Dim swConfigMgr As SldWorks.ConfigurationManager
    Dim vConfName As Variant
    Dim vConfParam As Variant
    Dim vConfValue As Variant
    Dim i As Long
    Dim j As Long
    Dim bRet As Boolean
   
   
    Set swApp = Application.SldWorks
    Set swModel = swApp.ActiveDoc
    Set swConfigMgr = swModel.ConfigurationManager
    Set swPart = swModel
   
    Debug.Print "File = " & swModel.GetPathName
   
    dbs = swApp.GetMaterialDatabases
    vConfName = swModel.GetConfigurationNames
       
    For i = 0 To UBound(vConfName)
        bRet = swConfigMgr.GetConfigurationParams(vConfName(i), vConfParam, vConfValue)
       
        Debug.Assert bRet
        Debug.Print "  Configuration = " & vConfName(i)
       
        sMatName = swPart.GetMaterialPropertyName2(vConfName(i), sMatDB)
       

        Debug.Print "  Material = " & sMatName
       
        For j = 0 To UBound(dbs)
            If StrComp(Left(Right(dbs(j), Len(sMatDB) + 7), Len(sMatDB)), sMatDB) = 0 Then
                Debug.Print "  Material Database = " & dbs(j)
                Exit For
            End If
        Next j

    Next i
   
End Sub

---

Gruss Andreas

------------------
21 ist nur die halbe Antwort.

[Diese Nachricht wurde von HenryV am 15. Feb. 2023 editiert.]

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP