---

So, wie versprochen lerne und lerne ich.

erster selbst geschriebener code, fast ohne hin und herkopieren, nur die Hilfe und ich 

Nun zu meinem Problem:

Ich möchte Step Dateien in sldprt "umwandeln". Die Step wird geöffnet, ausgebessert, gespeicher aber nicht geschlossen. Bei den letzten Sätzen (in dick) möchte er irgendwas Dimensioniert haben(Fehler91), ich hab nur nicht verstanden woŽs da hängt.

Code:

---

Sub main()

Dim swApp                  As SldWorks.SldWorks
Dim swPart                  As SldWorks.PartDoc
Dim swModel                As SldWorks.ModelDoc2
Dim swModelDocExt          As SldWorks.ModelDocExtension
Dim swImportStepData        As SldWorks.ImportStepData
Dim status                  As Boolean
Dim Errors                  As Long
Errors = 0
Dim Warnings                As Long
Warnings = 0
Dim stepFileName            As String
Dim FileName                As String
Dim strOrdnerName          As String
Dim strName                As String
Dim longstatus              As Long, longwarnings As Long
Dim varsplit                As Variant
Dim part                    As Object
Dim Titel                  As String
Dim model                  As Object

varsplit = Split(strName, ".")

strOrdnerName = "C:\Zwischenordner\Test\test\"
strName = Dir(strOrdnerName & "*.stp")

    Do While strName <> ""
        stepFileName = strOrdnerName & strName
            If stepFileName = strOrdnerName Then
    Exit Do
            End If
       
        Set swModel = swPart
        Set swApp = Application.SldWorks
   
            'Importinformationen holen
            Set swImportStepData = swApp.GetImportFileData(stepFileName)
           
            'Wenn ImportStepData::MapConfigurationData nicht gesetzt ist,dann standardmäßig die Umgebungseinstellung
            'swImportStepConfigData; andernfalls, überschreibe
            'swImportStepConfigData mit ImportStepData::MapConfigurationData
            swImportStepData.MapConfigurationData = True
           
            'Importieren der Step-Datei
            Set swPart = swApp.LoadFile4(stepFileName, "r", swImportStepData, Errors)
            Set swModel = swPart
            Set swModelDocExt = swModel.Extension
           
            'Importdiagnose Starten und versuche alle Fehler zu korrigieren
            Errors = swPart.ImportDiagnosis(True, False, True, 0)
            Set part = swApp.ActiveDoc
            varsplit = Split(strName, ".")
            Debug.Print varsplit(0)
            endname = varsplit(0) & ".sldprt"
           
            'speichern
            longstatus = part.SaveAs3(endname, 0, 2)
     
            Debug.Print (endname & " ==> " & value & " ==> " & valout)
           
           
            Set ModelDoc = swApp.OpenDoc6(FileName, 1, 0, "", Errors, Warnings)
           
            Titel = model.GetTitle
            swApp.CloseDoc Titel
            endname = Dir
        Loop
       
End Sub

---

Vielen Dank schonmal

------------------
Ich lehne es ab, anzuerkennen, dass es Unmöglichkeiten gibt - Henry Ford

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Ohne mich näher mit dem Code beschäftigt zu haben:
müsste es nicht

Code:

---

Titel = swmodel.GetTitle

---

heißen?

------------------
Gruß Stefan

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Da oben die letzten beiden Dimensionierungen darauf festgelegt sind ist hier Model mit einem Objekt festgelegt, sollte also stimmen.

swmodel wäre sonst SldWorks.ModelDoc2.

------------------
Ich lehne es ab, anzuerkennen, dass es Unmöglichkeiten gibt - Henry Ford

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

fehler gefunden, hätte statt als model, als part ausgeführt werden müssen.

neuer fehler: er spielt das Programm ab,er öffnet das teil speichert es allerdings nicht aber nix passiert

------------------
Ich lehne es ab, anzuerkennen, dass es Unmöglichkeiten gibt - Henry Ford

[Diese Nachricht wurde von Malte70 am 11. Dez. 2020 editiert.]

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

neuer stand: er speichert aber immernoch nicht

Code:

---

Sub main()

Dim swApp                  As SldWorks.SldWorks
Dim swPart                  As SldWorks.PartDoc
Dim swModel                As SldWorks.ModelDoc2
Dim swModelDocExt          As SldWorks.ModelDocExtension
Dim swImportStepData        As SldWorks.ImportStepData
Dim status                  As Boolean
Dim Errors                  As Long
Errors = 0
Dim Warnings                As Long
Warnings = 0
Dim stepFileName            As String
Dim Filename                As String
Dim strOrdnerName          As String
Dim strName                As String
Dim longstatus              As Long, longwarnings As Long
Dim varsplit                As Variant
Dim part                    As Object
Dim endname                As String

varsplit = Split(strName, ".")

strOrdnerName = "C:\Zwischenordner\Test\test\"
strName = Dir(strOrdnerName & "*.stp")

    Do While strName <> ""
        stepFileName = strOrdnerName & strName
            If stepFileName = strOrdnerName Then
    Exit Do
            End If
       
        Set swModel = swPart
        Set swApp = Application.SldWorks
   
            'Importinformationen holen
            Set swImportStepData = swApp.GetImportFileData(stepFileName)
           
            'Wenn ImportStepData::MapConfigurationData nicht gesetzt ist,dann standardmäßig die Umgebungseinstellung
            'swImportStepConfigData; andernfalls, überschreibe
            'swImportStepConfigData mit ImportStepData::MapConfigurationData
            swImportStepData.MapConfigurationData = True
           
            'Importieren der Step-Datei
            Set swPart = swApp.LoadFile4(stepFileName, "r", swImportStepData, Errors)
            Set swModel = swPart
            Set swModelDocExt = swModel.Extension
           
            'Importdiagnose Starten und versuche alle Fehler zu korrigieren
            Errors = swPart.ImportDiagnosis(True, False, True, 0)
            Set part = swApp.ActiveDoc
            varsplit = Split(strName, ".")
            Debug.Print varsplit(0)
            endname = varsplit(0) & ".sldprt"
           
            'speichern
            longstatus = part.SaveAs3(endname, 0, 2)
     
            Debug.Print (endname & " ==> " & value & " ==> " & valout)
           
            Filename = strOrdnerName & endname
           
            Debug.Print (Filename & " ==> " & value & " ==> " & valout)
           
            Set ModelDoc = swApp.OpenDoc6(Filename, 1, 0, "", Errors, Warnings)
            Dim Titel                  As String
            Titel = part.GetTitle
            swApp.CloseDoc Titel
            strName = Dir
        Loop
       
End Sub

---

------------------
Ich lehne es ab, anzuerkennen, dass es Unmöglichkeiten gibt - Henry Ford

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Fehler gefunden: SaveAs3 braucht ja den pfad mit dem namen, klar das der name nicht reicht   

------------------
Ich lehne es ab, anzuerkennen, dass es Unmöglichkeiten gibt - Henry Ford

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Fehler gefunden: SaveAs3 braucht ja den pfad mit dem namen, klar das der name nicht reicht   

------------------
Ich lehne es ab, anzuerkennen, dass es Unmöglichkeiten gibt - Henry Ford

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Hallo Malte,

hab deinen Code mal aufs wesentliche reduziert, da bekommt man sonst ja Augenkrebs.  .

Code:

---

Sub main()

Dim swApp                  As SldWorks.SldWorks
Dim swModel                As SldWorks.ModelDoc2
Dim swImportStepData        As SldWorks.ImportStepData

Dim longErrors              As Long
Dim longStatus              As Long

Dim stepFileName            As String
Dim strOrdnerName          As String
Dim strName                As String
           
Set swApp = Application.SldWorks

strOrdnerName = "C:\Users\XXX\Desktop\"
strName = Dir(strOrdnerName & "*.stp")

Do While strName <> ""
    stepFileName = strOrdnerName & strName
                   
    'Importinformationen holen
    Set swImportStepData = swApp.GetImportFileData(stepFileName)
             
    'Wenn ImportStepData::MapConfigurationData nicht gesetzt ist,dann standardmäßig die Umgebungseinstellung
    'swImportStepConfigData; andernfalls, überschreibe
    'swImportStepConfigData mit ImportStepData::MapConfigurationData
    swImportStepData.MapConfigurationData = True
             
    'Importieren der Step-Datei
    Set swModel = swApp.LoadFile4(stepFileName, "r", swImportStepData, longErrors)
             
    'Importdiagnose Starten und versuche alle Fehler zu korrigieren
    longErrors = swModel.ImportDiagnosis(True, False, True, 0)
   
    'speichern
    longStatus = swModel.SaveAs3(strOrdnerName & (Split(strName, ".")(0)) & ".sldprt", 0, 2)
   
    swApp.CloseDoc swModel.GetTitle
    strName = Dir
Loop
     
End Sub

---

------------------
--- Man muß nicht alles wissen, man muß nur wissen wo es steht ---

Staatlich anerkannte Deutschniete 

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Zitat:

---

Original erstellt von bk.sc:
...  da bekommt man sonst ja Augenkrebs.   .

---

    Danke 

@Malte
Normalerweise schaut man zuerst nach dem Programm
(set swApp = ...)
holt sich dann das aktuelle Dokument
(set swModelDoc = ...)
schaut was es ist und leitet dann das Part/die Baugruppe/die Zeichnung von ab
(set swPart = ...)

man kann die Dokumente natürlich auch mit direkt mit open bekommen...

Gruß, Christian

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP