---

Folgende Aufgabe:
Unser PDM System übergibt einen Zeichnungsstatus in Textform in die Dateieigenschaften der Zeichnung.
Dieser Text soll per VBA/Makro ausgelesen und mittels einer IF Prüfung auf einen bestimmten Inhalt überprüft werden. Als Ergebnis wird eine neue Eigenschaft samt neuem Wert geschrieben.

Mein Problem das ich gerade habe ist, dass ich mit der Get2 Methode nicht an die Werte komme. Gibt es für Zeichnungen eine eigene Methode?

Code:

---

Dim swApp As Object
Dim swModel    As SldWorks.ModelDoc2
Dim boolstatus As Boolean
Dim longstatus As Long, longwarnings As Long

Dim Prop As Integer
Dim FieldName As String
Dim UseCached As Boolean
Dim ValOut As String
Dim ResolvedValOut As String
Dim WasResolved As Boolean

Sub main()

Set swApp = Application.SldWorks
Set swModel = swApp.ActiveDoc

   
    FieldName = "Workflow"
    Prop = swModel.Get2(FieldName, ValOut, ResolvedValOut)
    If ValOut = "Frei" Then
        swModel.DeleteCustomInfo2 "", "Stempel"
        swModel.AddCustomInfo3 "", "Stempel", swCustomInfoText, "Freistempelung"
   
    End If

End Sub

---

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Hallo cncustomz,

Versuch mal:

Dim swApp As Object
Dim swModel    As SldWorks.ModelDoc2
Dim boolstatus As Boolean
Dim FieldName As String
Dim ResolvedValOut As String
Dim ValOut As String
Dim swModelDocExt As ModelDocExtension
Dim swCustProp As CustomPropertyManager

Sub main()

Set swApp = Application.SldWorks
Set swModel = swApp.ActiveDoc
Set swModelDocExt = swModel.Extension
Set swCustProp = swModelDocExt.CustomPropertyManager("")

 
    FieldName = "Workflow"
    boolstatus = swCustProp.Get4(FieldName, False, ValOut, ResolvedValOut)
    If ValOut = "Frei" Then
 
        boolstatus = swCustProp.Add3("Stempel", swCustomInfoText, "Freistempelung", swCustomPropertyDeleteAndAdd)
 
    End If

End Sub

Gruss Winni

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Perfekt. So funktioniert es genau wie ich es wollte.

Vielen Dank

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP