---

Hallo Forum,
ich bin mit Makros nicht mehr in Übung.
Ich möchte den Namen, von bestehenden Kommentare in einer BG, per Makro ändern. Kann mir jemand dazu die Methode geben.
Vielen Dank im Voraus!

Gruß - Lenz

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Hallo Lenz,

meinst du Comment::Name?
Gets or sets the name of the comment as it appears in the FeatureManager design tree.

Ciao,
Stefan

------------------
Inoffizielle deutsche SolidWorks Hilfeseite    http://solidworks.cad.de

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Hallo Stefan,
ja das meine ich. Ich kann es aber nicht richtig in mein Makro einbinden.
Ich habe viele BGs in die ich die gleichen, umfangreichen Kommentare einfügen muss.
Ich möchte das mit einem Makro machen. Ich habe das so begonnen:

Dim swApp As Object
Dim Part As Object
Dim boolstatus As Boolean
Dim longstatus As Long, longwarnings As Long

Sub main()

Set swApp = Application.SldWorks
Set Part = swApp.ActiveDoc
    boolstatus = Part.Extension.SelectByID2("Kommentare", "COMMENTSFOLDER", 0, 0, 0, False, 0, Nothing, 0)
Dim myComment As Object
Set myComment = Part.Extension.AddComment _
    ("Gewünschter Text")

End Sub

Nun sollen aber meine Kommentare die richtigen Namen im FM erhalten. Statt "Kommentar1" soll z.B. "Größe ändern" stehen. Entweder gleich bei der Erstellung des Kommentars oder im Anschluss daran.

Gruß - Lenz

[Diese Nachricht wurde von Lenzcad am 13. Jun. 2016 editiert.]

[Diese Nachricht wurde von Lenzcad am 13. Jun. 2016 editiert.]

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Hallo Lenz

Wie Stefan schon geschrieben hat, hat das iComment Objekt mehrere Properties und zwar FeatureOwner, Name und Text.
Name und Text kannst du ganz normal ändern bzw. zuweisen.

Code:

---

swComment.Name = "Größe ändern"
swComment.Text = "Gewünschter Text"

---

Siehe auch Beispiel Get Comments in Comments Folder Example (VBA)

Code:

---

Option Explicit

Dim swApp As SldWorks.SldWorks
Dim swModelDoc As SldWorks.ModelDoc2
Dim swFeat As SldWorks.Feature
Dim swFeatMgr As SldWorks.FeatureManager
Dim swCommentFolder As SldWorks.CommentFolder
Dim swComment As SldWorks.Comment
Dim sFeatType As String

Sub main()
Set swApp = Application.SldWorks
' Open part document
Set swModelDoc = swApp.ActiveDoc
' Traverse the FeatureManager design tree for Comments folder
    ' Get first feature in FeatureManager design tree
    Set swFeat = swModelDoc.FirstFeature
    Set swFeatMgr = swModelDoc.FeatureManager
   
    ' Examine FeatureManager design tree to verify that
    ' the the Comments folder is not shown; press F5
   
    Do While Not swFeat Is Nothing
      sFeatType = swFeat.GetTypeName
            ' If Comments folder, add a comment
            If sFeatType = "CommentsFolder" Then
                Set swCommentFolder = swFeat.GetSpecificFeature2
               
                ' Add comment and update FeatureManager design tree
                ' so that Comments folder is shown
                Set swComment = swCommentFolder.AddComment("Gewünschter Text")
                swComment.Name = "Größe ändern"
                swFeatMgr.UpdateFeatureTree
                ' Exit Do While Loop
                Exit Do
            End If
      ' Get next feature in FeatureManager design tree
      Set swFeat = swFeat.GetNextFeature
    Loop

End Sub

---

Gruss Andreas

------------------
21 ist nur die halbe Antwort.

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Hallo Andreas,
vielen, vielen Dank für Deine treffende und umfangreiche Hilfe.

schönen Gruß
Lenz

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP