---

Hallo Forum,

hat einer der Nutzer hier schon mal ein Makro erstellt, mit dem sich für alle Maße die Eigenschaft eines Teils/Bibliotheksfeatures von "für Zeichnung markiert" auf "nicht für Zeichnung markiert", und auch in die andere Richtung ändern lässt? Wenn ja, könnte er mir dieses zur Verfügung stellen?

Tausend Dank!

burgmann

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Hallo,

ich habe ein solches Makro mal auf meine Homepage gelegt. www.ib-knepper.de/download.htm
Ich hoffe es hilft Dir weiter.

Gruß Oliver

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Hallo, jens_oliver...

... wie funktioniert denn das Makro genau?
Bei mir bleibt alles beim Alten...?!?!

------------------
you can't change the world but you can leave a dent
------------------

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Hi,

Als Erstes sollte ein Dialog aufgehen der Fragt ob du die Markierung für alle Maße an oder ausschalten möchtest. Wenn ein Bauteil geöffnet ist sollten dann alle Maße umgestellt werden.

Gruß Oliver

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Zitat:

---

Original erstellt von jens_oliver:
Als Erstes sollte ein Dialog aufgehen

---

...hmm...?!? Ja!? Da passiert aber nichts!   

Wenn ich aber das Makro aus dem VB Editor starte, bleibt er hier hängen: "swApp          As SldWorks.SldWorks"
"Fehler beim Kompilieren: Projekt oder Bibliothek nicht gefunden"

Wo liegt das Problem?

***
EDIT: NEVERMIND!!! Das Makro ist für 2006!!! Ich habe aber nur 2005...
***

------------------
you can't change the world but you can leave a dent
------------------

[Diese Nachricht wurde von G. Dawg am 17. Okt. 2005 editiert.]

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

@ Jens_Oliver
>>> vielen Dank! Funktioniert echt super....
>>> Jetzt müssen wir noch schnell auf SW2006 umstellen....

Danke & Grüße

burgmann

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Hi,

sind bei Dir im VBA Editor unter Extras/Verweise die Bibliotheken von Solidworks markiert?

- Solidworks 2005 Constant type Library
- Solidworks Extensibility Type Library
usw

Gruß Oliver

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

ClipBoard-1.jpg

Ja... ich denke schon! ---> (screenshot)

***
EDIT: Das NICHT VORHANDEN (...) macht mir Sorgen!
***

------------------
you can't change the world but you can leave a dent
------------------

[Diese Nachricht wurde von G. Dawg am 17. Okt. 2005 editiert.]

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Hi,

das Makro sucht nach den 2006 Bibliotheken (NICHT VORHANDEN ...),
diese einfach deaktivieren und die 2005 aktivieren.

Oder einfach den Inhalt(Text) in ein neues Makro kopieren.

Gruß Oliver

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Ich habe nun alles in ein neues Makro kopiert und gestartet...
"swDocPART" -> Variable nicht definiert.... 

Ich gebs auf! 

Vielen Dank, trotzdem!

------------------
you can't change the world but you can leave a dent
------------------

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Danke, Jens Oliver!

Mit dem "Const  swDocPart=1" funkt das Ding einwandfrei!
Gäbe es nun die Möglichkeit, nur die Masse zu ändern, welche ausgewählt sind? Vielleicht möchte ich ja nicht alle ändern...!
Aber es funktioniert schon mal so wie es dedacht war! SUPER!

------------------
you can't change the world but you can leave a dent
------------------

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Hallo Jens,

vielen Dank für das Makro ... als Anmerkung: diese Art Diskussion ist genau der Grund, warum ich meine Makros nie mit den Verweisen mache, sondern die Konstanten immer direkt einbinde und spätesten bei der Veröffentlichung auf Late Binding (also Deklarationen als algemeines Object) mache. Ist wzar meist mehr Arbeit und sieht nicht so elegant aus, läuft aber überall und ich brauch mir keine Gedanken um die SolidWorks Version machen, solange die API Commands gleich bleiben 

Ciao,
Stefan

------------------
Inoffizielle deutsche SolidWorks Hilfeseite
http://solidworks.cad.de

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Hallo Stefan,

ich hätte natürlich auf die Probleme mit den Verweisen hinweisen sollen. Für Anwender, die ein Makro (nur) benutzen wollen ist es immer ärgerlich wenn das Programm nicht sofort läuft. Da ich normalerweise aber größere Projekte bearbeite, ist ein sauberer Programmierstiel sehr wichtig. Ich versuche immer das „late Binding“ zu vermeiden, da zum einem die Laufzeit erhöht wird und zum andern um eine Syntax und Type Überprüfung zu haben. Da vielleicht einige Anwender das Makro noch weiter bearbeiten wollen oder sich einige Sachen abschauen wollen, denke ich ist es richtig die „saubere“ Lösung zu zeigen.

Gruß Oliver

---------------
Software nach Maß für ihr CAD-System http://www.ib-knepper.de

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Zitat:

---

Original erstellt von jens_oliver:
...
ich habe ein solches Makro mal auf meine Homepage gelegt. www.ib-knepper.de/download.htm
...

---

Leider läuft der Link ins Leere  . Kann mir jemand das Makro zur Verfügung stellen?

------------------
Gruß Stefan

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Code:

---

Option Explicit

Dim swApp                  As SldWorks.SldWorks
Dim swModel                As SldWorks.ModelDoc2
Dim swFeat                  As SldWorks.Feature
Dim swSubFeat              As SldWorks.Feature
Dim swDispDim              As SldWorks.DisplayDimension
Dim markedForDrawing        As Boolean
Dim antwort

Sub main()

Set swApp = Application.SldWorks
antwort = MsgBox("Alle Parameter für Zeichnung markieren(Ja) deaktivieren(Nein)", vbYesNoCancel, "Ingenieurbüro Knepper")
If antwort = vbYes Then
    markedForDrawing = True
ElseIf antwort = vbNo Then
    markedForDrawing = False
Else
    Exit Sub
End If

Set swModel = swApp.ActiveDoc
If swModel Is Nothing Then
    antwort = MsgBox("Kein aktives Bauteil!", vbCancel, "Ingenieurbüro Knepper")
    Exit Sub
End If

If (swModel.GetType = swDocPART) Then
  Set swFeat = swModel.FirstFeature
    Do While Not swFeat Is Nothing
        Set swSubFeat = swFeat.GetFirstSubFeature
        Do While Not swSubFeat Is Nothing
            Set swDispDim = swSubFeat.GetFirstDisplayDimension
            Do While Not swDispDim Is Nothing
                swDispDim.markedForDrawing = markedForDrawing
                Set swDispDim = swSubFeat.GetNextDisplayDimension(swDispDim)
            Loop
            Set swSubFeat = swSubFeat.GetNextSubFeature
        Loop
        Set swDispDim = swFeat.GetFirstDisplayDimension
        Do While Not swDispDim Is Nothing
            swDispDim.markedForDrawing = markedForDrawing
            Set swDispDim = swFeat.GetNextDisplayDimension(swDispDim)
        Loop
        Set swFeat = swFeat.GetNextFeature
    Loop
  Else
  antwort = MsgBox("Kein aktives Bauteil!", vbCancel, "Ingenieurbüro Knepper")
End If

End Sub

---

------------------
21 ist nur die halbe Antwort.

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Ein herzliches Dankeschön!

------------------
Gruß Stefan

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP