---

Erich.png

Hallo,

auf dem angehängten Bild ist die Operation 8 zu sehen, diese Operation würde ich sehr gerne durch eine Q-Parametrierung ersetzen, zudem soll noch eine Tiefenzustellung dabei sein, um die Zustellung mit mehreren Steps zu erledigen.

Danke im Voraus:-)

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Moin Herrscher,

sehr seltsame Skizze.
Wer fertigt denn einen Sechskant auf Eckenmaß?
Macht es nicht viel mehr Sinn, die Schlüsselweite anzugeben?
(mal abgesehen davon, dass das Programm dann ebenfalls einfacher wäre)

LG, Nina

------------------
Nichts auf der Welt ist so gerecht verteilt wie Intelligenz.
Jeder ist der Meinung, genug davon zu besitzen. [René Descartes]
Ist das nicht wunderbar?!?    
System-Info | Bildschirmaufzeichnung | Creo-Forum | Richtig fragen

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Genau so soll es nachher sein, dass man nur die SW angibt und die Zustellung, dann soll das Programm selbst ablaufen. Das Bild ist von einer neueren Steuerung (meine ist ja etwas älter:-).

Gruß

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

evtl. die Kommentare entfernen

0  BEGIN PGM 0815 MM
1  BLK FORM 0.1 Z  X-12.5  Y-12.5  Z-15
2  BLK FORM 0.2  X+12.5  Y+12.5  Z+0
3  FN 0: Q1 =+19 ; SCHLUESSELWEITE
4  FN 0: Q2 =+6 ; ANZ. DER FLAECHEN
5  FN 0: Q3 =+0 ; INNEN(+1) AUSSEN(+0)
6  FN 0: Q19 =+200 ; VORSCHUB Z-
7  FN 0: Q20 =+200 ; VORSCHUB FRAESEN
8  FN 0: Q21 =-10 ; FRAESTIEFE Z
9  FN 0: Q25 =-10 ; ZUSTELLTIEFE Z
10 FN 0: Q22 =+0.3 ; ECKENRADIUS
11 FN 0: Q23 =+0 ; MITTELPUNKT X-ACHSE
12 FN 0: Q24 =+0 ; MITTELPUNKT Z-ACHSE
13 TOOL CALL 1 Z S2000 DR+0
14 CALL LBL 1
15 CALL LBL 2
16 L  Z+10 R0 FMAX M9
17 FN 9: IF +1 EQU +1 GOTO LBL 254
18 STOP M2
19 LBL 1
20 FN 4: Q4 =+Q1 DIV +2
21 FN 4: Q5 =+360 DIV +Q2
22 FN 4: Q6 =+Q5 DIV +2
23 FN 7: Q7 = COS +Q6
24 FN 4: Q8 =+Q4 DIV +Q7
25 FN 0: Q10 =+Q6
26 FN 2: Q11 =+360 - +Q6
27 FN 3: Q15 =+Q108 * +2
28 FN 2: Q12 =+Q4 - +Q15
29 FN 1: Q13 =+Q4 + +Q15
30 FN 4: Q14 =+Q108 DIV +2
31 FN 4: Q16 =+Q1 DIV +3
32 FN 1: Q26 =+0 + +Q25
33 LBL 0
34 LBL 2
35 FN 12: IF +Q3 LT +0.5 GOTO LBL 3
36 FN 12: IF +Q22 LT +Q108 GOTO LBL 4
37 FN 11: IF +Q108 GT +Q16 GOTO LBL 99
38 CC  X+Q23  Y+Q24
39 LP  PR+Q12  PA+0 R0 FMAX M3
40 L  Z+1 R0 FMAX M8
41 L  Z+Q26 R0 FQ19
42 LP  PR+Q4  PA+0 RL FQ20
43 RND RQ14
44 LP  PR+Q8  PA+Q6
45 RND RQ22
46 LBL 10
47 FN 1: Q10 =+Q10 + +Q5
48 LP  PR+Q8  PA+Q10
49 RND RQ22
50 FN 12: IF +Q10 LT +Q11 GOTO LBL 10
51 LP  PR+Q4  PA+0
52 RND RQ14
53 LP  PR+Q12  PA+0 R0
54 L  Z+1 R0 FMAX
55 FN 0: Q10 =+Q6
56 FN 9: IF +Q26 EQU +Q21 GOTO LBL 8
57 FN 1: Q26 =+Q26 + +Q25
58 FN 12: IF +Q26 LT +Q21 GOTO LBL 6
59 FN 11: IF +Q26 GT +Q21 GOTO LBL 2
60 LBL 8
61 LBL 0
62 LBL 3
63 CC  X+Q23  Y+Q24
64 LP  PR+Q13  PA+0 R0 FMAX M3
65 L  Z+1 R0 FMAX M8
66 L  Z+Q26 R0 FQ19
67 LP  PR+Q4  PA+0 RL FQ20
68 RND RQ14
69 LP  PR+Q8  PA-Q6
70 RND RQ22
71 LBL 5
72 FN 1: Q10 =+Q10 + +Q5
73 LP  PR+Q8  PA-Q10
74 RND RQ22
75 FN 12: IF +Q10 LT +Q11 GOTO LBL 5
76 LP  PR+Q4  PA+0
77 RND RQ14
78 LP  PR+Q13  PA+0 R0
79 L  Z+1 R0 FMAX
80 FN 0: Q10 =+Q6
81 FN 9: IF +Q26 EQU +Q21 GOTO LBL 9
82 FN 1: Q26 =+Q26 + +Q25
83 FN 12: IF +Q26 LT +Q21 GOTO LBL 7
84 FN 11: IF +Q26 GT +Q21 GOTO LBL 3
85 LBL 9
86 LBL 0
87 LBL 4
88 FN 0: Q22 =+Q108
89 FN 9: IF +1 EQU +1 GOTO LBL 2
90 LBL 0
91 LBL 6
92 FN 0: Q26 =+Q21
93 FN 9: IF +1 EQU +1 GOTO LBL 2
94 LBL 0
95 LBL 7
96 FN 0: Q26 =+Q21
97 FN 9: IF +1 EQU +1 GOTO LBL 3
98 LBL 0
99 LBL 99
100 STOP M5
101 ; !!!!FEHLER!!!!!
102 STOP M5
103 LBL 254
104 L  Z+100 R0 FMAX
105 L  X+0  Y+0 R0 FMAX
106 STOP M30
107 END PGM 0815 MM

------------------
Der Kopf ist rund, damit die Gedanken die Richtung wechseln können!

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Super vielen Dank:-) Werde ich direkt ausprobieren:-))))

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Aber ein Paar Fragen hab ich noch:

- was ist beim Satz 101 mit Fehler gemeint, bzw. steht bei 100 und 102 das gleiche im Satz
- wie kann ich die Orientierung des Sechskants ändern, z.b. um 15° verdrehen?

Gruß und Danke im Voraus:-)

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Wenn eine Falsche Eingabe erfolgt (z.B. Innensechskant fräsen mit zu großem Werkzeug) springt die Steuerung zum LBL99.
Dann steht da halt im Programmfenster " !!!!FEHLER!!!!!" und bleibt durch die zwei Stop stehen.

Wenn du den Sechskant um 15° verdrehen willst, gibst du halt am Programmanfang eine Drehung um 15° (Zyklus 10) ein.

------------------
Der Kopf ist rund, damit die Gedanken die Richtung wechseln können!

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP