---

Hallo an alle,

folgendes Problem, bei mir ist der "Part Name" immer gleich dem des "Instance Name", nun stört mich dass immer beide im "Assembly Design" angezeigt werden (zu lang und unübersichtlich).

Wie kann ich nur den "Part Name" anzeigen lassen?

Und als zweite Frage, ist es möglich Catia so zu configurieren das der "Instance Name" immer dem "Part Name" angepasst wird? Denn hin und wieder bekomme ich externe Daten wo noch der "alte" Name als "Instance Name" angezogen ist, eine automatisierung wäre sehr arbeitsersparend.

Schönen Dank für eure Unterstützung.

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Servus
Unter Tools -> Optionen -> Infrastruktur -> Product Structire -> Knotenanpassung kannst du die Darstellung im Baum definieren. (durch entfernen von "#IN#" sollte der Exemplarname verschwinden)

Gruß
Bernd

------------------
Warum einfach, wenn es auch kompliziert geht.

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Hallo Magou,

du kannst unter Tools-Optionen unter "Infrastructur-Product Structure" im Register der Knotenanpassung die oberen darzustellenden Werte manipulieren. In deinem Fall müsstest du die Eintragung für "(#IN#)" herausnehmen.

CATIA lässt sich so nicht konfigurieren, dass der Instancename = Partnumber ist. Du müsstest dann die Anzeige der Partnumber nochmals in deiner Customization fordern (also zweimal #PN# schreiben) - das ist wohl nicht so sinnvoll.
Eine Automatisierung gibts über Makros, die man schreibt oder sich schreiben lässt. Diese würden z.B. die Namen gleichsetzen und einen Zähler ".1" ".2" etc. hochzählen.

Zu deinen alten Teilen: kann es sein, dass du im cache mode geladen hattest und damit die Instance "nach vorne wandert" = andere Darstellung im Baum bekommst?

------------------
Grüße aus dem Thurgau
Thomas

+++++++++++++++++++++++++++++++++

CATIA - eine Laune der Natur ...

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Super, danke, das hatte ich gesucht... warum ich darauf nicht selber gekommen bin?!

Mit "alten" Namen meinte ich, dass wenn unser Dienstleister neu abspeichert dann ändert der nur den "Part Name" und nicht den "Instance Name" und somit bekomme ich den "alten" namen als "Instance Name" zurück.

Aber wenn man das Umbenennen nicht automatisieren kann dann ist es eh egal.

Danke nochmal.

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Servus
Anbei ein Script das alle Instanzen umbenennt (falls dies nicht bei Unterbaugruppen geschehen soll die Zeile "if oProduct.referenceproduct ..." wieder ein kommentieren).

Code:

---

' Makro: Instanzen_Umbenennen.CATScript
' Version: 1.0
' Code: CATIA CATScript
' Zweck: Erstellt die Exemplarnamen einer Baugruppe und in deren Komponenten.
'     Benennungsschema: PartNumer + . + Zähler
' Autor: bgrittmann
' Datum: 26.11.2010
'------------------------------------------------------------------------------------

CATIA.StatusBar = "Instanzen_Umbenennen.CATScript, Version 1.0"

Sub CATMain()

Dim oDoc As ProductDocument
Dim oProduct As Product
Dim oProducts As Products
Dim Setting As SettingController

'***Abfrage nach geöffnetem Dokument
If CATIA.Windows.Count = 0 Then
MsgBox "Es ist kein Dokument geöffnet." + vbNewLine + "Das Makro kann nicht ausgeführt werden und wird beendet.", vbCritical + vbOKOnly, "Kein Dokument offen"
Exit Sub
End If

'***Auslesen der Dokumentart
Set oDoc = CATIA.ActiveDocument
If TypeName(oDoc) <> "ProductDocument" Then
MsgBox "Dieses Dokument ist kein CATProduct." + vbNewLine + "Das Makro kann nicht ausgeführt werden und wird beendet.", vbCritical + vbOKOnly, "Falscher Dokumententyp"
Exit Sub
End If

'Umbenennen aufrufen
Set oProduct = oDoc.Product
Set oProducts = oProduct.Products
Instanz_Umbenennen oProducts

End Sub

Private Sub Instanz_Umbenennen(ByRef prodProducts As Products)

'Erstellt die Exemlarnamen neu, bestehend aus PartNumber+.+Zähler
Dim oProduct As Product
Dim i, j, intcount As Integer
Dim StrPartNumber As String
Dim bCache As Boolean

'Cache-Mode aktiv?
bCache = CATIA.SettingControllers.Item("CATSysCacheSettingCtrl").ActivationMode

'Exemplarnamen löschen
For i = 1 To prodProducts.Count
prodProducts.Item(i).Name = "temp2" & CStr(i)
'bei aktiviertem Cache-Mode, Teil in den DEFAULT_MODE wechseln
If bCache = 1 Then
prodProducts.Item(i).ApplyWorkMode DEFAULT_MODE
End If
Next

'Exemplare der Reihe nach umbenennen
For i = 1 To prodProducts.Count
Set oProduct = prodProducts.Item(i)
'Abfrage ob temporärer Name gesetzt
If Left(oProduct.Name, 4) = "temp" Then
Set oProduct = prodProducts.Item(i)
'Zähler initialisieren
intcount = 1
StrPartNumber = oProduct.PartNumber
oProduct.Name = StrPartNumber & "." & intcount
'Alle Komponenten unterhalb (>i) auf gleiche PartNumber prüfen
For j = i + intcount To prodProducts.Count
If StrPartNumber = prodProducts.Item(j).PartNumber Then
intcount = intcount + 1
prodProducts.Item(j).Name = StrPartNumber & "." & intcount
End If
Next
End If
'oProduct ist eine Komponenten?
If TypeName(oProduct.ReferenceProduct.Parent) <> "PartDocument" Then
'If oProduct.ReferenceProduct.Parent.Name = oProduct.Parent.Parent.ReferenceProduct.Parent.Name Then
'Sub rekursiv aufrufen
Instanz_Umbenennen oProduct.ReferenceProduct.Products
'End If
End If
Next
End Sub

---

Gruß
Bernd

------------------
Warum einfach, wenn es auch kompliziert geht.

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP