---

Servus forum,

wie kann ich hier auf die Bauteilnummer zugreifen?
Möchte Parameter und Eigenschaften per Makro miteinander verknüfen.

Language="VBSCRIPT"

Sub CATMain()

Set partDocument1 = CATIA.ActiveDocument

Set part1 = partDocument1.Part

Set relations1 = part1.Relations

Set parameters1 = part1.Parameters

Set strParam1 = parameters1.Item("      wie greif ich hier auf die Bauteilnummer zu?                      \Eigenschaften\BG")

Set formula1 = relations1.CreateFormula("Formel.30", "", strParam1, "Parameter_Stueckliste\BG ")

formula1.Rename "Formel.30"

........

------------------
Habe D`Ehre

Felsen

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Servus

Schau dir mal diesen Beitrag an, wie man auf die UserRefProperties  zugreifen kann.

Gruß
Bernd

------------------
Warum einfach, wenn es auch kompliziert geht.

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Servus Felsen

Ich hab dir mal einen kleinen Code zu deinem Problem zusammen geschrieben (damit ich in Übung bleib)

Code:

---

Sub CATMain()

Dim oPartDocument As PartDocument
Dim oParameterSet as ParameterSet
Dim oParameter as Parameter
Dim oUserRefPropertyParameter as Parameter
Dim strFormula as String
Dim oFormula as Formula
Dim i as Integer
Dim sParameterName as String

Set oUserRefPropertyParameter = Nothing

If TypeName(CATIA.ActiveDocument) <> "PartDocument" Then
    MsgBox "No PartDocument opened and active", vbCritical
    Exit Sub
End If

Set oPartDocument = CATIA.ActiveDocument
Set oParameterSet = oPartDocument.Part.Parameters.RootParameterSet.ParameterSets.Item("Stückliste")

for i = 1 to oParameterSet.DirectParameters.Count
    Set oParameter = oParameterSet.DirectParameters.Item(i)
    sParameterName = Right(oParameter.Name, (Len(oParameter.Name) - InStrRev(oParameter.Name,"\")))
    if sParameterName <> "" then   
        Set oUserRefPropertyParameter = GetUserRefPropertiesByName(oPartDocument.Product, sParameterName)
        if Not oUserRefPropertyParameter is Nothing then
            strFormula = oPartDocument.Part.Parameters.GetNameToUseInRelation(oParameter)
            Set oFormula = oPartDocument.Part.Relations.CreateFormula("", "", oUserRefPropertyParameter, strFormula)
        end if
    end if
next

End Sub

Function GetUserRefPropertiesByName(oProduct As Product, ParameterName As String) As Parameter

Dim UserProperties As Parameters
Dim I As Integer

Set UserProperties = oProduct.UserRefProperties

For I = 1 To UserProperties.Count
    If Right(UserProperties.Item(I).Name, Len(ParameterName)) = ParameterName Then
        Set GetUserRefPropertiesByName = UserProperties.Item(I)
        Exit Function
    End If
Next

Set GetUserRefPropertiesByName = Nothing

End Function

---

Viel Spaß beim nachvollziehen und verbessern.

Gruß
Bernd

------------------
Warum einfach, wenn es auch kompliziert geht.

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP