---

in Zeichnung habe ich Texte positioniert . Die haben Feature Name ( Properties)" Dokumentnumber"
Diese Texte möchte ich mit Parameter aus dem Part ersetzen. Alles automatisch mit einen Titelblok macro.
kann hier jemend einen Beispiel schreiben ?

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Servus
Willkommen im Forum. Bitte Systeminfo ergänzen.
Hast du schon mal hier im Forum nach so was gesucht? Hast du dir den Titelblockeditor auf catia.cad.de angeschaut?

Gruß
Bernd

------------------
Warum einfach, wenn es auch kompliziert geht.

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Hallo,

was hast du denn schon an Code erzeugt?
Man weiß aktuell ja gar nicht wo man dich abholen muss.

Was ist denn konkret deine Erwartung an "uns"?

Gruß
Randle

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Ich habe einen Part mit Prameter erzeugt .

Sub CATMain()

Set partDocument1 = CATIA.ActiveDocument

Set product1 = partDocument1.GetItem(" ")

Set product1 = product1.ReferenceProduct

Set parameters1 = product1.UserRefProperties

Set strParam1 = parameters1.CreateString("Dokumentnummer", "")
strParam1.ValuateFromString "123456789"

Set strParam1 = parameters1.CreateString("Bennennung", "")
strParam1.ValuateFromString "Zylinder"

End Sub

Jetzt möchte ich die Wert von dem Parameter in Zeichnungskopf mit Hilfe von einen Macro übetragen .

Vorlage für den Zeichnungskopf ist erstellt  und Zeichnung ist mit dem Part verlink.
Aktuel plazhalter für  Dokumentnummer  ist ein Text/ Properites "ZK1"
und für die Bennennung ist ein Text/ Properites "ZK2"

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Servus
Du könntest über DrawingViewGenerativeBehavior einer Bauteilansicht auf das dargestellte Teil/Baugruppe schließen. Und dann daraus den Parameter auslesen (siehe zB hier und Doku).
Den Parameter könntest du dann in Textfeld als Text einfügen (ggf auch über einen Attributlink).

Gruß
Bernd

------------------
Warum einfach, wenn es auch kompliziert geht.

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

kannst du einen Beispiel als Macro schreiben ?
Danke und viele Grüße

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Hallo,

an das verknüpfte Dokument einer Ansicht kommst du hiermit

Code:

---

Dim oDrwDoc As DrawingDocument
Dim oDrwSheet As DrawingSheet
Dim oDrwView As DrawingView
Dim oCatDoc as Document

Set oDrwDoc = CATIA.ActiveDocument          'prüfen ob ein Zeichnungsdokument geladen/aktiv ist
If Err.Number <> 0 Then                    'wenn keine Zeichnung geladen/aktiv ist...
    Exit Sub
End If

Set oDrwSheet = oDrwDoc.Sheets.Item(1)      'Blatt 1 ansprechen/zuweisen - ist immer vorhanden, keine Fehlerbehandlung erforderlich
Set oDrwView = oDrwSheet.Views.Item(3)      'prüfen ob eine Geometrieansicht vorhanden ist - Item(1) = Arbeitsansicht, Item(2) = Hintergrundansicht
If Err.Number <> 0 Then                    'wenn keine Geometrieansicht vorhanden ist
    Exit Sub
End If

Set oCatDoc = oDrwView.GenerativeBehavior.Document.Parent  'prüfen ob verknüpftes Dokument vorhanden ist

---

Einen Attributlink erzeugt man so:

Code:

---

Private Sub sCreateAttribLink(t_oText As DrawingText, t_oParameter As Parameter)

    t_oText.Text = ""
    t_oText.InsertVariable 0, 0, t_oParameter

End Sub

---

Viel Erfolg und Gruß
Randle

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Hier bekomme ich leider error
"Description: Objekt erforderlich:'t_oText' "

Sub sCreateAttribLink(t_oText As DrawingText, t_oParameter As Parameter)
    t_oText.Text = "Benennung"
    t_oText.InsertVariable 0, 0, t_oParameter

End Sub

was ist hier falsch?

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Hallo,

du musst beim Aufruf der Routine dieser zwei Objekte (DrawingText, Parameter) mitgeben, in etwa so:

sCreateAttribLink MyText, strParam1

Die Objekte musst du natürlich vorher definieren, für den Parameter hast du das ja schon.

Gruß
Randle

------------------
Wer für nichts steht, fällt für alles!

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Info.pdf

das habe ich gemacht.
sCreateAttribLink Benennung, Benennung

In Anhang habe ich dargestellt was mochte ich erreichen.
Da muss doch möglich sein mit dem Makro, die Parameter aus dem Part in Zeichnung zu Übertragen 

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

da feht mir noch die Übergabe

---------------------------------------------

Sub CATMain()

Dim oDrwDoc As DrawingDocument
Dim oDrwSheet As DrawingSheet
Dim oDrwView As DrawingView
Dim oCatDoc as Document
Dim t_oText As DrawingText
Dim t_oParameter As Parameter 

Set oDrwDoc = CATIA.ActiveDocument          'prüfen ob ein Zeichnungsdokument geladen/aktiv ist
If Err.Number <> 0 Then                    'wenn keine Zeichnung geladen/aktiv ist...
    Exit Sub
End If

Set oDrwSheet = oDrwDoc.Sheets.Item(1)      'Blatt 1 ansprechen/zuweisen - ist immer vorhanden, keine Fehlerbehandlung erforderlich
Set oDrwView = oDrwSheet.Views.Item(3)      'prüfen ob eine Geometrieansicht vorhanden ist - Item(1) = Arbeitsansicht, Item(2) = Hintergrundansicht
If Err.Number <> 0 Then                    'wenn keine Geometrieansicht vorhanden ist
    Exit Sub
End If
Set oCatDoc = oDrwView.GenerativeBehavior.Document.Parent  'prüfen ob verknüpftes Dokument vorhanden ist

set ProductDocument = ???????

set oParameter = ProductDocument.Product.Parameters.item("Benennung")
MsgBox(oParameter.value)

End Sub

---------------------------------------

in Partmodus
Set ProductDocument = CATIA.ActiveDocument   
und wie mache ich das in Zeichnzngsmodus mit verlinkung zum Part ?

set ProductDocument = ???????

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Beispieldaten.zip

Hallo,

also ich habe den folgenden Code mal eben zusammengezimmert und unter R18 erfolgreich getestet.

Code:

---

Sub CATMain()

Dim oDrwDoc As DrawingDocument
Dim oDrwSheet As DrawingSheet
Dim oDrwView As DrawingView
Dim oCatDoc As Document
Dim oDrwText As DrawingText
Dim oProd As Product
Dim oParam As Parameter

On Error Resume Next

Set oDrwDoc = CATIA.ActiveDocument          'prüfen ob ein Zeichnungsdokument geladen/aktiv ist
If Err.Number <> 0 Then                    'wenn keine Zeichnung geladen/aktiv ist...
    Exit Sub
End If

Set oDrwSheet = oDrwDoc.Sheets.Item(1)      'Blatt 1 ansprechen/zuweisen - ist immer vorhanden, keine Fehlerbehandlung erforderlich
Set oDrwView = oDrwSheet.Views.Item(3)      'prüfen ob eine Geometrieansicht vorhanden ist - Item(1) = Arbeitsansicht, Item(2) = Hintergrundansicht
If Err.Number <> 0 Then                    'wenn keine Geometrieansicht vorhanden ist
    Exit Sub
End If

Set oCatDoc = oDrwView.GenerativeBehavior.Document.Parent  'prüfen ob verknüpftes Dokument vorhanden ist
Set oProd = oCatDoc.Product

Set oParam = oProd.UserRefProperties.CreateString("Benennung", "Test")
Set oDrwText = oDrwSheet.Views.Item(2).Texts.GetItem("TB_BENENNUNG")
sCreateAttribLink oDrwText, oParam
If Err.Number <> 0 Then
    MsgBox "Irgendwas ist schiefgelaufen.", vbInformation, "Fehler"
End If

On Error GoTo 0
End Sub

Sub sCreateAttribLink(t_oText As DrawingText, t_oParameter As Parameter)
    t_oText.Text = ""
    t_oText.InsertVariable 0, 0, t_oParameter
End Sub

---

Der Code läuft durch wenn du beide Dokumente (Anhang: Beispieldaten.zip) in CATIA geladen sind und die Zeichnung aktiv ist.

Ich habe hier allerdings auf eine ausführliche Fehlerbehandlung verzichtet. Auch wird der Parameter im Part IMMER erzeugt (auch wenn der bereits vorhanden ist). Hier würde ich empfehlen noch was einzubauen was prüft ob es den Parameter schon gibt und ihn nur erzeugt wenn der noch nicht vorhanden ist

Die im Code hinterlegte Belegung für den 3D Parameters "Benennung" halte ich auch für problematisch, oder heißen bei euch alle Teile gleich?

Aber zumindest hast du jetzt Code der in der Basis funktioniert und den du entsprechend deinen Anforderungen anpassen/erweitern kannst.

Viel Erfolg und Gruß
Randle

------------------
Wer für nichts steht, fällt für alles!

[Diese Nachricht wurde von Randle am 04. Aug. 2017 editiert.]

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Danke Dir ,
Jetzt funktioniert richtig
viele Grüße

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP