---

Hallo und vielen Dank an alle die sich die Zeit
nehmen mir zu helfen.
habe mal wieder ein neues Problem - nichts großes dennoch komm ich nicht weiter.
Ich möchte aus meiner Teilenummer die Anzahl der Zeichen (von links)
bis zum Doppel-Unterschtrich auslesen-Problem die Anzahl der Zeichen können verschieden sein. Bsp. 0000000__0000__Bezeichnung
in diesem Fall sind es 7 Zeichen bis "__" (von links)
oder 0000000000__0000__Bezeichnung hier sind es 10 Zeichen bis "__"
Kann mir Jmand ein Makrobeispiel aufführen für VBA
ist für Catia V5 R19

------------------
Mit freundlichem Gruß
Andreas

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Hallo Andreas,

es gibt da mehrere Möglichkeiten einen String zu durchsuchen.

Mit Instr()

Code:

---

Sub MitInstr()
Dim MyString    As String
Dim iAnzahl    As Integer

'Beispielstring
MyString = "00000__0000__Bezeichnung"

'Instr() gibt die Stelle eines bestimmten Zeichens
'in einer Zeichenkette wieder und das -1
iAnzahl = InStr(1, MyString, "__", vbTextCompare) - 1

'Ausgabe
MsgBox "Nullstellen mit Instr(): " & iAnzahl, vbOKOnly, "Hinweis"

End Sub

---

mit Split()

Code:

---

Sub MitSplit()
Dim MyString    As String
Dim iAnzahl    As Integer
Dim MySplit

'Beispielstring
MyString = "00000__0000__Bezeichnung"

'Split() trennt einen String und gibt ein
'eindimensionales Array zurück
MySplit = Split(MyString, "__")

'Len() gibt die länge eines Strings zurück
iAnzahl = Len(MySplit(0))

'Ausgabe
MsgBox "Nullstellen mit Split(): " & iAnzahl, vbOKOnly, "Hinweis"

End Sub

---

mit einer For oder Do Schleife und Mid()

Code:

---

Sub MitForSchleife()
Dim MyString    As String
Dim iAnzahl    As Integer

'Beispielstring
MyString = "00000__0000__Bezeichnung"

'String in einer For Schleife von erster Stelle
'letzter durchlaufen, dabei Zähler eins nach oben
'zählen bis Trennstelle "__" erreicht wurde.
For iAnzahl = 1 To Len(MyString) Step 1
    If Mid(MyString, iAnzahl, 2) = "__" Then
        iAnzahl = iAnzahl - 1
        Exit For
    End If
Next

'Ausgabe
MsgBox "Nullstellen mit ForSchleife(): " & iAnzahl, vbOKOnly, "Hinweis"

End Sub

---

mfg
Mario

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Hallo Mario

noch mal recht vielen Dank für deine Vorschläge -
funktionieren super.   

------------------
Mit freundlichem Gruß
Andreas

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP