---

Hallo,
ich habe schon einiges mit Makros bisher gemacht und konnte mir auch einige selbst erstellen.
(Teilweise auch dank dem Forum hier)
Doch nun hänge ich doch an einer Sache:

Und zwar möchte ich ein Makro schreiben, mit dem ich Maßzahlen in Klammern schreiben kann, ohne erst auf die Eigenschaften zu gehen.

Es soll wie folgt funktionieren:

- ich klicke ein Maß an
- starte das Makro
- der Maßtext ist in Klammern gesetzt

Nur bekomme ich das irgendwie nicht gebacken...

Momentan bin ich nur soweit:

________________________________________________________

Sub CATMain()

Dim drawingDocument1 As DrawingDocument
Set drawingDocument1 = CATIA.ActiveDocument

Dim selection1 As Selection
Set selection1 = drawingDocument1.Selection

'Hier kommt dann der Befehl hin, der die Klammern setzt.

selection1.Clear

End Sub

________________________________________________________

Das einzige, was ich bis jetz hinbekommen habe ist folgendes:
Da werden alle Blätter und alle Ansichten nach Maßen durchsucht und diese alle geändert.
Jedoch will ich nur ein einzelnes ändern (wie oben beschrieben).

________________________________________________________

Set drawingSheets1 = activedoc.Sheets

For a = 1 To drawingSheets1.Count
Set drawingSheet1 = drawingSheets1.Item(a)
Set drawingViews1 = drawingSheet1.Views

For b = 1 To drawingViews1.Count
Set drawingView1 = drawingViews1.Item(b)
Set dimensions1 = drawingView1.Dimensions

For c = 1 To dimensions1.Count
Set dimension1 = dimensions1.Item(c)
Set DrawingDimValue1 = dimension1.GetValue

DrawingDimValue1.SetBaultText 1, "(", ")", "", ""

Next
Next
Next

________________________________________________________

Ich habe es noch nicht geschafft diesen Befehl so zu ändern, dass er nur für mein ausgewähltes Maß gilt.
Ich hoffe ihr könnt mir da weiterhelfen.

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Hallo,

ich würde es mit einer UserSelection machen. Infos findest du im Forum genug.
Dadurch kannst du auch sicherstellen, dass nur ein Maß selektiert ist.

Danach gehts weiter mit:

Code:

---

Set dimension1 = oSelection.item(1)
Set DrawingDimValue1 = dimension1.GetValue
DrawingDimValue1.SetBaultText 1, "(", ")", "", ""

---

Grüsse Dominik

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Hallo,

Ich habe das mal versucht, wie du gesagt hast.
Doch wenn ich ich das unten aufgeführte Makro ausfühe bekomme ich die Meldung:
"Object requiered"

Kann es sein das ich mich da irgendwie vertan hab?

-------------------------------------------------

Sub CATMain()

Dim drawingDocument1 As DrawingDocument
Set drawingDocument1 = CATIA.ActiveDocument

Set oSelection = CATIA.ActiveDocument.Selection
Dim InputObjectType(0)
InputObjectType(0) = "AnyObject"

Status = oSelection.SelectElement2(InputObjectType, "Wählen Sie die Bemaßung aus", False)
If (Status <> "Normal") Then
    MsgBox "Abbruch"
    Exit Sub
Else

Set dimension1 = oSelection.Item(1)
Set DrawingDimValue1 = dimension1.GetValue
DrawingDimValue1.SetBaultText 1, "(", ")", "", ""

End If

oSelection.Clear

End Sub

-------------------------------------------------

Ich kann mir gut vorstellen, das ich da noch etwas vergesen habe.

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Hallo John,

ändere mal die fett markierte Zeile in deinem Code 

Code:

---

Sub CATMain()

Dim drawingDocument1 As DrawingDocument
Set drawingDocument1 = CATIA.ActiveDocument

Set oSelection = CATIA.ActiveDocument.Selection
Dim InputObjectType(0)
InputObjectType(0) = "AnyObject"

Status = oSelection.SelectElement2(InputObjectType, "Wählen Sie die Bemaßung aus", False)
If (Status <> "Normal") Then
    MsgBox "Abbruch"
    Exit Sub
Else

Set dimension1 = oSelection.Item(1).Value
Set DrawingDimValue1 = dimension1.GetValue
DrawingDimValue1.SetBaultText 1, "(", ")", "", ""

End If

oSelection.Clear

End Sub

---

------------------
MFG Daniel

Systeminformation | Inoffizielle CATIA Hilfeseite | CATIA FAQ | Suche | TraceParts (Normteile...) | 3D Content Central (noch mehr Normteile...)

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Ja, Super!!!!

Das war der Fehler gewesen.
Jetzt funktioniert es so wie es soll 

Vielen Dank für eure Hilfe!

mfg John

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP