---

Hallo zusammen,
ist es möglich das Makro so zu ändern das es die Dateiauswahl öffnet und nicht direkt auf ("d:\punkte.xls") zugreift ? Ich würde den Excelsheet gerne ohne genaue Pfadangabe und Namen auswählen

Set Excel = CreateObject("Excel.Application")      'Excel starten
  Excel.Visible = True
  Set WB = Excel.Workbooks.Open("d:\punkte.xls")    'Arbeitsmappe öffnen
  Set WS = WB.Worksheets.Item(1)                      'Tabelle holen

Für eine Hilfe wäre ich sehr Dankbar.

Mit freundlichen Grüßen
Manni

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

hilft dir schon die Forensuche weiter?

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Hallo,

falls du mit CATIA programmierst solltest du mal nach der FileSelectionBox suchen.

Falls du mit VB (extern) programmierst kannst du den OpenFileDialog verwenden.

Grüsse Dominik

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Hallo Dominik,

ich habe erst mit diesem Thema begonnen und habe jetzt ein Problem. In Excel (Makro) habe ich das schon gemacht aber mit CATIA noch nicht. Das CATIA-Makro läuft super, es ist mir aber zu unflexibel.

Das ganze läuft als CATScript. Ich finde jedoch nichts zu "FileSelectionBox".
Das Aufzeichnen des Makros zum öffnen der Dateiauswahl funzt nicht. 
Hast Du vielleicht ein kleines Makro ?

Mit freundlichen Grüßen
Manni

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Hallo Manni
wegen dialog öffnen

Code:

---

myTabelle = CATIA.FileSelectionBox("FileOpen", "*.xlsx;*.xls", CatFileSelectionModeOpen)
If myTabelle <> "" Then
DEIN code

End If

---

somit ist mytabelle deine Punktedatei
Grüsse
Andy

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Hallo Andy,

sorry aber ich bring das Makro mit deinem Vorschlag nicht zum laufen.
Kannst Du mir bitte nochmals kurz helfen.
Habe das Makro aus dem Forum leicht angepasst.

Sub CATMain()
'Set CATIA = GetObject("", "CATIA.Application") ' wird nur benötigt, weil ich Excel als Entwicklungssumgebung benutze
  Dim Excel As Application
  Dim WB As Workbook
  Dim WS As Worksheet
 
  Set Excel = CreateObject("Excel.Application")            ' Excel starten
  Excel.Visible = True

  Set WB = Excel.Workbooks.Open("d:\punkte.xls")          ' Arbeitsmappe öffnen

  Set WS = WB.Worksheets.Item(1)                          ' Tabelle holen
 
  Set Part1 = CATIA.ActiveDocument.Part                  ' aktives part holen
  Set partDocument1 = CATIA.ActiveDocument
  Set HybShapeFac = Part1.HybridShapeFactory              'factory zu erstellen der Punkte
  Set HKoerper = CATIA.ActiveDocument.Part.HybridBodies  'hauptkörper holen zum einfügen der Punkte
  Set measurement_points = HKoerper.Add                  'Geoset einfügen
      measurement_points.Name = "Messpunkte"              'benennen
 
  nRow = 2                                                'ab Zeile 2 Zeile der Tabelle einlesen
 
  Do  'lesen bis EOF
      ' Spalte 1 = Name // Spalte 2,3,4 = Werte
    Element = (WS.Cells(nRow, 1).Value)
    XCoord = CDbl(WS.Cells(nRow, 2).Value)
    YCoord = CDbl(WS.Cells(nRow, 3).Value)
    ZCoord = CDbl(WS.Cells(nRow, 4).Value)
   
    Set hybridShapeFactory1 = Part1.HybridShapeFactory
    Set hybridShapePointCoord1 = hybridShapeFactory1.AddNewPointCoord(XCoord, YCoord, ZCoord)
    measurement_points.AppendHybridShape hybridShapePointCoord1    ' Punkt einfügen

    hybridShapePointCoord1.Name = Element                          ' Punkt benennen
        nRow = nRow + 1                                            ' Zeile hochzählen
    Loop While (WS.Cells(nRow, 2).Text <> "")                      ' Schleife verlassen, wenn Zelle leer ist
 
    Part1.Update                                                  ' Part aktualisieren

  Excel.Quit                                                      ' Excel schliessen

End Sub

Mit freundlichen Grüßen
Manni

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Hallo Manni
auf die schnelle mal dein script

Code:

---

Sub CATMain()
'Set CATIA = GetObject("", "CATIA.Application") ' wird nur benötigt, weil ich Excel als Entwicklungssumgebung benutze
  Dim Excel As Application
  Dim WB As Workbook
  Dim WS As Worksheet
dim mytabelle as String
myTabelle = CATIA.FileSelectionBox("FileOpen", "*.xlsx;*.xls", CatFileSelectionModeOpen)
If myTabelle <> "" Then

  Set Excel = CreateObject("Excel.Application")            ' Excel starten
  Excel.Visible = True

  Set WB = Excel.Workbooks.Open(mytabelle)          ' Arbeitsmappe öffnen

  Set WS = WB.Worksheets.Item(1)                          ' Tabelle holen

  Set Part1 = CATIA.ActiveDocument.Part                  ' aktives part holen
  Set partDocument1 = CATIA.ActiveDocument
  Set HybShapeFac = Part1.HybridShapeFactory              'factory zu erstellen der Punkte
  Set HKoerper = CATIA.ActiveDocument.Part.HybridBodies  'hauptkörper holen zum einfügen der Punkte
  Set measurement_points = HKoerper.Add                  'Geoset einfügen
      measurement_points.Name = "Messpunkte"              'benennen

  nRow = 2                                                'ab Zeile 2 Zeile der Tabelle einlesen

  Do  'lesen bis EOF
      ' Spalte 1 = Name // Spalte 2,3,4 = Werte
    Element = (WS.Cells(nRow, 1).Value)
    XCoord = CDbl(WS.Cells(nRow, 2).Value)
    YCoord = CDbl(WS.Cells(nRow, 3).Value)
    ZCoord = CDbl(WS.Cells(nRow, 4).Value)
 
    Set hybridShapeFactory1 = Part1.HybridShapeFactory
    Set hybridShapePointCoord1 = hybridShapeFactory1.AddNewPointCoord(XCoord, YCoord, ZCoord)
    measurement_points.AppendHybridShape hybridShapePointCoord1    ' Punkt einfügen

    hybridShapePointCoord1.Name = Element                          ' Punkt benennen
        nRow = nRow + 1                                            ' Zeile hochzählen
    Loop While (WS.Cells(nRow, 2).Text <> "")                      ' Schleife verlassen, wenn Zelle leer ist

    Part1.Update                                                  ' Part aktualisieren

  Excel.Quit                                                      ' Excel schliessen
end if

End Sub

---

versuch es mal! Hab es nur bis zum dialog schnell getestet!

Grüsse
Andy

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Hallo Andy,

alles klar hab das Makro hinbekommen und es läuft.

Vielen Dank für Deine Hilfe, das Problem ist gelöst.

Mit freundlichen Grüßen
Manfred

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP