---

Hallo,

stehe gerade vor einer Herausforderung (Problem).

Kann ich mittels VBA auf eine Access-Datenbank zugreifen?
Und wenn ja, wie?

Danke schonmal im Voraus.

MfG

VBAler

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

HAllo VBAler,

da deine Frage nichts mit CATIA V5 zu tun hat, habe ich sie in das VB-Brett verschoben.

Viele Grüße,

CEROG

------------------
Meine Firma  |  Website zum Buch |Technisches Zeichnen mit CATIA V5 | Mein CATIA-Blog

Wie stelle ich meine Fragen richtig?

---

Hey VBAler,

klar kannst du das machen.
Müsste mittels OLEDB und dem Pfad zur DB funktionieren!
Hab auf die Schnelle folgendes gefunden >>Klick<<.
Ist allerdings über DAO.
Viel Spass
HTH

Tobias

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Hi,

hab noch ein Bespiel gefunden

Code:

---

Private Sub CommandButton1_Click()
Dim adoCon As New ADODB.Connection
Dim adoRS As ADODB.Recordset
Dim field As ADODB.field
Dim DbDatei As String

  DbDatei = "E:\Projekte\Entw\vb6\tb_edbs3\vorlage.mdb"
 
  adoCon.CursorLocation = adUseClient
  adoCon.Open "PROVIDER=Microsoft.Jet.OLEDB.4.0;Data Source=" & DbDatei

  Set adoRS = New ADODB.Recordset
  adoRS.Open "select Folie,Elementardaten from EDBS_Surface_Folien Order by Folie", adoCon, adOpenStatic, adLockOptimistic

 
  ' Felder
  For Each field In adoRS.Fields
      Debug.Print field.Name & "  " & field.Type ' & .....
  Next field

  ' Der Reihe nach
  If adoRS.RecordCount > 0 Then
    adoRS.MoveFirst
    While Not adoRS.EOF
        Debug.Print adoRS("Folie").Value
        Debug.Print adoRS(0).Value
        Debug.Print adoRS("Elementardaten").Value
        Debug.Print adoRS(1).Value
        adoRS.MoveNext
    Wend
  End If
 
  ' Suchen
  adoRS.Filter = "Folie = '011'"
  Debug.Print adoRS.RecordCount
  ' oder oder
 
  ' Schliessen und aufräumen
  adoRS.Close
  adoCon.Close
  Set adoRS = Nothing
  Set adoCon = Nothing
 
End Sub

---

Jetzt kommt es noch drauf an was du machen willst.

Wilfried Stelberg

------------------
Warum lisp'eln wenn's auch anders geht.
www.ib-stelberg.de

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Hallo Wilfried,

kleiner Tipp, es geht auch ohne einen Verweis zu setzen. Das macht das ganze unabhängig von der Version. Nur die Konstanten müssen deklariert werden da sie ja nicht verfügbar sind. Beispiel:

Code:

---

Option Explicit

Private Const adUseClient = 3

Public Sub test()

    Dim objConnection As Object, objRecordset As Object
   
    On Error GoTo error_exit
   
    Set objConnection = CreateObject(Class:="ADODB.Connection")
    Set objRecordset = CreateObject(Class:="ADODB.Recordset")
   
    With objConnection
      .Provider = "Microsoft Jet 4.0 OLE DB Provider"
      .ConnectionString = "Data Source=D:\Eigene Dateien\Eigene Datenbanken\TestDB.mdb"
      .Open
    End With
   
    With objRecordset
      .ActiveConnection = objConnection
      .CursorLocation = adUseClient
      .Source = "SELECT tbl_Namen.* FROM tbl_Namen" 'Beispiel !!!
      .Open
    End With
   
    With objRecordset
        Do While Not .EOF
       
            MsgBox .Fields(0)
            .MoveNext
       
        Loop
    End With

error_exit:
    If CBool(Err.Number) Then MsgBox "Fehler " & CStr(Err.Number) & vbLf & vbLf & _
        Err.Description, vbCritical, "Fehlermeldung"
       
    If Not objRecordset Is Nothing Then objRecordset.Close
    If Not objConnection Is Nothing Then objConnection.Close
    Set objConnection = Nothing
    Set objRecordset = Nothing
   
End Sub

---

------------------
Gruß
Nepumuk 

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP