---

Hallo zusammen
Ich sollte ein script welches ein Praktikant in unserem Hause geschrieben hat noch ergänzen.

Hier noch der Auszug:
______________________________________________________________________
option explicit

Dim Abfrage , MyV5_File
Dim fso , fsoFile , wshell
Dim WSHShell
MyV5_File = "C:\Programme\MyV5\MyV5.txt"

set fso = CreateObject("Scripting.FileSystemObject")

if not fso.fileExists (MyV5_File) then
set fsoFile = FSO.OpenTextFile(MyV5_File , 2 , True)
Abfrage = inputbox ("Bitte defineiren sie den Standort" & Chr(13) & "Standort1 / Standort2 / Standort3","Standortabfrage","..")
if Abfrage = "STANDORT1" then
fsoFile.writeline "\\nws012\cad_pdm_admin$"
elseif Abfrage = "STANDORT2" then
fsoFile.writeline "\\nws022\cad_pdm_admin$"
elseif Abfrage = "STANDORT3" then
fsoFile.writeline "\\PASRV-14\cad_pdm_admin$"
elseif Abfrage = "standort1" then
fsoFile.writeline "\\nws012\cad_pdm_admin$"
elseif Abfrage = "standort2" then
fsoFile.writeline "\\nws022\cad_pdm_admin$"
elseif Abfrage = "standort3" then
fsoFile.writeline "\\PASRV-14\cad_pdm_admin$"
elseif Abfrage = "Standort1" then
fsoFile.writeline "\\nws012\cad_pdm_admin$"
elseif Abfrage = "Standort2" then
fsoFile.writeline "\\nws022\cad_pdm_admin$"
elseif Abfrage = "Standort3" then
fsoFile.writeline "\\PASRV-14\cad_pdm_admin$"
else
msgbox "Bitte einen gültigen Standort eingeben!"
End if
fsoFile.close
End if

Set WSHShell = WScript.CreateObject("WScript.Shell")
WshShell.Run "C:\programme\MyV5\myV5\smyV5.bat", 7,True
____________________________________________________________________
In diesem Script wird der Benutzer beim erstmaligem Anmelden gefragt an welchem Standort er sich befindet, gemäss seiner Eingabe wird ein File (MyV5.txt)erstellt worin definiert ist, von welchem Server er die Einstellungen synchronisieren soll und anschliessend wird ein Programm gestartet. Falls der Benutzer jedoch die Abfrage mit ESC Abbricht erstellt er das File MyV5.txt trotzdem (ohne Eintrag) und das Programm wird gestartet. Dies soll unterbunden werden.

Da ich in VB nicht so bewandert bin, frage ich euch an:
Wie muss das Script ergänzt werden, falls keine der entsprechenden Standorte gewählt wird oder die Abfrage mit ESC abgebrochen wird? Soll das File Myv5.txt wieder gelöscht werden, damit das Programm nicht startet.

Gruss und Dank.

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Morgen trainman,

versuche das mal so.

Erstellt das File nur, wenn ein passender Wert angegeben wurde.
Und gibt eine Meldung aus, falls die Datei schon existiert.

CU, Bernd
--

Code:

---

Option Explicit

Dim Abfrage, MyV5_File
Dim fso, fsoFile, wshell
Dim WSHShell
Dim strWert

MyV5_File = "C:\Programme\MyV5\MyV5.txt"

Set fso = CreateObject("Scripting.FileSystemObject")

If fso.fileExists(MyV5_File) Then
  MsgBox "Datei " & MyV5_File & " existiert bereist!"
Else
  Abfrage = InputBox("Bitte definieren sie den Standort" & Chr(13) & "Standort1 / Standort2 / Standort3", "Standortabfrage", "..")
  Select Case UCase(Abfrage)
      Case "STANDORT1": strWert = "\\nws012\cad_pdm_admin$"
      Case "STANDORT2": strWert = "\\nws022\cad_pdm_admin$"
      Case "STANDORT3": strWert = "\\PASRV-14\cad_pdm_admin$"
      Case Else: strWert = "": MsgBox "Bitte einen gültigen Standort eingeben!"
  End Select
End If

If strWert <> "" Then
  Set fsoFile = fso.OpenTextFile(MyV5_File, 2, True)
  fsoFile.writeline strWert
  fsoFile.Close
  Set WSHShell = WScript.CreateObject("WScript.Shell")
  WSHShell.Run "C:\programme\MyV5\myV5\smyV5.bat", 7, True
End If

---

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Hallo bst
Hat SUPER funktioniert!

Vielen Dank.

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP