---

Hallo zusammen
stehe vor folgendem Problem:
ich möchte aus VB direkt ein Powerpoint öffnen
Test = Shell("C:\Programme\Microsoft Office\Office\POWERPNT.EXE d:\Demo_Originale\test.ppt", 1)

Die Präsentation wird zwar geöffnet, aber es erscheint trotzdem eine Fehlermeldung:
Objektvariable oder With-Blockvariable nicht definiert

Kann mir jemand sagen, was ich falsch mache?

Gruss
san

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Hallo san,

ich empfehle dir die ShellExecute-Methode, sie hat den Vorteil, dass du den Pfad des Programms nicht kennen musst und eine Fehlerbehandlung mitgeliefert wird.

Option Explicit

Private Declare Function ShellExecute Lib "shell32.dll" _
        Alias "ShellExecuteA" (ByVal HWND As Long, ByVal lpOperation As String, _
        ByVal lpFile As String, ByVal lpParameters As String, _
        ByVal lpDirectory As String, ByVal nShowCmd As Long) As Long
       
Private Sub Command1_Click()
  Call ExecuteShell(Me.HWND, "Open", "d:\Demo_Originale\test.ppt")
End Sub

Public Function ExecuteShell(ByVal HWND As Long, _
                            ByVal Operation As String, _
                            ByVal sFileName As String, _
                            Optional ByVal Parameters As String = "", _
                            Optional ByVal Directory As String = "", _
                            Optional ByVal Show As Long = 1) As Boolean

Dim l As Long
  l = ShellExecute(HWND, Operation, sFileName, Parameters, Directory, Show)
  If l > 32 Then
    ExecuteShell = True
  Else
'    Fehlerbehandlung
  End If
End Function

HTH pablo

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP