Hallo,
anbei wie gewünscht das Makro.
1 Lastschritt: Vorspannung aufbringen
2 Lastschritt: Temperatureinfluss
Postscribt: Ausgabe der max. Verschiebung in X&Y-Richtung
tw - ist in diesem Fall eine Variabe und im "BeginLevel" mit 25°C definiert
!====================================================================================
!Vorspannung + thermische Last
!====================================================================================
fini
/cle
!---------------------------------BEGIN LEVEL----------------------------------------
/title,Dehnungsberechnung mit Vorspannung + thermische Last
!---Geometriedaten---
a=985 !Kantenlänge (quadrat) in [mm]
b=70 !Kantenlänge Aussparung in [mm]
d=0.25 !Dicke in [mm]
!---Materialdaten---
e1=1350 !E-Modul bei -40°C [N/mm²]
e2=1070 !E-Modul bei -10°C [N/mm²]
e3=950 !E-Modul bei 20°C [N/mm²]
e4=775 !E-Modul bei 50°C [N/mm²]
e5=330 !E-Modul bei 80°C [N/mm²]
v=0.47 !Querkontraktionszahl
q=0.0018 !Dichte in [g/mm²]
i1=9.9e-05 !Isotrope thermische Ausdehnung bei -40°C in [1/K]
i2=1.15e-04 !Isotrope thermische Ausdehnung bei -10°C in [1/K]
i3=1.3e-04 !Isotrope thermische Ausdehnung bei 20°C in [1/K]
i4=1.5e-04 !Isotrope thermische Ausdehnung bei 50°C in [1/K]
i5=2.1e-04 !Isotrope thermische Ausdehnung bei 80°C in [1/K]
t1=233.15 !Temperatur -40°C in [K]
t2=263.15 !Temperatur -10°C in [K]
t3=293.15 !Temperatur 20°C in [K]
t4=323.15 !Temperatur 50°C in [K]
t5=353.15 !Temperatur 80°C in [K]
treff=283.65 !Referenztemperatur 10,5°C in [K]283.65
!---Belastungsgrößen---
fs=6 !Vorspannung [N/mm²]
tw=298,15 !Temperatur 25°C in [K]
tk=271,65 !Temperatur -1,5°C in [K]
!---Vernetzungs-Konstanten---
na=20 !Elementgröße entlang der Quadratkanten
!-------------------------------PREPROCESSOR-----------------------------------------
/prep7 !Preprozessor starten
!---Elementvereinbarung---
et,1,281 !Shell - Membran
sectype,,shell,,Membran
secdata,d
!---Materialvereinbarung----
mptemp,1,233.15,263.15,293.15,323.15,353.15 !Temperaturen dem Material zuordnen
mp,reft,1,treff !Referenztemperatur
mpdata,ex,1,,e1,e2,e3,e4,e5 !E-Modul Temp.-abh.
mpdata,nuxy,1,,v,v,v,v,v !Querkontraktionszahl Temp.-abh.
mpdata,alpx,1,,i1,i2,i3,i4,i5 !thermisches Ausdehnungsverhalten Temp,-abh.
mp,dens,1,q !Dichte
!---Modellgenerierung---
rectng,0,a+2*b,0,a+2*b
rectng,0,b,0,b
rectng,a+b,a+2*b,0,b
rectng,0,b,a+b,a+2*b
rectng,a+b,a+2*b,a+b,a+2*b
asba,1,2
asba,6,3
asba,1,4
asba,2,5
adele,all
l,7,14
l,14,17
l,17,12
l,12,7
numcmp,line !Lines neu mummerieren
al,1,7,5,13
al,2,14,8,16
al,9,15,3,11
al,4,6,10,12
al,1,2,9,10
!---Vernetzung---
lesize,all,20
type,1
mat,1
mshkey,2
amesh,all
fini !Verlassen des Preprozessors
!----------------------------SOLUTION PROCESSOR--------------------------------------
/solu !Solutionprozessor starten
tref,treff !Referenztemp. für Berechnung setzten
!-Randbedingungen - Seiten ohne Vorspannung-
nsel,s,loc,y,0 !selectiert Nodes in y=0
d,all,uy,0 !selectierte nodes - verschiebung in y=0
d,all,uz,0 !selectierte nodes - verschiebung in z=0
allsl !Reselctierung
nsel,s,loc,x,0 !selectiert Nodes in x=0
d,all,ux,0 !selectierte nodes - verschiebung in x=0
d,all,uz,0 !selectierte nodes - verschiebung in z=0
allsel !Reselctierung
!-Randbedingungen - Seiten mit Vorspannung-
nsel,s,loc,x,a+2*b !selectiert Nodes in x=1140
d,all,uz,0 !selectierte nodes - verschiebung in z=0
allsel
nsel,s,loc,y,a+2*b !selectiert Nodes in y=1140
d,all,uz,0 !selectierte nodes - verschiebung in z=0
allsel
eplo !zeige Elemente
!-Last - Vorspannung-
nsel,s,loc,y,a+2*b
sf,all,pres,-fs !Vorspannung in y=1140
allsel
nsel,s,loc,x,a+2*b
sf,all,pres,-fs !Vorspannung in x=1140
allsel
/psf,pres,,2,1 !anzeigen der Vorspannung mit Preilen
eplo
!--- Lastfall-1---
time,1
nlgeom,on
solve !Berechnung starten
!---thermischer Lastfall-2---
time,2
bf,all,hgen,tw !Temp auf alle Nodes - hohe Temp.
nlgeom,on
solve !Berechnung starten
fini !Verlassen des Solutionprozessors
/eof
!------------------------------POSTPROCESSOR----------------------------------------
/post1 !Postprozessor starten
/SHOW,WIN32C !Verwende bessere Grafik
/CONTOUR,1,100,0, !100 Farben
allsel
*cfopen,result_umax,txt
*vwrite
('umaxX umaxY')
nsort,u,x
*get,MaxX,sort,,imax
*get,uX,node,MaxX,u,x
nsort,u,y
*get,MaxY,sort,,imax
*get,uY,node,MaxY,u,y
*vwrite,uX,uY
(e10.4,' ',e10.4)
Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP