---

Hi,

ich würde gerne ein Diagramm erstellen. Auf die x-achse soll die Verschiebung eines Knotens in Y-Richtung  und auf die Y-Achse die Summe aller Knotenkräfte im Modell in Y-Richtung.

Die Befehle die mir bislang als sinnvoll erschienen sind

nsol,node_uy,nodenumber,u,y (für die Verschiebung des Knotens)
fsum (für die Summe der Kräfte)

Hab versucht damit ne Schleife über die substeps zu basteln aber bislang ist da nichts sinnvolles bei rausgekommen:

*do,i,1,ns  (ns=number of substeps)
  set,sbstep,i
  fsum
  *get,fy,fsum,,item,fy
  nsol,displ,3621,u,y
  kraft(i)=fy
  displ(i)=displ
*enddo
xvar,displ
plvar,kraft

Viele Grüße 

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Unter der Voraussetzung , dass es Lösungen zu verschiedenen Zeitpunkten gibt, würde ich versuchen mit:

/post26
nsol,1,3621,u,y
nsol,2,3621,fy  !oder anderes nach Operationen
plva,2

------------------
Viel Erfolg wünscht
Wolfgang Schätzing

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Danke für die schnelle Antwort, aber das funktioniert nicht.

Auf die x-achse soll die verschiebung eines Knotens in y-Richtung.
Das bekomme ich so weit ich das jetzt richtig verstanden hab so hin:

/post26
nsol,2,1939,u,y
xvar,2

Auf die y-achse soll die Summe ALLER Knotenkräfte im Modell in Y-Richtung.
Mein Versuch sieht jetzt so aus:

/post1
*get,nsubsteps,active,,set,sbst
*dim,forcey,array,ns,1
*do,i,1,nsubsteps
  set,sbstep,i
  *get,forcey,fsum,,item,fy
  forcey(i,1)=forcey
*enddo

plvar,3
   
Allerdings kommt dann die Fehlermeldung "Parameter FORCEY needs subscripts".

MfG

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Wenn ich den Quelltext für ein kurzes (extrem abgerüstetes) Beispiel bekomme, sehe ich es mir an.

------------------
Viel Erfolg wünscht
Wolfgang Schätzing

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

lager.jpg lager2.jpg

! Lager ucp204
! [mm,s,kg,N]

finish
/clear,start
/prep7

! ---------------------------------------------------------------------------------------------------------------

! Elementtyp und Materialeigenschaften

et,1,plane183 ! Elementtyp1 = Plane183, high order 2D element mit quadratischen Ansatzfunktionen, 6/8 Knoten

mp,ex,1,21e4 ! Emodul = 210000 N/mm2
mp,prxy,1,0.3 ! Poissonzahl = 0.3

! Erzeugen der Geometrie

cyl4,0,0,20 ! Fläche1, Kreis
cyl4,0,0,17 ! Fläche2, Kreis
asba,1,2 ! Erzeugt Fläche3, Kreisring, löscht Flächen 1,2

cyl4,0,0,13 ! Fläche1
cyl4,0,0,10 ! Fläche2
asba,1,2 ! Erzeug Fläche4, Kreisring, löscht Flächen 1,2

cyl4,0,0,10 ! Fläche1, Kreis
cyl4,0,-15,2 ! Fläche2, Kreis

! Vernetzung der Flächen

esize,0.5,0 ! Globale Elementgröße = 0.5
amesh,all ! Vernetzt alle Flächen

! ----- Kontakte ------------------------------------------------------------------------------------------------

et,2,conta172  ! Conta172, 2D 3-Knoten Fläche-zu-Fläche Kontakt-Element, ON SELECTED NODES
et,3,targe169  ! Targe169, nicht durchdringbare Zielfläche für die Kontaktelemente, ON SELECTED LINES

! Target (1)

asel,s,area,,1
lsla,s
lsel,r,loc,y,0,-10
type,3
real,11
lmesh,all
alls

! Contact (1)

asel,s,area,,4
lsla,s
lsel,r,radius,,10
lsel,r,loc,y,0,-10
type,2
real,11
esurf
alls

! Target (2)

asel,s,area,,4
lsla,s
lsel,r,radius,,13
lsel,r,loc,y,0,-10
type,3
real,12
lmesh,all
alls

! Contact (2)

asel,s,area,,2
lsla,s
lsel,r,loc,y,-13,-15
type,2
real,12
esurf
alls

! Target (3)

asel,s,area,,2
lsla,s
lsel,r,loc,y,-15,-17
type,3
real,13
lmesh,all
alls

! Contact (3)

asel,s,area,,3
lsla,s
lsel,r,radius,,17
lsel,r,loc,y,0,-17
type,2
real,13
esurf
alls

! ------ Dirichlet und Neumann - RB --------------------------------------------------------------------------

asel,s,area,,3
lsla,s
lsel,r,radius,,20
dl,all,,all,0
alls

asel,s,area,,1
da,all,uy,-1
alls

nsel,s,loc,x,0
d,all,ux,0
alls

finish

! ------ Solution options ---------------------------

/solu

antype,static
nlgeom,on
nsubst,20,40,5
outres,all,all

solve

! ------ Postprocessing

  /post1

*get,lastsbst,active,,set,sbst
*dim,forcey,array,lastsbst

*do,i,1,lastsbst
    set,sbstep,i
    *get,forcey(i),fsum,,item,fy
  *enddo


/post26

numvar,200
nsol,2,1939,u,y

        xvar,2
plvar,forcey

!---------------------------

Bei dem Modell handelt es sich um ein Rillenkugellager im Schnitt.
Die mittlere Fläche stellt die Welle dar, die sich um uy verschiebt (infolge von Schwingungen).
Ich möchte die gesamte Kraft in Y-Richtung plotten, die das Lager der Verschiebung entgegenbringt, also den Steifigkeitsverlauf des Lagers in Radialrichtung.

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Folgende Sequenz müsste das Gewünschte machen:

! ------ Postprocessing
  /post1
set,last
*get,lastsbst,active,,set,sbst
*dim,forcey,table,lastsbst,2

*do,i,1,lastsbst
    set,sbstep,i
    fsum
    *get,forcey(i,1),fsum,,item,fy
    *get,forcey(i,2),node,1939,u,y
  *enddo

/axlab,x,uy
/axlab,y,fy
*vplot,forcey(1,2),forcey(1,1)

------------------
Viel Erfolg wünscht
Wolfgang Schätzing

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Vielen herzlichen Dank, das hat funktioniert! 

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP