Hallo Zusammen,
Ich mache meine Masterarbeit in ansys apdl,und möchte ich zugversuch eines stabes simulieren und am ende ein Kraft weg kurve erstellen,Ich habe es schon gemacht,aber leider fehlt mir nur die Haltezeit rein in simulation mitzubringen.
zu erst sollte die Kraft ansteigen bis zum fliessen dann dort eine haltezeit abgegeben und dann wieder kraftabfall.
mein apdl code ist wie gefolgt:
finish
/clear
/PREP7
stablaenge=600
huelsenlaenge=100
Drahtdurchmesser=11.4
ET,1,PLANE183
et,2,solid186
!Materialdaten fuer 375.0 Grad Celcius definieren:
MPTEMP,,375.0
! EX = Spannung[0]/Dehnung[0] !!
MPDATA, EX, 1,, 206608.7320824302
MPDATA, PRXY, 1,, 0.314620094503658
MPDATA, DENS, 1,, 7.850000e-009
MPDATA, MU, 1,, 0.1
TB, MISO, 1, 1, 9!Mat-Id 1, 1 Temperatur, 9 Datenpaare
!Spannung-Dehung von Material von den oben genannten Temperatur
TBPT, DEFI, 0.007745074675517, 1600.200058592283300
TBPT, DEFI, 0.008942098516976, 1656.999824651538100
TBPT, DEFI, 0.011331856158590, 1728.511427689995100
TBPT, DEFI, 0.013715947694540, 1765.623353752475200
TBPT, DEFI, 0.015698352765668, 1789.131883774720100
TBPT, DEFI, 0.021987640124426, 1826.508313539192400
TBPT, DEFI, 0.029856800408690, 1843.182969034318400
TBPT, DEFI, 0.050107640124426, 1880.380047505938100
TBPT, DEFI, 0.058887640124426, 1894.916864608075900
!Model erstellen
cyl4,,,4,90,
cyl4,,,4,,Drahtdurchmesser/2,90
lsel,s,,,8,9,1
lesize,all,,,2
lsel,s,,,2,3,1
lesize,all,,,4
lsel,s,,,1,4,3
lesize,all,,,6
!vernetzen von den oben erstellten Fläche
amesh,all
!eine lokale korrdinaten system default ist 10 und type 1 zylinder
local,11,1
!erzeugen von flächen anhand die vorherige erstellten fläche mit lokal korrdinaten systen 11 und 4 =gleiche flächen wie orginal
agen,4,all,,,,90,,11
nummerg,all
type,2
real,2
mat,1
esize,,100
vext,all,,,,,600
csys,1
nsel,s,loc,z,0,huelsenlaenge
!nplot
nsel,u,loc,x,0,(Drahtdurchmesser/2)-0.1
!nplot
cm,fest_knoten,node !
nsel,s,loc,z,stablaenge,stablaenge+1
cm,slave_nodes,node
allsel
*get,numbermaxNode,NODE,,num,max
numbermaxNode1=numbermaxNode+1
*get,numbermaxElem,elem,,num,max
numbermaxElem1=numbermaxElem+1
! Define surface-based constraint type of pair
MAT,1
R,3
ET,3,170
ET,4,174
KEYOPT,4,12,5!
KEYOPT,4,4,2
KEYOPT,4,2,2
KEYOPT,3,2,1
KEYOPT,3,4,111111
TYPE,3
Real,3
! Erstellen von Pilot Knoten
pilot_node=numbermaxNode1
N,numbermaxNode1, 0,0,600
TSHAP,PILO
EN,numbermaxElem1,pilot_node
tshape
CMSEL,S,slave_nodes
! Generate the contact surface
REAL,3
TYPE,4
CMSEL,S,slave_nodes
ESURF
ALLSEL
! Hinzufuegen zum Festhalten am Pilotknoten
R,5
ET,5,170
ET,6,174
KEYOPT,6,12,5
KEYOPT,6,4,2
KEYOPT,6,2,2
KEYOPT,5,2,1
KEYOPT,5,4,111111
TYPE,5
Real,5
! Erstellen der Pilot-Knoten wo die Festhaltung erfolegen soll
pilot_node2=numbermaxNode1+1
N,numbermaxNode1+1, 0,0,0
TSHAP,PILO
EN,numbermaxElem1+1,pilot_node2
tshape
CMSEL,S,slave_nodes
! Generate the contact surface
REAL,5
TYPE,6
cmsel,s,fest_knoten
ESURF
ALLSEL
d,pilot_node2,all
csys,0
! Aufruf des Loesungsmoduls
/solu
ANTYPE,0
nlgeom,on
outres,all,all !
time,1
nsubst,10,100,10
!alles selektieren
alls
f,pilot_node,fz,170000
LNSRCH,ON
NEQIT,60
solve
/post26
NSOL,2,pilot_node,U,Z,UZ
RFORCE,3,pilot_node2,F,Z,FZ
PROD,4,3, , ,RF, , ,-1 !Wegen Vorzeichen
PRVAR,UZ,RF !Listing variablen
!kann man speichern als Textdatei
! Kraft-Weg-Kurve exportieren und file*.png (mit
! geaenderten Hintergrundfarben) erzeugen/speichern
/SHOW,PNG
/GRAPHICS,FULL
PNGR,TMOD,1
/RGB,INDEX,100,100,100,0
/RGB,INDEX,0,0,0,15
/AXLAB,X,displacement UZ
/AXLAB,Y,force FZ
XVAR,2
PLVAR,4
/SHOW,CLOSE
/post1
*dim,label,char,1,2
label(1,1)='Weg'
label(1,2)='Kraft'
*dim,_uz,,10 ! 10 entspricht der Substeps-Anzahl
*dim,_fz,,10 ! nsubst,10,100,10
*do,i,1,10
set,1,i
*get,_uz(i),node,pilot_node,u,z
*get,fz1,node,pilot_node2,rf,fz
_fz(i)=-fz1 !Wegen Vorzeichen
*enddo
! Datenpunkte in csv-Datei speichern
*cfopen,test,csv
*vwrite,label(1,1),label(1,2)
(A12,2x,A12)
*vwrite,_uz(1),_fz(1)
(E12.6,2x,E12.6)
*cfclos
finish
Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP