Moin,
ich habe gerade Problem mit den Einstellungen bzgl. der "Penetration" bei den Contact Elements. Das Modell selber funktioniert bei etwas anderen Randbedingungen bereits. Und auch die Konvergenz ist ein Problem, weshalb man mit CNVTOL noch am Konvergenzkriterium drehen muss damit es konvergiert. Wäre super wenn da jemand noch einen Tipp hätte, da ich langsam schon alles ausprobiert habe (FKTOLN, PINB, verschiedene Keyopts..)
Es geht um folgendes Delaminationsproblem: Ein eingesägter Balken wird so belastet, dass sich der Riss weiter ausbreitet:
Folgende Kurve soll dabei rauskommen:
(Quelle: Matzenmiller, Uni Kassel)
Bis zum Knick wird noch nichts delaminiert, daher ein linearer Anstieg, bis dann sich der Riss fortbildet und daher die Kraft abnimmt. Ab diesem Punkt treten auch die Probleme bei meinem Modell auf, Fehlermeldungen sind:
"3D contact elements have too much penetration"
"contact elements change status abruptly"
"there are x-Anzahl small pivot terms"
Vielen Dank schon mal!
FINISH
/CLEAR
/PREP7
ET,1,SOLID185
ET,2,SOLID185
ET,3,TARGE170
ET,4,CONTA173
!KEYOPT,4,9,1 ! Penetration Option
KEYOPT,4,12,5 ! Bonded Option
! ------------------------------
MP,EX,1,130000 ! (N/mm^2)
MP,EY,1,8000
MP,EZ,1,8000
MP,GXY,1,6000
MP,GYZ,1,6000
MP,GXZ,1,6000
MP,PRXY,1,0.3
MP,PRXZ,1,0.3
MP,PRYZ,1,0.3
TB,CZM,2,1,1,CBDE
TBDATA,1,48,0.257,48,0.856,1.E-8
! ------------------------------
Geometrie (mm):
b=24 ! Breite
l=105 ! Länge
thk=3.1 ! Dicke gesamt
! Volumen obere Hälfte des Balkens:
K,1,0,0,0
K,2,l,0,0
K,3,l,b,0
K,4,0,b,0
K,5,0,0,-thk/2
K,6,l,0,-thk/2
K,7,l,b,-thk/2
K,8,0,b,-thk/2
V,1,2,3,4,5,6,7,8
! Volumen untere Hälfte des Balkens:
K,9,0,0,-thk/2
K,10,l,0,-thk/2
K,11,l,b,-thk/2
K,12,0,b,-thk/2
K,13,0,0,-thk
K,14,l,0,-thk
K,15,l,b,-thk
K,16,0,b,-thk
V,9,10,11,12,13,14,15,16
! ------------------------------
! Anzahl Elemente in der Dicke:
LSEL,S,LOC,x,l
LSEL,r,LOC,y,0
LESIZE,ALL,0.75
LSEL,S,LOC,x,0
LSEL,r,LOC,y,0
LESIZE,ALL,0.75
LSEL,S,LOC,x,l
LSEL,r,LOC,y,b
LESIZE,ALL,0.75
LSEL,S,LOC,x,0
LSEL,r,LOC,y,b
LESIZE,ALL,0.75
! Anzahl Elemente in der Breite:
LSEL,S,LOC,x,0
LSEL,r,LOC,z,0
LESIZE,ALL, , ,20
LSEL,S,LOC,x,0
LSEL,r,LOC,z,-thk/2
LESIZE,ALL, , ,20
LSEL,S,LOC,x,0
LSEL,r,LOC,z,-thk
LESIZE,ALL, , ,20
LSEL,S,LOC,x,l
LSEL,r,LOC,z,0
LESIZE,ALL, , ,20
LSEL,S,LOC,x,l
LSEL,r,LOC,z,-thk/2
LESIZE,ALL, , ,20
LSEL,S,LOC,x,l
LSEL,r,LOC,z,-thk
LESIZE,ALL, , ,20
! Anzahl Elemente in der Länge:
LSEL,S,loc,y,0
LSEL,r,loc,z,0
LESIZE,ALL, , ,60
LSEL,S,loc,y,0
LSEL,r,loc,z,-thk/2
LESIZE,ALL, , ,60
LSEL,S,loc,y,0
LSEL,r,loc,z,-thk
LESIZE,ALL, , ,60
LSEL,S,loc,y,b
LSEL,r,loc,z,0
LESIZE,ALL, , ,60
LSEL,S,loc,y,b
LSEL,r,loc,z,-thk/2
LESIZE,ALL, , ,60
LSEL,S,loc,y,b
LSEL,r,loc,z,-thk
LESIZE,ALL, , ,60
ALLSEL,ALL
! Mesh untere Hälfte des Balkens:
TYPE,1
MAT,1
LOCAL,11,0,0,0,0
ESYS,11
VMESH,2
! Mesh obere Hälfte des Balkens:
CSYS,0
TYPE,2
ESYS,11
VMESH,1
! Target Elements (oben):
CSYS,0
TYPE,3
MAT,2
REAL,3
ESEL,S,TYPE,,2
NSLE,S
NSEL,R,LOC,Z,-thk/2
NSEL,R,LOC,X,0,60
ESURF
! Contact Elements (unten):
TYPE,4
REAL,3
RMODIF,3,3,-1E5 ! FKN (=elastische Anfangssteigung Dm)
RMODIF,3,12,-1E5 ! FKT (=elastische Anfangssteigung Dm)
!RMODIF,3,6,0.2 ! PINB
ESEL,S,TYPE,,1
NSLE,S
NSEL,R,LOC,Z,-thk/2
NSEL,R,LOC,X,0,60
ESURF
! ------------------------------
! Boundary Conditions:
ALLSEL,ALL
NSEL,S,LOC,X,0
D,ALL,ALL
NSEL,ALL
FINISH
! ------------------------------
/SOLU
NLGEOM,ON
TIME,1
NSUBST,100,100,100
OUTRES,ALL,ALL
CNVTOL,U,16,0.2
u=16 ! Verschiebung wie in Grafik
ESEL,S,TYPE,,2
NSLE,S
NSEL,R,LOC,X,105
NSEL,R,LOC,Z,0
D,ALL,UZ,u
NSEL,ALL
ESEL,ALL
SOLVE
FINISH
! Kraft/Weg-Kurve Plotten:
/POST26
NSEL,S,LOC,X,105
NSEL,R,LOC,Z,0
NSEL,R,LOC,Y,12
*GET,NTOP,NODE,0,NUM,MAX
NSEL,ALL
NSOL,2,NTOP,U,Z,UZ
RFORCE,3,NTOP,F,Z,FZ
PROD,4,3, , ,RF, , ,9
/AXLAB,X, u (mm)
/AXLAB,Y, F (N)
/YRANGE,0,200
XVAR,2
PLVAR,4
Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP
Foren auf CAD.de
| 
