---

Modell.JPG

Hallo,

ich versuche Wirbelströme in einer Platte zu berechen und komme nicht weiter. Das Modell ist so aufgebaut, wie im Punkt 4.4 im Buch FEM für Praktiker, Band 4 2. Auflage. Im Gegensatz zum Beispiel im Buch, wird die Spule wird von einer Spannungsquelle in Reihe mit einem Widerstand (also ohne C und L) siuns-förmig gespeist. Die Berechnung erfolgt im eingeschwungenen Zustand, also harmonisch.
Speisestrom, Flussdichte im Innern der Spule ohne Platte sind erwartungsgemäß.
Füge ich die Platte (solid97,1 mit VOLT und AZ als Freiheitsgrad, keine Kopplung von Freiheitsgraden) in die Mitte der Spule ein, erfolgt die Rechnung ohne Angabe von Warnungen oder Fehlern. Beim Versuch, die Wirbelströme darzustellen mit dem Code:

/post1
set,1,1,,1
esel,s,mat,,3
plve,jt !Vektor Stromdichte

plesol,jt,sum !Summe

etable,strd,jt,x
pletab,strd,avg

kann man keine Stromdichte feststellen. Auch ist das Feld im Innern der Spule so, als wäre keine Platte darin enthalten. Muss noch irgendein Flag gesetzt werden, oder ist solid97,1 nicht der richtige elemttyp.

Hat jemand eine Idee?

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Schon mal mit solid97,0 probiert?

------------------
Viel Erfolg wünscht
Wolfgang Schätzing

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Ergebnis.JPG

Hallo Herr Dr. Schätzing,

vielen Dank für die schnelle Antwort.
Ja, hab ich schon ausprobiert. Es ist das gleiche Ergebnis. Ich dachte aber, dass man als Freiheitsgrad VOLT und AZ haben muss. Zumindest meinte ich das beim Beispiel 4.7 so rausgelesen zu haben. Da werden ja auch Ströme in das Rohr eingekoppelt. Daran hatte ich mich orientiert und deshalb solid97,1. Aber es hat eh keinen Effekt. Hier der Quelltext meines Programms:

!Wicklung 3D
!Stromgespeist
!nach 4.4

finish
/clear

!---------Variablen----------------------------------
wiho=0.775 !Wickelhöhe
wiradin=0.75 !Wickelradius innen
wiradau=0.8 !Wickelradius außen
widi=wiradau-wiradin !Wickelungsdicke
wianz=48 !Windungsanzahl
radau=1.6 !Radius außen
wifla=wiho*widi !Wickelfläche
pi=3.1416
wivol=wiho*(pi*wiradau*wiradau-pi*wiradin*wiradin)

plabrei=1 !Plattenbreite
plaho=1 !Plattenhöhe
pladi=0.002 !Plattenhöhe

mw=wiradau/10 !Maschenweite

!---------Beschaltung--------------------------------

sp=280 !Spannung
widerst=1 !Widerstand
freq=250 !Frequenz

wkappa=56e6 !spez. Leitfähigkeit Kupfer
kappaalu=37e6 !spez. Leitfähigkeit Alu

pi=4*atan(1)
abm=radau !Schaltungsabmessungen

/prep7
et,1,solid97,0 !Luft, 3D-Element->static domain
et,2,solid97,0 !Platte, VOLT und AZ als DOF nötig
et,3,solid97,3 !circuit coupled stranded coil
et,4,infin111,1 !Randelement
et,7,circu124,0 !Widerstand
et,8,circu124,4,0 !Spannungsquelle, sinus
et,9,circu124,5 !Koppelelment->3D/stranded coil

!--------Material Prperties--------------------------
mp,murx,1,1  !rel Permeabilität Luft
mp,murx,2,1  !rel Permeabilität Kupfer
mp,rsvx,2,1/wkappa !spez. Leitfähigkeit Kupfer
mp,rsvx,3,1/kappaalu !spez. Leitfähigkeit Alu
mp,murx,3,1

/view,,1,2,3 !anderer Blickwinkel

!-------Reale Konstanten-----------------------------
r,1,wifla,wianz,wivol,0,1,0 !Spule
r,7,widerst !Widerstand

!real,nr,ampl,phase,graphical offset,ID
r    , 8,sp  ,0    ,0              ,0

r,9,1 !Koppelelment

!----Geometrie---------------------------------------
cylind,wiradin,wiradau,-wiho/2,wiho/2,-90,90
cylind,wiradin,wiradau,-wiho/2,wiho/2,90,270
vglue,all !Aus V1 und V3 wird
numcmp,volu,all !V1 und V2

sphere,,radau,-90,90 !V3
sphere,,radau,90,270 !V4
vglue,3,4 !V3,5
numcmp,volu !V3,4
vovlap,all !V1,2,5,6
numcmp,volu !V1,2,3,4
!V1,2: Wicklung V3,4: Umgebung

block,-plabrei/2,plabrei/2,-plaho/2,plaho/2,-pladi/2,pladi/2
!V5

!-----------Vernetzung--------------------------------
!Stromführende Bereiche möglichst mit Quadern vernetzen!!!
!-----------Leiter------------------------------------
esize,mw*2 !grob vernetzt, da Stromverteilung
!esize,mw !auf Spule egal ist, ist nur Feldquelle
type,3
mat,2
real,1
mshkey,1 !mapped meshing
mshape,0,3d !quaderförmige Vernetzung, 3D
vmesh,1,2
!-----------Luft--------------------------------------
esize,mw*4
type,1
mat,1 !Leiter
mshkey,0 !free meshing
mshape,1,3d !Tetraeder
vmesh,3,4 !Feuer frei
!----------Platte-------------------------------------
esize,mw*2
type,2
mat,3
mshkey,1 !mapped meshing
mshape,0,3d !Quaderförmig
vmesh,5

!-----------Randelemente--------------------------------------
csys,2 !Kugelkoordinaten
type,4 !Randelemente
esize,,1 !ein Element dick
asel,s,ext !Außenflächen
vext,all,,,mw !volume from extruding areas
nsel,s,ext !Externe Knoten gewählt
sf,all,inf !infin111 Flag gesetzt
csys,0 !kart. Koord

!----------Freiheitsgradfestlegung für Wicklung---------------
esel,s,type,,3 !Elemente der Wicklung gewählt
nsle !Knoten gewählt
cp,1,curr,all !Kopplung des Stromes
cp,2,emf,all !Kopplung des Feldes
*get,knr1,node,0,num,max !Knoten für Kopplung zum Netzwerk

!---------Kopplung der Plattenelemente------------------------
!esel,s,mat,,3 !Plattenelemente ausgewählt
!nsle !Knoten ausgewählt
!cp,3,volt,all !Potenzial gekoppelt-->Gesamtstrom=0

!----------Elementkoordinaten---------------------------------
local,11,1 !lokale Zylinderkoordinaten
emodif,all,esys,11 !Elementkoordinatensystem
csys,0 !Kartesische KOORD.

!----------Speisende Schaltung--------------------------------
allsel !Selectionen aufgehoben
numcmp,node !Nummerierung Knoten komprimieren
*get,knr,node,,num,max !höchste Knotennummer rausgesucht
n,knr+1,-2.5*abm,0,0 !node,nodenumber,x,y,z
n,knr+2,-2.5*abm,abm,0
n,knr+3,-2*abm,abm,0
n,knr+4,-1.5*abm,abm,0
n,knr+5,0,0,0 !leer für Spannungsquelle

!---------Vereinbarung der Schaltungselemente-----------------
type,7 !Widerstand
real,7 !Kondesatorspannung und Kapazität
e,knr+1,knr+2 !sitzt zwischen Knoten 1 und 2

type,8 !Spannungsquelle hat 3 Knoten
real,8
e,knr+2,knr+3,knr+5 !Einer hängt "in der Luft"

type,9 !Koppelelement
real,9
e,knr+3,knr+4,knr1
eplot

!---------Bezugsknoten der Schaltung auf Masse----------------
nsel,s,node,,knr+1
nsel,a,node,,knr+4
d,all,volt,0
allsel
eplot

!---------Lösung----------------------------------------------
/solu
allsel
antype,harm !Harmonisch
harfrq,freq !Frequenz
solve

!-----Flussdichte auf Pfad------------------------------------
/post1
path,pfad,2,,400 !Pfadvereinbarung zwischen 2
!Punkten mit 200 Stützstellen
ppath,1,node,0,0,-1.5 !Knoten 1
ppath,2,node,0,0,1.5 !Knoten 2
!-----Magnetflussdichte---------------------------------------
pdef,fludi,b,z !Definition der Größe, Magnetflussdichte
plpath,fludi !Plotten der Flussdichte

!--------Strom durch Widerstand-------------------------------
set,1,1,,0 !Real Part
esel,s,type,,7 !Vorwiderstand
presol,amps

set,1,1,,1 !Imaginary Part
esel,s,type,,7 !Vorwiderstand
presol,amps

/post1
set,1,1,,1
esel,s,mat,,3
!plve,jt
plesol,jt,sum

etable,strd,jt,x
pletab,strd,avg

Vielleicht ist auf Anhieb etwas falsches erkennbar.

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Ja, ist es!
Die Platte ist nicht mit der Restgeometrie verbunden. Es fehlt das vovlap nach der Generierung der Platte.

Für die Vernetzung der Platte mit Hexaedern sollte die Geometrie weiter unterteilt werden. (Achtelkugeln usw.)

soldid97,1 für die Platte war richtig.

------------------
Viel Erfolg wünscht
Wolfgang Schätzing

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Strom.JPG

Vielen Dank für den Tip. Hab das vovlap Kommando eingefügt. Leider kann ich noch keinen Strom sehen. Hier der aktuelle Quellcode:

!Wicklung 3D
!Stromgespeist
!nach 4.4

finish
/clear

!---------Variablen----------------------------------
wiho=0.775 !Wickelhöhe
wiradin=0.75 !Wickelradius innen
wiradau=0.8 !Wickelradius außen
widi=wiradau-wiradin !Wickelungsdicke
wianz=48 !Windungsanzahl
radau=1.6 !Radius außen
wifla=wiho*widi !Wickelfläche
pi=3.1416
wivol=wiho*(pi*wiradau*wiradau-pi*wiradin*wiradin)

plabrei=1 !Plattenbreite
plaho=1 !Plattenhöhe
pladi=0.002 !Plattenhöhe

mw=wiradau/10 !Maschenweite

!---------Beschaltung--------------------------------

sp=280 !Spannung
widerst=1 !Widerstand
freq=250 !Frequenz

wkappa=56e6 !spez. Leitfähigkeit Kupfer
kappaalu=37e6 !spez. Leitfähigkeit Alu

pi=4*atan(1)
abm=radau !Schaltungsabmessungen

/prep7
et,1,solid97,0 !Luft, 3D-Element->static domain
et,2,solid97,0 !Platte, VOLT und AZ als DOF nötig
et,3,solid97,3 !circuit coupled stranded coil
et,4,infin111,1 !Randelement
et,7,circu124,0 !Widerstand
et,8,circu124,4,0 !Spannungsquelle, sinus
et,9,circu124,5 !Koppelelment->3D/stranded coil

!--------Material Properties--------------------------
mp,murx,1,1  !rel Permeabilität Luft
mp,murx,2,1  !rel Permeabilität Kupfer
mp,rsvx,2,1/wkappa !spez. Leitfähigkeit Kupfer
mp,rsvx,3,1/kappaalu !spez. Leitfähigkeit Alu
mp,murx,3,1

/view,,1,2,3 !anderer Blickwinkel

!-------Reale Konstanten-----------------------------
r,1,wifla,wianz,wivol,0,1,0 !Spule
r,7,widerst !Widerstand

!real,nr,ampl,phase,graphical offset,ID
r    , 8,sp  ,0    ,0              ,0

r,9,1 !Koppelelment

!----Geometrie---------------------------------------
cylind,wiradin,wiradau,-wiho/2,wiho/2,-90,90
cylind,wiradin,wiradau,-wiho/2,wiho/2,90,270
vglue,all !Aus V1 und V3 wird
numcmp,volu,all !V1 und V2

sphere,,radau,-90,90 !V3
sphere,,radau,90,270 !V4
vglue,3,4 !V3,5
numcmp,volu !V3,4

block,-plabrei/2,plabrei/2,-plaho/2,plaho/2,-pladi/2,pladi/2
!V5
vovlap,all !V1,2,6,7,8,9
numcmp,volu !V1,2,3,4,5,6

!V1,2: Wicklung, V3,4: Platte,  V5,6:Luft 

!-----------Vernetzung--------------------------------
!Stromführende Bereiche möglichst mit Quadern vernetzen!!!
!-----------Leiter------------------------------------
esize,mw*2 !grob vernetzt, da Stromverteilung
!esize,mw !auf Spule egal ist, ist nur Feldquelle
type,3
mat,2
real,1
mshkey,1 !0=free meshing, 1=mapped
mshape,0,3d !1=Tetraeder,0=hexaeder
vmesh,1,2

!----------Platte-------------------------------------
esize,mw/2
type,2
mat,3
mshkey,0 !free meshing
mshape,1,3d !Tetraeder
vmesh,3,4

!-----------Luft--------------------------------------
esize,mw*6
type,1
mat,1 !Luft
mshkey,0 !
mshape,1,3d !
vmesh,5,6 !Feuer frei

!-----------Randelemente--------------------------------------
csys,2 !Kugelkoordinaten
type,4 !Randelemente
esize,,1 !ein Element dick
asel,s,ext !Außenflächen
vext,all,,,mw !volume from extruding areas
nsel,s,ext !Externe Knoten gewählt
sf,all,inf !infin111 Flag gesetzt
csys,0 !kart. Koord

!----------Freiheitsgradfestlegung für Wicklung---------------
esel,s,type,,3 !Elemente der Wicklung gewählt
nsle !Knoten gewählt
cp,1,curr,all !Kopplung des Stromes
cp,2,emf,all !Kopplung des Feldes
*get,knr1,node,0,num,max !Knoten für Kopplung zum Netzwerk

!----------Elementkoordinaten---------------------------------
local,11,1 !lokale Zylinderkoordinaten
emodif,all,esys,11 !Elementkoordinatensystem
csys,0 !Kartesische KOORD.

!----------Speisende Schaltung--------------------------------
allsel !Selectionen aufgehoben
numcmp,node !Nummerierung Knoten komprimieren
*get,knr,node,,num,max !höchste Knotennummer rausgesucht
n,knr+1,-2.5*abm,0,0 !node,nodenumber,x,y,z
n,knr+2,-2.5*abm,abm,0
n,knr+3,-2*abm,abm,0
n,knr+4,-1.5*abm,abm,0
n,knr+5,0,0,0 !leer für Spannungsquelle

!---------Vereinbarung der Schaltungselemente-----------------
type,7 !Widerstand
real,7 !Kondesatorspannung und Kapazität
e,knr+1,knr+2 !sitzt zwischen Knoten 1 und 2

type,8 !Spannungsquelle hat 3 Knoten
real,8
e,knr+2,knr+3,knr+5 !Einer hängt "in der Luft"

type,9 !Koppelelement
real,9
e,knr+3,knr+4,knr1
eplot

!---------Bezugsknoten der Schaltung auf Masse----------------
nsel,s,node,,knr+1
nsel,a,node,,knr+4
d,all,volt,0
allsel
eplot

!---------Lösung----------------------------------------------
/solu
allsel
antype,harm !Harmonisch
harfrq,freq !Frequenz
solve

!-----Flussdichte auf Pfad------------------------------------
/post1
path,pfad,2,,400 !Pfadvereinbarung zwischen 2
!Punkten mit 200 Stützstellen
ppath,1,node,0,0,-1.5 !Knoten 1
ppath,2,node,0,0,1.5 !Knoten 2
!-----Magnetflussdichte---------------------------------------
pdef,fludi,b,z !Definition der Größe, Magnetflussdichte
plpath,fludi !Plotten der Flussdichte

!--------Strom durch Widerstand-------------------------------
set,1,1,,0 !Real Part
esel,s,type,,7 !Vorwiderstand
presol,amps

set,1,1,,1 !Imaginary Part
esel,s,type,,7 !Vorwiderstand
presol,amps

!-------Stromplot---------------------------------------------

/post1
set,1,1,,1
esel,s,mat,,3
!plve,jt
plesol,jt,sum

etable,strd,jt,x
pletab,strd,avg

esel,s,type,,2
plve,jt

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

marikrau2.txt marikrau.jpg

Ich sehe eine Stromdichte. Allerdings ist unbedingt zu empfehlen, die Platte mit Hexaedern zu vernetzen.
(Wir sind von unserem Moderator angehalten, längere Quelltexte in einen Anhang zu stecken.)

------------------
Viel Erfolg wünscht
Wolfgang Schätzing

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Vielen Dank Herr Dr. Schätzing. Das Programm läuft.

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Sehr geehrter Herr Dr. Schätzing, Kopplung der Knoten an der Platte wurde entfernt. Ich dachte die sei nötig, damit der Gesamtstrom =0 wäre.

Ich sehe gerade, dass es sowieso von vornherein auskommentiert gewesen ist.
Mein Fehler.

[Diese Nachricht wurde von Petrov am 25. Jan. 2012 editiert.]

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP