---

Hallo Zusammen,

ich bin neu im Ansys programmieren und habe ein kleines Problem. Für jmd mit etwas Kenntniss wird die Frage sicher leicht zu beantworten sein.
Mein Ziel ist ein 8-Eck mit Tiefe t zu erstellen und dieses mit 4 Bohrungen zu versehen.
Wenn ich den Code komplett ausführe zeigt er drei Bohrungen korrekt also als subtrahiert an, die vierte allerdings noch als Fläche bzw Volumen. Sobald ich das erzeugte 8-Eck drehe werden alle Bohrungen "normal" angezeit, also so als ob sie nie von der eigentlichen 8-Eck Fläche subtrahiert wurden.
Ist dies nur ein visueller Fehler von Ansys oder ist in meinem Code fehlerhaft.
C***
FINISH
/CLEAR
C***Parameter

/PREP7                          ! öffnet den Preprozessor
et,1,solid185                  ! Elementtyp ebene Spannung mit Dicke
MP,EX,1,200000                  ! E-Modul
MP,PRXY,1,0.3                  ! Querkontraktionszahl

C***Parameter
t=-5 !Tiefe
d=3.5 !Durchmesser Haken

/pnum,line,1
/pnum,area,1

C***  Geometrie
K,1,0,10,0  !Keypoints für 8-Eck
K,2,10,20,0
K,3,90,20,0
K,4,100,10,0
K,5,100,-10,0 
K,6,90,-20,0
K,7,10,-20,0
K,8,0,-10,0
L,1,2 !Keypoints zu 8-Eck verbinden
L,2,3
L,3,4
L,4,5
L,5,6
L,6,7
L,7,8
L,8,1
AL,ALL !Area erzeugen
K,9,0,-10,t !Keypoint für Extrude Befehl
L,9,8
VEXT,ALL,,,0,0,t !8-Eck mit Tiefe t
CYL4,10,10,5,,,,t !4 Bohrungen mit Tiefe t
CYL4,10,-10,5,,,,t 
CYL4,90,10,5,,,,t
CYL4,90,-10,5,,,,t
ASBA,1,12 !Bohrungen von 8-Eck subtrahieren
ASBA,27,16
ASBA,28,20
ASBA,27,24

Vielen dank für eure Hilfe.

Für Verbesserungsvorschläge bezüglich schönerer Programmierung wäre ich ebenfalls dankbar.
Danke für eure Hilfe.

Viele Grüße
Christopher

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Eleganter geht es noch, aber so funktioniert es schon mal. Du hast erst das Volumen erzeugt und dann die Flächen abgezogen, umgekehrt sollte es aber sein. Außerdem gibst du bei dem vext Befehl schon die Dicke an und brauchst deshalb den Keypoint 9 gar nicht.

FINISH
/CLEAR
!C***Parameter
/PREP7                          ! öffnet den Preprozessor
et,1,solid185                  ! Elementtyp ebene Spannung mit Dicke
MP,EX,1,200000                  ! E-Modul
MP,PRXY,1,0.3                  ! Querkontraktionszahl
!C***Parameter
t=-5 !Tiefe
d=3.5 !Durchmesser Haken
/pnum,line,1
/pnum,area,1
!C***  Geometrie
K,1,0,10,0  !Keypoints für 8-Eck
K,2,10,20,0
K,3,90,20,0
K,4,100,10,0
K,5,100,-10,0
K,6,90,-20,0
K,7,10,-20,0
K,8,0,-10,0
L,1,2 !Keypoints zu 8-Eck verbinden
L,2,3
L,3,4
L,4,5
L,5,6
L,6,7
L,7,8
L,8,1
AL,ALL !Area erzeugen
CYL4,10,10,5 !4 Bohrungen mit Tiefe t
CYL4,10,-10,5
CYL4,90,10,5
CYL4,90,-10,5
ASBA,1,2
ASBA,6,3
ASBA,1,4
ASBA,2,5
vext,all,,,0,0,t,
finish

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Danke klappt jetzt super !

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP