---

Hallo,

ich versuche gerade das Verhalten eines Knickstabes nach dem 4. Eulerfall zu simulieren. Die Knickkraft zu berechnen haut super hin. Was irgendwie gar nicht funktioniert ist ein darstellen der Verschiebung am Kraftangriffspunkt in Abhängigkeit der Kraft. Dazu habe ich ein Tutorial für den 1. Eulerfall umgeschrieben. Hat jemand ne Idee, was ich falsch mache?

Hier der Code:

FINISH ! These two commands clear current data
/CLEAR
/TITLE,Eigenvalue Buckling Analysis
/PREP7 ! Enter the preprocessor
ET,1,BEAM3 ! Define the element of the beam to be buckled
R,1,.5,1.666667E-3,.2 ! Real Consts: type 1, area (mm^2), I (mm^4), height (mm)
MP,EX,1,210000 ! Young's modulus (in MPa)
MP,PRXY,1,0.3 ! Poisson's ratio
K,1,0,0 ! Define the geometry of beam (85 mm high)
K,2,0,42.5
K,3,0,85
L,1,3 ! Draw the line
ESIZE,10 ! Set element size to 1 mm
LMESH,ALL,ALL ! Mesh the line
FINISH
/SOLU ! Enter the solution mode
ANTYPE,STATIC ! Before you can do a buckling analysis, ANSYS
! needs the info from a static analysis
PSTRES,ON ! Prestress can be accounted for - required
! during buckling analysis
DK,1,ALL ! Constrain the bottom of beam
DK,3,Ux,0
DK,3,ROTZ,0
FK,3,FY,-1 ! Load the top vertically with a unit load.
! This is done so the eigenvalue calculated
! will be the actual buckling load, since
! all loads are scaled during the analysis.
SOLVE
FINISH
/SOLU ! Enter the solution mode again to solve buckling
ANTYPE,BUCKLE ! Buckling analysis
BUCOPT,LANB,1 ! Buckling options - subspace, one mode
SOLVE
FINISH
/SOLU ! Re-enter solution mode to expand info - necessary
EXPASS,ON ! An expantion pass will be performed
MXPAND,1 ! Specifies the number of modes to expand
SOLVE
FINISH
/POST1 ! Enter post-processor
SET,LIST ! List eigenvalue solution - Time/Freq listing is the
! force required for buckling (in N for this case).
SET,LAST ! Read in data for the desired mode
PLDISP ! Plots the deflected shape

FINISH ! These two commands clear current data
/CLEAR
/TITLE, Nonlinear Buckling Analysis
/PREP7 ! Enter the preprocessor
ET,1,BEAM3 ! Define element as beam3
MP,EX,1,0.21E6 ! Young's modulus (in Pa)
MP,PRXY,1,0.3 ! Poisson's ratio
R,1,.5,1.666667E-3,.2 ! area, I, height
K,1,0,0 ! Define the geometry of beam (85 mm high)
K,2,0,42.5
K,3,0,85
L,1,3 ! Draw the line
ESIZE,1 ! Sets element size to 1 mm
LMESH,ALL ! Mesh line
FINISH
/SOLU
ANTYPE,STATIC ! Static analysis (not buckling)
NLGEOM,ON ! Non-linear geometry solution supported
OUTRES,ALL,ALL ! Stores bunches of output

NSUBST,20 ! Load broken into 5 load steps
NEQIT,1000 ! Use 20 load steps to find solution
AUTOTS,ON ! Auto time stepping
LNSRCH,ON
/ESHAPE,1 ! Plots the beam as a volume rather than line
DK,1,ALL ! Constrain the bottom of beam
DK,3,Ux,0
DK,3,ROTZ,0
FCR=1.9131
FK,3,FY,-1.2*FCR ! Apply load slightly greater than predicted
! required buckling load to upper node
FK,2,FX,-0.006*FCR ! Add a horizontal load (0.5% FY) to initiate
! buckling
SOLVE
FINISH
/POST26 ! Time history post processor
RFORCE,2,1,F,Y ! Reads force data in variable 2
NSOL,3,2,U,Y ! Reads y-deflection data into var 3
XVAR,2 ! Make variable 2 the x-axis
PLVAR,3 ! Plots variable 3 on y-axis
/AXLAB,Y,DEFLECTION ! Changes y label
/AXLAB,X,LOAD ! Changes X label
/REPLOT

---

Und was ist der Fehler? Hast du Konvergenzprobleme? Wenn ja, dann versuche mal, eine nicht ganz so große Kraft aufzugeben, Faktor 1.2 ist nicht nur "slightly greater". Vergleiche dazu auch Szabo, Höhere Technische Mechanik, der hat das nachkritische Verhalten analytisch untersucht. Der kommt schon bei geringsten Kraftsteigerungen auf deutliche Knickauslenkungen.

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Das Problem ist, dass nichts sinnvolles bei raus kommt. 1.2*FCR ist wirklich ziemlich größer. Ich habe 1.2 gewählt, was das auch der Ansatz in dem Tutorial für den 1. Eulerfall gewählt wurde. In diesem Fall ergibt sich eine schöne Kurve, die beim überschreiten der Knickkraft stark einknickt. Aber ANSYS scheint mit den Randbedingungen für den 4.Fall ein Problem zu haben.

Analytisch hab ich das auch schon gerechnet. Jetzt möchte ich den Verlauf einfach mit der FEM Lösung vergleichen.

---

Dann schick mal am besten ein Bild mit den nicht sinnvollen Ergebnissen...

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

kurve.jpg

ich hab das ganze etwas umgebaut... jetzt gehts:

CODE:

/COM,ANSYS MEDIA REL. 121 (10/15/2009) REF. VERIF. MANUAL: REL. 121
/VERIFY,VM136
/PREP7                   
MP,PRXY,,0.3
/TITLE, LARGE DEFLECTIONS OF A BUCKLED BAR (THE ELASTICA)
C***    THEORY OF ELASTIC STABILITY, TIMOSHENKO AND GERE, 2ND ED., PAGE 78
UNITS, SI
ANTYPE,STATIC
NLGEOM,ON                ! ACTIVATE LARGE DEFLECTION PROCESS
ET,1,BEAM3,,,,,,,1        ! TURN OFF BEAM3 PRINTOUT
R,1,.5,1.666667E-3,.2    ! AREA,IZZ,HEIGHT IN MM
MP,EX,1,0.21E6
N,1
N,21,,85
FILL
E,1,2
EGEN,20,1,1
FINISH
/SOLU   
ANTYPE,STATIC ! Static analysis (not buckling)
NLGEOM,ON ! Non-linear geometry solution supported
OUTRES,ALL,ALL ! Stores bunches of output

NSUBST,50 ! Load broken into 20 load steps
NEQIT,1000 ! Use 20 load steps to find solution
AUTOTS,ON ! Auto time stepping
LNSRCH,ON
/ESHAPE,1 ! Plots the beam as a volume rather than line
D,1,ALL ! Constrain the bottom of beam
D,21,Ux,0
D,21,ROTZ,0
FCR=1.9131
F,21,FY,-1.1*FCR ! Apply load slightly greater than predicted
! required buckling load to upper node
F,11,FX,-0.005*FCR ! Add a horizontal load (0.5% FY) to initiate
! buckling
SOLVE
FINISH
/POST26 ! Time history post processor
RFORCE,2,1,F,Y ! Reads force data in variable 2
NSOL,3,2,U,Y ! Reads y-deflection data into var 3
XVAR,2 ! Make variable 2 the x-axis
PLVAR,3 ! Plots variable 3 on y-axis
/AXLAB,Y,DEFLECTION ! Changes y label
/AXLAB,X,LOAD ! Changes X label
/REPLOT