Hallo, ich habe folgendes Problem:
an einem Sandwichmodell (Volumen=solid185, Deckschicht=Shell181, Haftschicht=combin39) führe ich eine nichtlineare Traglastanalyse durch. Die Deckschicht ist mit Federelementen haftfest am Volumen verbunden. Es gibt Bereiche mit unterschiedlicher Haftung. Die Federn "wirken" an koinzidenten Knoten nur in eine Raumrichtung (KO3=3). Die anderen Raumrichtungen sind mit cpintf "gesperrt". Leider bricht die Traglastberechnung ab. Kann mir jemand weiterhelfen?
Kopple ich die Knoten in der Haftschicht mit cpintf,all dann konvergiert alles. Setze ich für die Federn KO4=1 ein, und lasse ich cpintf weg, konvergiert das ganze auch. Stimmen durch die Beulen im Deckblech die Knoten-KOS nicht mehr überein und kommt es deshalb nicht zur Konvergenz?
Für eine helfende Antwort wäre ich dankbar!
Eingabefile:
fini
/clear
/filname,Test_Block !Einheiten in N und mm
!Vorwerte:
Laenge=200 !mm
Breite=200 !mm
Dicke=100 !mm
Blechdicke=1 !mm
fyd=320 !N
Elx=100 !Die Länge der Elemente er entsprechenden Richtungen wird festgelegt
Ely=40
Elz=5
Hymin=0.2*Breite !Bereich mit Haftimperfektion wird festgelegt.
Hymax=0.8*Breite
Hxmax=0.1*Laenge
/prep7
et,1,solid185 !Die solid185 Volumen-Elemente für dem Schaumkern werden definiert
mp,ex,1,8
mp,nuxy,1,0
et,2,shell181 !Die shell181 Schalen-Elemente für die Deckbleche werden definiert
r,2,Blechdicke
mp,ex,2,200000
tb,biso,2
tbdata,1,fyd,0
mp,nuxy,2,0.3
et,3,combin39
Keyopt,3,1,0 !Belastungskurve entspricht Entlastungskurve
Keyopt,3,2,0 !Druckspannungen folgen einer definierten Kurve
Keyopt,3,3,3 !Feder wirkt in Dickenrichtung
keyopt,3,4,0
keyopt,3,6,1
r,3,-100,0,-0.012,0,-0.01,-0.1*(Laenge/Elx)*(Breite/Ely)
rmore,0,0,2,4000
r,4,-100,0,-0.012,0,-0.01,-0.05*(Laenge/Elx)*(Breite/Ely)
rmore,0,0,2,2000
r,5,-100,0,-0.012,0,-0.01,-0.025*(Laenge/Elx)*(Breite/Ely)
rmore,0,0,1,1000
r,6,-100,0,0,0,1,200,2,400
r,7,0.1
k,1,0,0,0
k,2,Laenge,0,0
k,3,0,Breite,0
k,4,Laenge,Breite,0
l,1,2
l,3,4
l,3,1
l,4,2
al,1,4,2,3
!Generierung der Haftschicht
agen,2,1,1,1,,,0
!Element- und Materialzuweisung im Deckblech
asel,s,area,,1
lesize,1,Laenge/Elx
lesize,2,Laenge/Elx
lesize,3,Breite/Ely
lesize,4,Breite/Ely
type,2
mat,2
real,2
amesh,all
allsel
asel,s,area,,2
lesize,5,Laenge/Elx
lesize,7,Laenge/Elx
lesize,8,Breite/Ely
lesize,6,Breite/Ely
real,7
amesh,all
allsel
!Federn im Normalbereich
type,3
real,3
nsel,s,loc,x,Laenge/Elx,Laenge-Laenge/Elx
nsel,r,loc,y,Breite/Ely,Hymin-Breite/Ely
eintf,0.02
allsel
type,3
real,3
nsel,s,loc,x,Laenge/Elx,Laenge-Laenge/Elx
nsel,r,loc,y,Hymax+Breite/Ely,Breite-Breite/Ely
eintf,0.02
allsel
type,3
real,3
nsel,s,loc,x,Hxmax+Laenge/Elx,Laenge-Laenge/Elx
nsel,r,loc,y,Hymin-Breite/Ely,Hymax+Breite/Ely
eintf,0.02
allsel
esel,s,real,,3
/color,elem,yell
allsel
!Federn im Normalbereich am Rand
type,3
real,4
nsel,s,loc,x,Laenge/Elx,Laenge-Laenge/Elx
nsel,r,loc,y,0
eintf,0.02
allsel
type,3
real,4
nsel,s,loc,x,Laenge/Elx,Laenge-Laenge/Elx
nsel,r,loc,y,Breite
eintf,0.02
allsel
type,3
real,4
nsel,s,loc,x,0
nsel,r,loc,y,Breite/Ely,Hymin-Breite/Ely
nsel,a,loc,y,Hymax+Breite/Ely,Breite-Breite/Ely
eintf,0.02
allsel
type,3
real,4
nsel,s,loc,x,0
nsel,r,loc,y,Hymax+Breite/Ely,Breite-Breite/Ely
eintf,0.02
allsel
type,3
real,4
nsel,s,loc,x,Laenge
nsel,r,loc,y,Breite/Ely,Breite-Breite/Ely
eintf,0.02
allsel
esel,s,real,,4
/color,elem,bmag
allsel
type,3
real,5
nsel,s,loc,x,0
nsel,r,loc,y,0
nsel,a,loc,y,Breite
eintf,0.02
allsel
type,3
real,5
nsel,s,loc,x,Laenge
nsel,r,loc,y,0
nsel,a,loc,y,Breite
eintf,0.02
allsel
esel,s,real,,5
/color,elem,lgra
allsel
!Federn mit Haftimperfektion
type,3
real,6
nsel,s,loc,x,0,Hxmax
nsel,r,loc,y,Hymin,Hymax
eintf,0.02
allsel
esel,s,real,,6
/color,elem,whit
allsel
!Kern
vext,2,,1,,,-Dicke
allsel
!Das Volumen wird vernetzt
type,1
mat,1
real,1
esize,Dicke/Elz
vsweep,all
allsel
aclear,2
allsel
!Deckblech und Federn werden farblich hervorgehoben
asel,s,mat,,2
esla,s
/color,elem,blue
allsel
/solu
nsel,s,loc,z,-Dicke !Die Festhalterung am unteren Deckblech wird eingeführt.
d,all,all
allsel
nsel,s,loc,x,Laenge !Symmetrierandbedingungen in Längenrichtung
dsym,symm,x
allsel
nsel,s,loc,y,0 !Symmetrierandbedingungen in Breitenrichtung
nsel,a,loc,y,Breite
dsym,symm,y
allsel
esel,s,type,,3 !Kopplung der Knoten für Federelemente
nsle,s,all
nsel,u,loc,y,Hymin,Hymax
cpintf,ux
cpintf,uy
allsel
esel,s,type,,3 !Kopplung der Knoten für Federelemente
nsle,s,all
nsel,r,loc,x,Hxmax,Laenge
nsel,r,loc,y,Hymin,Hymax
cpintf,ux
cpintf,uy
allsel
/solu !Der Lösungsteil wird gestartet
antype,static
pstres,on
nsub,1
fdel,all
allsel
lsel,s,line,,3
nsll,s,1
*get,nodvorne,node,,count
f,all,fx,1/nodvorne !Eine Last der Größe 1 wird auf alle Knoten im Lasteinleitungsbereich verteilt
allsel
solve
finish
/solu !Die Beulanaylse wird gestartet
antype,buckle
bucopt,lanb,1 !Das Lanczos-Verfahren wird verwendet. Der 1. Eigenwert wird angezeigt.
mxpand,1
solve
finish
/post1
set,last !Die Daten werden geladen
pldisp !Das deformierte Modell wird angezeigt
save
finish
/filnam,Traglast Block !Eine nichtlineare Tragalstanalyse wird durchgeführt
/prep7
fdel,all
upgeom,(0.1*Blechdicke),1,1,Test_Block,rst !Die (-0.1*Blechdicke)-fache Vorverformung gemäß dem 1. Eigenwert wird eingelesen.
lsel,s,line,,3
nsll,s,1
d,all,ux,1
allsel
/solu
antype,static
solcon,on
nlgeom,on !Th. 2. Ordnung wird berücksichtigt
pstres,on
time,1
nsubst,10,,10
autots,on
outres,all,all
allsel
solve
save
fini
Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP