---

Hallo

Hallo zur Ausgabe eines Zug-Dehnungs Diagrammes will ich die Werte von mehreren Elementen (am besten entlang eines definierten Paths) mitteln.

Bisher habe gebe ich schon die Zug-Dehnungs Kurve eines bestimmten Elementes aus siehe der Code unten [1]. Da die Elementnummer aber ja vom verwendeten Netz abhängt und ein Mittelwert über mehrere Elemente vielleicht eh geeigneter ist bin ich damit nicht sehr zufrieden.

In /Post1 kann man ja mittels  "PDEF, EPELX, EPEL, X / PDEF, SX, S, X" die Mittelwerte entlang eines Pfades bekommen. Gibt es eine ähnliche Möglichkeit für die ESOL Kommandos in /Post26?

Gibt es andere Möglichkeiten (vielleicht mit einer Schleife)?

Danke
Florian

[1]:

/POST26
NUMVAR,200 

element=360  ! choose the element

SOLU,191,NCMIT
STORE,MERGE
FILLDATA,191,,,,1,1
REALVAR,191,191
FILLDATA,192,,,,0,0
FILLDATA,193,,,,1,0
FILLDATA,194,,,,-1,0
FILLDATA,195,,,,1,1
VARNAME,195,NSET

! 
! Name: eng_strain
! ID:  2
! Function: exp(esol(60, ,EPEL,X))-1 
ESOL,200,element,,EPEL,X 
EXP,199,200
FILLDATA,198,,,,1,0
REALVAR,198,198
PROD,197,198,194
ADD,2,199,197,,eng_strain

! 
!STORE,MERGE
FILLDATA,192,,,,0,0
FILLDATA,193,,,,1,0
FILLDATA,194,,,,-1,0
FILLDATA,195,,,,1,1
VARNAME,195,NSET

! 
! Name: eng_stress
! ID:  3
! Function: esol(60, ,S,X)/(eng_strain + 1)
!          stress_true / ( strain_eng + 1)
ESOL,200,element,,S,X
FILLDATA,197,,,,1,0
REALVAR,197,197
ADD,198,2,197
QUOT,3,200,198,,eng_stress 

! Plot
XVAR,2        ! X-Achse: eng_strain
PLVAR,3,      ! Y-Achse: eng_stress

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Hallo

ich habe mein Problem nun über eine Schleife gelöst - gar nicht so kompliziert:

Code:

---

/PREP7
[...]

! Punkte für die Messlänge
PATH,Mess,4,30,20,            ! Pfad definieren [letzte Zahl] bestimmt die Auflösung
PPATH,1,0,-10,0,Probendicke/2-0.2,0,
PPATH,2,0,10,0,Probendicke/2-0.2,0,
PPATH,3,0,-10,0,Probendicke/2+0.2,0,
PPATH,4,0,10,0,Probendicke/2+0.2,0,

ALLSEL
ESEL,s,path,Mess
CM,l_0,elem            ! Elemente der Messtrecke für später speichern

[...]

FINISH

/POST26
NUMVAR,200 

SOLU,150,NCMIT  ! Anzahl der Rechenschritte zum initialisierne der Tabellen???
STORE,MERGE

ALLS
CMSEL,s,l_0

*GET,akt,elem,,num,min  ! Ermittlung der kleinsten selektierten Elementnummer
*GET,anzahl,elem,,count  ! Ermittlung der selektierten Elemente

ESOL,200,akt,,EPEL,X ! Dehnung
ESOL,100,akt,,S,X ! Spannung

*do,i,2,anzahl
  *GET,akt,elem,akt,nxth      ! Auswaehlen des naechsten selektierten Knotens
  ESOL,199,akt,,EPEL,X        ! Dehnung
  ESOL,99,akt,,S,X       ! Spannung

  add,200,200,199            ! Aufsummieren
  add,100,100,99              ! Aufsummieren
*ENDDO

FILLDATA,151,,,,anzahl,0  ! Speichern der Elementanzahl in 151

FILLDATA,152,,,,-1,0  !var152 = -1
FILLDATA,153,,,,1,0    !var153 = 1

! Durchschnitt bilden
QUOT,200,200,151      ! 200 = true strain average
QUOT,100,100,151      ! 100 = true stress average

! 
! Name: eng_strain
! ID:  4
! Function: exp(esol(60, ,EPEL,X))-1
! eng_strain = exp( true_strain) - 1
!        [4] = exp( [200] ) - [152]
EXP,199,200
ADD,4,199,152,,eng_strain_avg

! 
! Name: eng_stress 
! ID:  5
! Function: esol(60, ,S,X)/(eng_strain + 1)
!    eng_stress = stress_true / ( strain_eng + 1)
!            [5] = [100] / ( [4] + [153])
ADD,199,4,153
QUOT,5,100,199,,eng_stress_avg

! Plotten
/axlab,x,eng. Strain
/axlab,y,Stress
XVAR,4      ! X-Achse: eng_strain
PLVAR,5      ! Y-Achse: eng_stress

! Save time history variables to file H:/DA/Ansys/Stress_Strain_element60.csv 
*CREATE,scratch,gui
*DEL,_P26_EXPORT
*DIM,_P26_EXPORT,TABLE,anzahl,1
VGET,_P26_EXPORT(1,0),4  ! eng_strain average
VGET,_P26_EXPORT(1,1),5  ! eng_stress average
/OUTPUT,'Stress_Strain_element60','csv','H:/DA/Ansys' 
*VWRITE,'eng_strain','eng_stress' 
%C; %C
*VWRITE,_P26_EXPORT(1,0),_P26_EXPORT(1,1) 
%G; %G 
/OUTPUT,TERM
*END
/INPUT,scratch,gui 
! End of time history save 

---

Gruß
Florian

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP