---

Hallo,

ich möchte euch um Hilfe bitten bezgl. der Definition periodischer Randbedingungen. Und zwar möchte ich einen Würfel mit diesen Randbedingungen versehen, um Randeinflüsse zu vermeiden. Ich weiss, dass diese Randbedingungen coupled degrees of freedom heissen. Wo kann ich diese in DesignSpace (V.10.0 oder 11.0) finden?
Bin dankbar über jede Art von Hilfe.

Grüsse Christoph

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Noch eine Zusatzinfo:
es geht hier um die Untersuchung von Metallhohlkugelstrukturen, die mit einem FE-Modell simuliert werden sollen. Der Würfel ist eine Einheitszelle aus der Struktur.

Vielen Dank für eure Hilfe.
mfg Christoph

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Hallo,

das geht in DS nicht, weil keine Command-Blöcke verfügbar sind.

Mit den weitergehenden Lizenzen ginge das z. B. mit so einem Script, wie unten. Dabei wird vorausgesetzt, dass die Z-Achse Rotationsachse ist, Seite1 und Seite2 als Knotenkomponenten mit den Schnittufern definiert sind. Nach der Rechte Hand Regel sollte dabei SEite1 zuerst definert werden (Reihenfolge spielt eine Rolle!, nach Rotationsachse definieren). Es werden keine cp's definiert, da man ja koinzidente Knoten haben müsste, sondern ce's, die auch mit ungleicher Vernetzung und sogar ungleicher Geometrie (die es ja eigentlich nicht geben dürfte, die man lässigerweise aber manchmal hinnehmen möchte) funktionieren.
Damit die ce's erzeugt werden können, werden die Knoten in eine gemeinsame Ebene verdreht, dazu muss temporär das Element-Shape-checking ausgeschaltet werden.
Weitergehender Support zu diesem Makro wird nicht geleistet, wer mehr darüber wissen will, sollte die Commandos im Commands Reference Manual nachvollziehen.

Mit freundlichen Grüßen
Christof Gebhardt

/pmacro
/prep7
save,x,db

/view,1,1
eplo
! Makro für zykl. Symmetrie über CEs
! 20.10.2000
! CGEB
! setzt voraus: z-Achse= Rotationsache
! setzt voraus: 2 componenten seite1 und seite2

/nerr,900000,900000

/sys,echo Cyclic.txt aktiv, Fenster schliessen!!! >text.txt
/sys,start text.txt
csys,1
dsys,1
alls
nrotate,all

cmsel,s,seite1
*get,xmax1,node,,mxloc,x
nsel,r,loc,x,xmax1
*get,zmax1,node,,mxloc,z
nsel,r,loc,z,zmax1
*get,nmin1,node,,num,min

cmsel,s,seite2
*get,xmax2,node,,mxloc,x
nsel,r,loc,x,xmax2
*get,zmax2,node,,mxloc,z
nsel,r,loc,z,zmax2
*get,nmin2,node,,num,min

y1=ny(nmin1)
y2=ny(nmin2)
Wi=y2-y1

modm,nocheck
cmsel,s,seite1
*get,nn,node,,count
csys,1
dsys,1
*do,i,1,nn
  *get,nmin,node,,num,min
  x1=nx(nmin)
  y1=ny(nmin)
  z1=nz(nmin)
  nmod,nmin,,y1+wi
  nsel,u,,,nmin
*enddo
dsys

csys,1
cmsel,s,seite1
nrotat,all

cmsel,s,seite2
esln
cmsel,s,seite1
modm,check
shpp,on
ceintf,,ux,uy,uz
modm,nocheck
shpp,off

cmsel,s,seite1
*do,i,1,nn
  *get,nmin,node,,num,min
  x1=nx(nmin)
  y1=ny(nmin)
  z1=nz(nmin)
  nmod,nmin,,y1-wi
  nsel,u,,,nmin
*enddo

modm,nocheck
shpp,off

cmsel,s,seite1
*get,n1,node,,count
alls
*get,kopp,active,0,ce
*msg,ui,kopp,kopp/3,n1
%I CEs fuer %I von %i Knoten generiert
cmsel,s,seite1
cmsel,a,seite2
alls

cmsel,s,seite1
nrotat,all
alls
fini
save,db
/solu

------------------
Christof Gebhardt
CAD-FEM GmbH
Marktplatz 2
85567 Grafing
Tel. +49 (0) 8092 7005 65
cgebhardt@cadfem.de
www.cadfem.de

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Vielen Dank für die Antwort. Leider kam sie etwas spät für mich.
Trotzdem herzlichen Dank für die Ausführlichkeit1
Mit freundlichen Grüssen

Christoph

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP