!Zwei Wicklungen eine erregt eine belastet
!3-D
!harmonisch
!ohne Kern
!Schätzing für Donkey 5.12.2007
fini  $/cle
*abbr,zweiwi3d,/inp,zweiwi3d_2,txt

/prep7
ET,1,97,0           ! Luft
ET,2,97,3           ! Wicklung
ET,3,111,1          ! Rand
ET,4,124,0          ! Widerstand
ET,5,124,4          ! Spannungsquelle,sinus
ET,6,124,5          ! Kopplung zur Wicklung
EMUNIT,MKS
MP,murx,1,1         !Luft
MP,murx,2,1         !Wicklung1
MP,rsvx,2,1/56e6    !Wicklung1
MP,murx,3,1         !Wicklung2
MP,rsvx,3,1/56e6    !Wicklung2

!--------------------------
pi=4*atan(1)
riw1=15e-3  !Radius innen Wicklung1
raw1=20e-3  !Radius außen Wicklung1
hw1=5e-3    !Höhe Wicklung1
aw1=(raw1-riw1)*hw1  !Fläche Wicklung1
vw1=hw1*(pi*raw1**2-riw1**2) !Volumen Wicklung1
nw1=100     !Windungszahl Wicklung1

!Real für Wicklung:care,turn,volu,dirx,diry,dirz,csym,fill
r,2,aw1,nw1,vw1,0,1,0
rmore,1,0.8
!-------------------------
riw2=15e-3  !Radius innen Wicklung2
raw2=20e-3  !Radius außen Wicklung2
hw2=5e-3    !Höhe Wicklung2
aw2=(raw2-riw2)*hw2  !Fläche Wicklung2
vw2=hw2*(pi*raw2**2-riw2**2) !Volumen Wicklung2

nw2=100      !Windungszahl Wicklung2
!Real für Wicklung:care,turn,volu,dirx,diry,dirz,csym,fill
r,3,aw2,nw2,vw2,0,1,0
rmore,1,0.8
!-----------------------
rkam=40e-3  !Radius Kammer
abst=2e-3
!-----Geometrie------
abm=60e-3
n,1,-abm*1.5,0,0   !für Schaltungselemente
n,2,-abm*1.5,abm/2,0
n,3,-abm,abm/2,0
n,4,-abm,0,0
n,5,abm*0.8,0,0  !für Sekundärkreis
n,6,abm,abm/2,0
n,7,abm*1.2,0,0
/color,outl,blac

!/eof

!-----Wicklung1-----
cylind,riw1,raw1,-hw1-abst/2,-abst/2,  0,180
cylind,riw1,raw1,-hw1-abst/2,-abst/2,180,360
!numcmp,volu
!---neues Koordinatensystem------
zver=10e-3    !Z-Verschiebung
yver=6e-3     !Y-Verschiebung
dreh=15       !Drehung
local,11,0,,yver,zver,,-dreh
wpcsys,,11

!-----Wicklung2-----
cylind,riw2,raw2,+hw2+abst/2,+abst/2,  0,180
cylind,riw2,raw2,+hw2+abst/2,+abst/2,180,360

wpcsys,,0
csys,0

!----Lufthülle------
sphere,rkam
!-------------------
vovlap,all
!V1,6: Wicklung1 V3,7: Wicklung 2 V8: Luft

!-----Vernetzung-----
type,2
mat,2
real,2
esize,hw1
!esize,hw1/4
vmesh,1,6,5   !Wicklung 1
mat,3
real,3
vmesh,3,7,4   !Wicklung 2
!------Elementkoordinaten----
esel,s,mat,,2
local,12,1
emodif,all,esys,12
!--------
esel,s,mat,,3
local,13,1,,yver,zver,,-dreh
emodif,all,esys,13
csys,0

!-------Luft------
type,1
mat,1
esize,rkam/2
mshkey,0
mshape,1
vmesh,8

!-----Rand-----
csys,2
type,3
esize,,1
asel,s,ext
vext,all,,,1e-3
nsel,s,ext
sf,all,inf
csys,0
!-------------------------
esel,s,mat,,2
nsle
cp,1,curr,all
cp,2,emf,all
!*get,node_ein,node,,num,min

esel,s,mat,,3
nsle
cp,3,curr,all
cp,4,emf,all
!*get,node_aus,node,,num,min


!----Spannungsquelle-----
type,5
!Real,nr,offs,ampl,freq,delay,phase,exp
!r,5,0,12,50,0,0,0
r,5,100 
real,5  $e,2,1,4
!-----Widerstand1-0-Ohm------
type,4  $r,6,1e-6  $real,6  $e,2,3
!----Kopplung------
type,6  $r,7,1  $real,7  
e,3,4,node(riw1,0,0)
!-------Masse----
allsel
d,1,volt,0
d,4,volt,0


!-----Widerstand2-1MOhm-----
Rlast=1e-6     !Kurzschluss
RLast=1e6      !Leerlauf
type,4  $r,8,RLast  $real,8  
e,6,7
!----Kopplung------
type,6  $r,9,1  $real,9  
e,5,6,node(riw2,0,0)
d,5,volt,0
d,7,volt,0
!---------------------

allsel
!----------------
/solu
antype,harm
harfr,50
solve
!-------------
/post1
esel,s,mat,,2,3
plve,jt

set,1,1
U_pri_real=volt(3)
U_sek_real=volt(6)
set,1,1,,1
U_pri_imag=volt(3)
U_sek_imag=volt(6)

/eof

/post1
esel,s,type,,4
set,1,1
presol,elem

/post1
esel,s,type,,4
set,1,1,,1
presol,elem


/post26
nsol,2,3,volt
nsol,3,6,volt
prva,2,3