!Temperaturverlauf eines Tages stundenweise
finish  $/clear
*abbr,matziii,/input,matziii,txt

!----Parameter-----
*dim,tag_temp,array,24
tag_temp(1)=13.1,12.5,12.0,11.9,12.9,14.1,15.9,17.9,19.3,20.6,21.2,21.7
tag_temp(13)=22.1,22.5,22.7,22.5,22.1,21.5,20.2,18.5,17.1,15.9,15.1,14.6,
breit=0.1
lang=0.2
dick=0.8
t_umg=8     !Umgebungstemperatur
!-------------
/prep7
et,1,solid90

mp,kxx,1,4			!Waermeleitfaehigkeit	
mp,c,1,4000                     !spez_Wärme
mp,dens,1,2000                  !Dichte

!-----Geometrie---
block,0,breit,0,dick,0,lang
/view,,1,1,1,
!---Vernetzung----
esize,breit/2
vmesh,1
tunif,t_umg
!---Lösung----
/solu
antype,trans
*do,i,1,24
nsel,s,loc,y,dick
sf,all,conv,100,tag_temp(i)  !Konvektion
allsel
time,i*60*60
solve
*enddo
!-----Auswertung-------
/post1
plns,temp


!/eof

!---Animation---
/post1
set,first
/cont,,9,t_umg,,22
*do,i,1,24
plns,temp
/wait,.1
set,next
*enddo


!-----Auswertung-----
/post26

nsol,2,node(0,dick/4*4,0),temp,,oben
nsol,3,node(0,dick/4*3,0),temp,,
nsol,4,node(0,dick/4*2,0),temp,,mitte
nsol,5,node(0,dick/4*1,0),temp,,
nsol,6,node(0,dick/4*0,0),temp,,unten
plvar,2,3,4,5,6