!Potentialfeld
!Ziel: Ausgabe des Potentials als Matrix
finish  $/clear
*abbr,matrix,/inp,matrix,txt
!-------------------
abx=120e-3       !Abmessung x
aby=100e-3       !Abmessung y
elex=30e-3       !Elektrode x
eley=20e-3       !Elektrode y
pot1=10          !10 Volt
teilerx=12       !Teiler x
teilery=10       !Teiler y
!------------------
/prep7
et,1,plane121
mp,perx,1,1    
!----Geometrie----
rectng,0,abx,0,aby
!----Vernetzung-------
lsel,s,loc,x,abx/2
lesize,all,,,teilerx
lsel,s,loc,y,aby/2
lesize,all,,,teilery
amesh,all   
!---Randbedingungen------
nsel,s,loc,x,abx-elex,abx
nsel,r,loc,y,aby-eley,aby
d,all,volt,pot1
!--------------
nsel,s,loc,x,0
nsel,a,loc,y,0
d,all,volt,0
!----------------------------
allsel
/solu
solve
!------------------
/post1
/triad,off
/plopts,minm,0
plns,volt
!----------------------------------

!/eof
 
!-----Auslagern der Knotenpotentiale---------------
*dim,feld,array,teilerx+1,teilery+1
faktor=10e-3  !für Überhöhung
*do,ix,0,teilerx
  *do,iy,0,teilery
    narb=node(ix*abx/teilerx,iy*aby/teilery,,)
    feld(ix+1,iy+1)=volt(narb)*faktor
  *enddo  !iy
*enddo  !ix


!================================
*create,ausgabe
*mwrite,feld,felddat,dat
(e10.3)
*end
*use,ausgabe