!Schweißen mit Nahtfüllung
!aus dem Forum von kurzschluss2000
!Schätzing, 11.11.2012

finish  $/clear
*abbr,fuge1,/inp,fuge1,inp

dick=0.01  !Dicke der Platte
breit=0.2  !Breite 
lang=0.4   !Länge

/PREP7
et,1,solid5,8
block,-breit/2-dick/2,breit/2+dick/2,0,lang,0,dick

esize,dick
vmesh,all

/view,,0.4,-0.5,0.8
/angle,,-35

MP,KXX,1,40
MP,DENS,1,7800
MP,C,1,500
TUNIF,20

nsel,s,loc,x,-dick/2,dick/2
nsel,r,loc,y,0,lang
esln,s,1
eplot

esel,inve
cm,blech%0%,elem
!-----------------------------
/solu
antyp,trans 
outres,all,all
time,1e-12
solve


!------------------------
Last=7e9  !thermische Last
schritte=40
*do,i,1,schritte
bfdele,all,all
nsel,s,loc,x,-dick/2,dick/2
nsel,r,loc,y,dick*(i-1),dick*i
esln,s,1
bf,all,hgen,last
nsel,all
cmsel,a,blech%(i-1)%,elem
cm,blech%i%,elem
time,i
solve
*enddo


!-------Auswertung--------
/post1
/plopts,minm,0
/triad,off
plns,temp

/eof


/cont,,9,20,,1500
*do,i,1,schritte
/seg,multi,fuge,0.5
set,i
cmsel,s,blech%i-1%
plns,temp
*enddo
anim,5,1,0.2

/seg,delet
/seg,off