finish
/clear,start

/Title,Einzelentladungskrater bei der Mikrofunkenerosion

/prep7

!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!Parameter

we=1802e-6 		![J]
d=87e-6			![m]
te=1e-6			![s]
te2=100

Qq=0.12*we/(3.1416*(d/2)*(d/2)*te)	!Wärmestromdichte [W/m²]

Tu=20					!Umgebungstemperatur
n=50

!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!Definition des Elemtetyps

ET,1,PLANE55 

!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!Materialparameter

MP,KXX,1,36.8		!Thermische Leitfähigkeit [W/(m²K)]
MP,C,1,468		!Thermische Kapazität [J/(kg K)]
MP,dens,1,7800		!Dichte [kg/m³]

!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!Geometrie

rectng,-(4*d),8*d,,8*d
rectng,,4*d,,d
AOVLAP,1,2

!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!Meshing Parameter

LESIZE,5,,,4*n
LESIZE,8,,,n
LESIZE,4,,,n/2
LESIZE,2,,,n/2
LESIZE,3,,,n
LESIZE,9,,,n/3
LESIZE,10,,,n/3

!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!Meshing

MSHAPE,0,2D 
MSHKEY,1
AMESH,2

MSHAPE,1,2D 
MSHKEY,0
AMESH,3

!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!Lastschritte...

/SOLU

ANTYPE,TRANS,NEW	!Berechnung wird transient durchgeführt
TINTP,,,,1		!Zeit-Integrationsparameter (Methode nach Euler Rückwärtseinsetzen)
OUTRES,all,all


lsel,s,,,9
lsel,a,,,10
lsel,a,,,2
lsel,a,,,3
lsel,a,,,4
nsll,s,1
d,all,temp,TU
alls


!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!Lastschritt 1 (Zimmertemp)
! 1.Lastschritt

TIMINT,OFF		!Ausstellen der transienten Efffekte

time,te		!Zeit am Ende dieses Lastfalls		
	
D,ALL,TEMP,TU		!Zimmertemp
alls

solve

!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!Lastschritte: bewegte Wärmequelle
!2.Lastschritt

TIMINT,on
TIME,2*te

ddel,all,temp
NSEL,S,LOC,Y,0  
NSEL,r,LOC,X,d+d/2,2*d+d/2
SF,all,hflux,Qq

NSUB,10
kbc,1
alls
Solve
   

!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
!3.Lastschritt

time,te2

NSEL,S,LOC,Y,0  
NSEL,r,LOC,X,d+d/2,2*d+d/2
SFDEL,all,HFLUX
SF,all,conv,1500,20

NSUB,20
kbc,1
alls
solve

!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!

finish

!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!

/prep7

ET,2,PLANE42

!!!!!!!!!Elementtyp von tehrm. auf Strukturanalyse umschaltenplane55

etchg,tts
etlist

!!!!!!!!!!!!!Materialdaten für Strukturanalyse

mp,ex,1,21e+4
mp,alpx,1,12.1e-6
mp,nuxy,1,0.3

finish

/solu

!!!statische Berechnung
antype,static  

!!Einspannung
lsel,s,,,3
nsll,s,1
d,all,uy
alls

!!!Daten der thermischen Berechnung auf das Modell transferieren!

ldread,temp,3,10,,,,rth  !!!ließt vom 1.Lastschritt und letzten Substep Temperaturen ein
eplot

solve

!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!

finish

!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!

!Postprocessing
!Knoten 100

/post26
nsol,2,103,u,y ! Verschiebung in Y-Richtung
lines,1000     ! Anzahl der max.Zeilen
prvar,2        ! Auflisten der Werte


/post1
schr=1                     !Anzahl SETS
kn1=103                    !Knoten dessen Verschiebung dargestellt werden soll
*dim,tabla,array,4,schr    !array(Spalte, Zeile)
*do,i,1,schr  
set,,,,,,,i                !bestimmt welches SET gelesen wird 
plnsol,epel,eqv            !elastische Dehnung (Vergleichsdehnung)
*get,elDehnung,plnsol,,max    !ließt Dehnung aus Resultfile
tabla(1,i)=i*1  
tabla(2,i)=elDehnung
tabla(3,i)=uy(kn1)
tabla(4,i)=ux(kn1)
*enddo  
/input,'___zu_ergebnissen','dat','c:\Dokumente und Einstellungen/Administrator',, 0