/com,
/com,
/com,>>>>>>>>>>>>>>>>>>>>>  REMOTE DISPLACEMENT MPC184   <<<<<<<<<<<<<<<<<<<<<<<<<<<
/com,

fini
/cle
/filna,remote_displ_mpc184
/title,remote displacement MPC184
/input,block_4x4,inp

!---------------------   pilot node / beam spider construct   ----------------------
!collect model parameter
!used to not redefine existing Items and to have separat numbers (mat, type, section
!real constant) for new items

*get,nnode,node,,count                      !maximum node number
*get,maxmat,mat,,num,max                    !highest material number
*get,rcmax,rcon,,num,max                    !highest real constant set
*get,etmax,etype,,num,max                   !highest element type number 
*get,secmax,secp,num,max                    !highest section number

npilot=nnode+1                              !number for new pilot node

!define pilot node
n,npilot,1                                   !define pilot node

!define beam spider using MPC184
et,etmax+1,184,1,0                          !define MPC184 elemet type as
                                            !rigid beam with constraint equations
                                            
nsel,s,loc,x                                !select all interface nodes
*get,nnode,node,,count                      !number of interface nodes 
nn=0                                        !initialize counter
type,etmax+1                                !set type pointer
real,rcmax+1                                !set real constant pointer
mat,maxmat+1                                !set material pointer
secn,secmax+1                               !set section pointer

*do,i,1,nnode                                !loop over interface nodes
   nn=ndnext(nn)                            !next highest selected node number 
   nsel,a,node,,npilot                      !also select pilot node 
   e,nn,npilot                              !define Element
   nsel,u,node,,npilot                      !unselect pilot node
*enddo
alls
fini

!----------------------   boundary conditions and solution   -----------------------
!2 analysis: 
!1 - deformation driven
!2.- foce driven

/solu
antype,stat

!fixation
nsel,s,loc,x,-0.5,-0.5                       !fixation at rear
d,all,all                                    ! 

!--------------------   first load step - displacement driven   --------------------
!displacement at pilot node
alls
d,npilot,uy,-0.1                              !displacement at pilot node

!solve
alls
solve                                         !SOLVE FOR LS1 = DISPLACEMENT DRIVEN

!--------------------   second load step - force driven   --------------------------
ddele,npilot,all                              !delete BC's from pilot node 
*get,react,node,npilot,rf,fy                  !get reaction force at pilot node 
f,npilot,fy,react                             !define load at pilot node

alls
solve

!--------------------   Post processing - make pictures   --------------------------

/post1
set,1                                         !first load step
/view,1,0.5,0.1,1
/auto
/title, LS1 displacement driven
/show,png
plns,u,sum
/show,close

set,2
/title, LS2 force driven
/show,png
plns,u,sum
/show,close