/com,
/com,
/com,          Hauptspannungen und Richtungen aus elementergebnissen
/com,>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>><<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
/com,
!*******************************************************************************
!Dieses Macro ermittelt die Hauptspannungsrichtungen (Eulewinkel) und speichert
!Sie im Parameter "elemente" ab.
!elemente | cent x | cent y | cent z | angel1 | angel2 | angel3
!cent x - x koordinate element
!cent y - y koordinate element
!cent z - z koordinate element

!Zur Kontrolle kann für jedes element ein locales cos erstellt werden in dem
!x - Achse => absolut groeste HS
!y - Achse => absolut mittelste HS
!Z - Achse => absolut kleinste HS
!ist
!*******************************************************************************
!aufruf: hauptspannung,COS
!            COS = 1 - COS werden erstellt
!            COS = 0 - COS werden nicht erstellt
!*******************************************************************************            

alls
esel,u,ename,,154                    !surface elemente deselektieren
esel,u,ename,,170,176                !kontaktelemente deselektieren

*get,nelem,elem,,count               !elemente zaehlen
*get,maxcsys,cdsy,,num,max           !groesste csys nr
*if,maxcsys,lt,11,then               !kleinstes user cos = 11
   maxcsys=10
*endif

*dim,elemente,,nelem,6               !output vektor

etab,s_x,s,x
etab,s_y,s,y
etab,s_z,s,z
etab,s_xy,s,xy
etab,s_yz,s,yz
etab,s_xz,s,xz

ne=0

csys,0
*do,i,1,nelem
   ne=elnext(ne)
   *dim,stress,,1,6
   *dim,loc,,3,1
   
   *vget,loc(1,1),elem,ne,cent,x,,,4
      
   *get,stress(1,1),etab,1,elem,ne
   *get,stress(1,2),etab,2,elem,ne 
   *get,stress(1,3),etab,3,elem,ne 
   *get,stress(1,4),etab,4,elem,ne 
   *get,stress(1,5),etab,5,elem,ne 
   *get,stress(1,6),etab,6,elem,ne 

   *mfun,elemente(i,1),tran,loc(1,1)  
   *vfun,elemente(i,4),euler,stress(1,1)   
   
   *if,arg1,eq,1,then   
      local,maxcsys+i,,elemente(i,1),elemente(i,2),elemente(i,3),elemente(i,4),elemente(i,5),elemente(i,6)
      csys,0
   *endif
      
   stress=  $ loc=                              
*enddo

!aufraemen
nelem= $ maxcsys= $ ne= $ i=