/batch,list
/title, Microstrip Rectangular Patch Antenna
/com, Problem: Compute S-Parameter of Microstrip Rectangular Patch
/com, Microstrip: Width=2.46 mm, Substrate thickness=0.794 mm, er=2.2
/com, Patch: 16x12.45 mm^2; Distance from microstrip edge to patch
/com, edge: 2.09 mm
/nopr
/prep7
! --- define elements and material ---
epsr=2.2
et,11,200,7
et,1,120,1,,,0
et,2,120,1,,,1

mp,murx,1,1.
mp,perx,1,epsr
mp,murx,2,1.
mp,perx,2,1.
! --- define geometry ---
ws=2.46
wp1=2.09
wp2=7.9
hp=16.
hm=4.
hs=0.794
scal=1.e-3
*dim,a,array,8
*dim,b,array,5
a(4)=0
a(3)=a(4)-wp1
a(2)=a(3)-ws
a(1)=a(2)-ws
a(5)=a(4)+ws
a(6)=a(5)+wp2
a(7)=a(6)+ws
a(8)=a(7)+ws
b(2)=0
b(1)=b(2)-hm
b(3)=b(2)+hp
b(4)=b(3)+hm
b(5)=b(4)+1.25*hm
*do,i,1,7
*do,j,1,4
rect,a(i),a(i+1),b(j),b(j+1)
*enddo
*enddo
aglue,all
! --- define mesh size ---
nx1=8
nx2=4
nx3=5
ny1=4
ny2=16
nz1=5
nz2=4
hx1=(a(3)-a(1))/nx1
hx2=(a(4)-a(3))/nx2
hx3=(a(5)-a(4))/nx3
hy1=(b(2)-b(1))/ny1
hy2=(b(3)-b(2))/ny2
lsel,s,loc,x,(a(1)+a(2))/2
lsel,a,loc,x,(a(2)+a(3))/2
lsel,a,loc,x,(a(6)+a(7))/2
lsel,a,loc,x,(a(7)+a(8))/2
cm,lx1,line
lesize,lx1,hx1
lsel,s,loc,x,(a(3)+a(4))/2
lsel,a,loc,x,(a(5)+a(6))/2
cm,lx2,line
lesize,lx2,hx2
lsel,s,loc,x,(a(4)+a(5))/2
cm,lx3,line
lesize,lx3,hx3
lsel,s,loc,y,(b(1)+b(2))/2
lsel,a,loc,y,(b(3)+b(4))/2
lsel,a,loc,y,(b(4)+b(5))/2
cm,ly1,line
lesize,ly1,hy1
lsel,s,loc,y,(b(2)+b(3))/2
cm,ly2,line
lesize,ly2,hy2
alls
type,11
asel,all
amesh,all
alls

asel,s,loc,z,0
asel,r,loc,x,a(2),a(7)
asel,r,loc,y,b(1),b(4)
cm,agr1,area
! --- 3d meshing ---
type,1
mat,1
esize,,nz1
asel,s,area,,agr1
vext,all,,,0,0,-hs
alls
mat,2
esize,,nz1
asel,s,area,,agr1
vext,all,,,0,0,hs
alls
! --- PML element ---
type,2
mat,1
esize,,nz1
asel,s,loc,z,0
asel,u,area,,agr1
vext,all,,,0,0,-hs
mat,2
esize,,nz1
asel,s,loc,z,0
asel,u,area,,agr1
vext,all,,,0,0,hs
esize,,nz2
asel,s,loc,z,hs
vext,all,,,0,0,hs
asel,s,loc,z,0
aclear,all
alls
nummrg,all
! --- PEC for microstrip and PML wall ---
nsel,s,loc,z,0
nsel,r,loc,x,a(4),a(5)
nsel,r,loc,y,b(1),b(2)
d,all,ax,0
nsel,s,loc,z,0
nsel,r,loc,x,a(3),a(6)
nsel,r,loc,y,b(2),b(3)
d,all,ax,0
nsel,s,loc,y,b(1)
nsel,r,loc,x,a(2)+1.e-3,a(7)-1.e-3
nsel,r,loc,z,-hs+1.e-3,hs-1.e-3
cm,nprt,node
nsel,s,ext
nsel,u,node,,nprt
d,all,ax,0
! --- define port ---
nsel,s,loc,y,b(1)
nsel,r,loc,x,a(2),a(7)
nsel,r,loc,z,-hs,hs
sf,all,port,1
hfport,1,modal,,1,ext,1.,pi,,,1
alls
vlscale,all,,,scal,scal,scal,,,1
fini
/solu
! --- perform a frequency sweep for s-parameter from 1GHz to 20 GHz ---
spswp,1e9,20e9,0.5e9,1,,2,1
fini