FINISH

/CLEAR

dicke=1.0
dicke_Luft=1.0
hoehe=4.0

laenge = 10.0
anz_Rippen_y = 4
laenge_alu= 0.8 
laenge_luft=(laenge-anz_Rippen_y*laenge_alu)/(anz_Rippen_y-1)

breite = 6.00
anz_Rippen_x = 6
breite_alu= 0.5 
breite_luft=0.1

!Falls nur eine Rippe in X-Richtung angesetzt wird, ist sie so breit wie der Kühlkörper

*IF,anz_Rippen_x,GT,1,THEN
	breite_luft=(breite-anz_Rippen_x*breite_alu)/(anz_Rippen_x-1)
*ELSE
	breite_alu=breite
*ENDIF

/prep7

!Materialien anlegen
et,1,70
esize,0.5
mp,kxx,1,0.0237

et,2,70
esize,0.5
mp,kxx,2,0.0100262

!Bestimmung der Knoten in X-Richtung
k,1,,,-dicke_Luft
k,2,dicke_Luft,,-dicke_Luft
k,3,dicke_Luft+breite_alu,,-dicke_Luft

*IF,anz_Rippen_x,GT,1,THEN
	*do, i, 1, anz_Rippen_x-1
		k,2*i+2,i*(breite_alu+breite_luft)+dicke_luft,,-dicke_Luft
		k,2*i+3,(i+1)*breite_alu+i*breite_luft+dicke_luft,,-dicke_Luft
	*enddo 
*ENDIF
k,,(anz_Rippen_x-1)*(breite_alu+breite_luft)+breite_alu+2*dicke_luft,0,-dicke_Luft


!Spiegelung der Knoten in Y-Richtung
kgen,2,1,anz_Rippen_x*2+3,1, 0,dicke_luft,0,20
kgen,2,1,anz_Rippen_x*2+3,1, 0,laenge_alu+dicke_luft,0,40
kgen,anz_Rippen_y,21,41+anz_Rippen_x*2+3,1, 0,laenge_alu+laenge_luft,0,40
kgen,2,anz_Rippen_y*40+1,anz_Rippen_y*40+21+anz_Rippen_x*2+3,1, 0,dicke_luft,0,20

!Verbinden der Knoten zu Flächen
*do, i, 1, (anz_Rippen_x*2)+1
	A,i,i+1,21+i,20+i
	*rep,anz_Rippen_y*2+1,20,20,20,20
*enddo 



!Den Körper in Z-Richtung "aufziehen"

K,796,0,0,0
K,797,0,0,dicke
K,798,0,0,hoehe
K,799,0,0,hoehe+dicke_luft

nums,line,800
L,1,796
L,796,797
L,797,798
L,798,799
vdrag,all,,,,,,800,801,802,803

!Selektieren der benötigten Volumen

vsel,u,loc,X,0, dicke_luft
vsel,u,loc,X,breite+dicke_luft, breite+2*dicke_luft
vsel,u,loc,y,0, dicke_luft
vsel,u,loc,y,laenge+dicke_luft, laenge+2*dicke_luft
vsel,u,loc,z,0, -dicke_luft
vsel,u,loc,z,hoehe, hoehe+dicke_luft


*IF,anz_Rippen_x,GT,1,THEN
	*do, i, 1, (anz_Rippen_x*2)+1
		vsel,u,loc,X,i*breite_alu+(i-1)*breite_luft+dicke_luft, i*(breite_alu + breite_luft)+dicke_luft
	*enddo
*ENDIF

*do, i, 1, anz_Rippen_y-1
	vsel,u,loc,Y,i*laenge_alu+(i-1)*laenge_luft+dicke_luft, i*(laenge_alu + laenge_luft)+dicke_luft
*enddo

!,x,dicke_luft, breite+dicke_luft,y,dicke_luft, laenge+dicke_luft,

vsel,a,loc,z,0,dicke

vsel,u,loc,X,0, dicke_luft
vsel,u,loc,X,breite+dicke_luft, breite+2*dicke_luft
vsel,u,loc,y,0, dicke_luft
vsel,u,loc,y,laenge+dicke_luft, laenge+2*dicke_luft
vsel,u,loc,z,0, -dicke_luft
vsel,u,loc,z,hoehe, hoehe+dicke_luft


CM,ALU,VOLU

vsel,inve

CM,LUFT,VOLU

!Meshen der Luft und ALU
MAT,2
TYPE,2
vmesh,LUFT

CMSEL,S,ALU
MAT,1
TYPE,1
vmesh,ALU

/SOLU

cmsel, s, ALU, volu
eslv, s

nsel,s,loc,z
nsel,r,loc,x,0.365*breite+dicke_luft,0.635*breite+dicke_luft	!Breite des Widerstands ist 16mm
nsel,r,loc,y,0.395*laenge+dicke_luft,0.605*laenge+dicke_luft	!Länge des Widerstands ist 21mm

sf,all,hflux,35
!d,all,temp,100

ALLS

nsel,s,loc,z,hoehe+dicke_luft
nsel,a,loc,z,-dicke_luft

nsel,a,loc,y,laenge+2*dicke_luft
nsel,a,loc,y,0

nsel,a,loc,x,breite+2*dicke_luft
nsel,a,loc,x,0


d,all,temp,20

alls


SOLVE

cmsel, s, ALU, volu
eslv, s
eplot

/POST1
plns,temp

nsel,s,loc,z
nsel,r,loc,x,0.365*breite+dicke_luft,0.635*breite+dicke_luft	!Breite des Widerstands ist 16mm
nsel,r,loc,y,0.395*laenge+dicke_luft,0.605*laenge+dicke_luft	!Länge des Widerstands ist 21mm

etable,temp_,temp
ssum
*get,temp_sum,ssum,,item,temp_
*get,nanz,node,,count

!prnsol,temp


!*get,q,fsum,heat
!*get,emax,elem,,num,max
!*get,emin,elem,,num,min
!*dim,vol,,emax-emin+1
!*get,vol(1:emax-emin+1),elem,(emin:emax),volu
!*vscfun,volsum,sum,vol
!qref=-(ABS(Q)**1.8)
!KRIT=QREF/VOLSUM


!/input,C:\obth1012\Speicherbefehl,txt