!*******************************************************************
!Projekt: 	Modell des Standard-Kleinteil-Versuches_01_DY_Viertel
!Bearbeiter:	Thoralf Kästner
!*******************************************************************


finish		!aktuellen Prozess beenden
/clear,start	!Speicher leeren und ANSYS neustarten
!/CWD,'D:\ANSYS Berechnungen\Start'
/FILNAME,SKV_DY_46_100_alpha_45,1
!*******************************************************************
!Randbedingungen der Berechnung
Belastungsart = 1	!Belastungsart: 1 = Verschiebung ; 2 = Zugkraft (Verschiebung noch nicht implementiert)
NLGeometrie   = 1	!Berücksichtigung nicht linearer Geometrie: 0 = Nein ; 1 = Ja	
Schaedigung   = 1	!Berücksichtigung des Schädigungsmodells nach Gurson: 0 = Nein ; 1 = Ja


!Eingangswerte
!Basiseinheiten:	[N] und [mm]
!Probengeometrie: 

a 		= 5			!Nahtdicke 
sin_alpha	= 0.38268		!Sinus des halben Nahtöffnungswinkels
sin_alpha2	= 0.92388		!Sinus des Gegenwinkels
e 		= 0.5			!Einbrand
w  		= 1.5			!Breite Wärmeeinflusszone
b0		= 3*a			!Probenbreite
bk		= 4*a			!Probenbreite-Kopf
t		= 5			!Probendicke
l1		= a			!Höhe feine Vernetzung GW
lc		= 60			!Versuchslänge
le		= 10			!Übergangslänge Probenkörper-Probenkopf
ll		= 9			!Lasteinleitungslänge
	
!Material:
EM  		= 210000		!E-Modul
v  		= 0.3			!Querkontraktionszahl
fy1 		= 460.0			!Fließspannung 
f01 		= 0.0020		!Primärhohlraumbildner Anteil
fc1		= 0.0420		!Kritischer Hohlraumanteil
fF1		= 0.150			!Failure Hohlraumanteil

fy2 		= 506.0	
f02 		= 0.0030
fc2		= 0.0420
fF2		= 0.150	

fy3 		= 460.0	
f03 		= 0.0026
fc3		= 0.0420
fF3		= 0.150		
q1  		= 1.50			!Anpassungsparameter
q2  		= 1.00
q3  		= 2.25

!Belastung:
vy 		= 1.0			!Verschiebungsgröße
q  		= 440			!Belastung (Zugkräfte positiv) 


!Netzgrößen
nSG 	  	= 0.5 			!Elementgröße Schweißgut
nWEZ		= 0.8			!Elementgröße Wärmeeinflusszone
nGW_l1    	= 1.0			!Elementgröße GW_fein
nGW_lc  	= 3.0			!Elementgröße Versuchslänge
nGW_le  	= 3.0			!Elementgröße Lasteinleitung





!*******************************************************************
/prep7		!Preprozessor starten
ET,1,186,	!Elementtyp 1 ist Solid186 
!*******************************************************************
!Material	(Material 1 = SG, 2 = WEZ, 3 = GW)
Type,all	!Zuweistung zu Elementtyp 1


MPTEMP,1,0


MPDATA,EX,1,,EM 
MPDATA,EY,1,,EM
MPDATA,EZ,1,,EM
MPDATA,PRXY,1,,v	!Querdehnzahl	 
TB,PLASTIC,1,1,9,MISO	!Multilineares Werkstoffverhalten  		
TBTEMP,0		!Bezugstemperatur							
!Gleichmaßdehnung								
TBPT,DEFI,0.00000,460.0												
TBPT,DEFI,0.00051,481.3						
TBPT,DEFI,0.00260,495.4						
TBPT,DEFI,0.02250,512.5						
TBPT,DEFI,0.04660,575.4						
TBPT,DEFI,0.07013,617.1						
TBPT,DEFI,0.09312,643.5						
TBPT,DEFI,0.11559,670.5						
TBPT,DEFI,0.13757,685.4	
	


MPDATA,EX,2,,EM    
MPDATA,EY,2,,EM
MPDATA,EZ,2,,EM      
MPDATA,PRXY,2,,v		 
TB,PLASTIC,2,1,7,MISO	  
TBTEMP,0										
!Gleichmaßdehnung											
TBPT,DEFI,0.00000,506.0
TBPT,DEFI,0.00122,590.6
TBPT,DEFI,0.00397,608.9
TBPT,DEFI,0.01346,650.4
TBPT,DEFI,0.02909,698,1
TBPT,DEFI,0.04447,726.3
TBPT,DEFI,0.05729,740.3							
								

MPDATA,EX,3,,EM 
MPDATA,EY,3,,EM
MPDATA,EZ,3,,EM         
MPDATA,PRXY,3,,v		 
TB,PLASTIC,3,1,9,MISO	  
TBTEMP,0							
!Gleichmaßdehnung								
TBPT,DEFI,0.00000,460.0											
TBPT,DEFI,0.00031,471.2						
TBPT,DEFI,0.00081,501.5						
TBPT,DEFI,0.00235,537.4						
TBPT,DEFI,0.00578,554.4						
TBPT,DEFI,0.01761,593.6						
TBPT,DEFI,0.03703,639.6						
TBPT,DEFI,0.05608,667.8						
TBPT,DEFI,0.07190,682.8		


*if,Schaedigung,eq,1,then
	! Gurson Model   
	tb,gurs,1,1,5,BASE	! BASE DEFINED   
	tbdata,1,fy1,f01,q1,q2,q3	

	tb,gurson,1,,2,coal
	tbdata,1,fc1,fF1

	tb,gurs,2,1,5,BASE	! BASE DEFINED   
	tbdata,1,fy2,f02,q1,q2,q3

	tb,gurson,2,,2,coal
	tbdata,1,fc2,fF2

	tb,gurs,3,1,5,BASE	! BASE DEFINED   
	tbdata,1,fy3,f03,q1,q2,q3

	tb,gurson,3,,2,coal
	tbdata,1,fc3,fF3
*endif
!*******************************************************************
!Geometrie 
!Berechnung von Eingangsgrößen
ba	= (a*sin_alpha)/(sin_alpha2)	!Halbe Breite Schweißnaht 
bw	= (W)/(sin_alpha2)		!Breite WEZ	


!Keypoints 
k,100,b0/2,e+ba,0
k,101,b0/2,0,0
k,102,a/2-e,e,0
k,103,0,e,0
k,104,0,0,0

k,150,b0/2,e+ba,t
k,151,b0/2,0,t
k,152,a/2-e,e,t
k,153,0,e,t
k,154,0,0,t

k,200,b0/2,e+ba+bw,0
k,201,a/2-2*e,bw,0
k,202,0,bw,0

k,250,b0/2,e+ba+bw,t
k,251,a/2-2*e,bw,t
k,252,0,bw,t

k,300,b0/2,e+ba+bw+l1,0
k,301,0,e+ba+bw+l1,0


k,350,b0/2,e+ba+bw+l1,t
k,351,0,e+ba+bw+l1,t


k,400,b0/2,e+ba+bw+lc/2,0
k,401,0,e+ba+bw+lc/2,0


k,450,b0/2,e+ba+bw+lc/2,t
k,451,0,e+ba+bw+lc/2,t


k,500,bk/2,e+ba+bw+lc/2+le,0
k,501,0,e+ba+bw+lc/2+le,0


k,550,bk/2,e+ba+bw+lc/2+le,t
k,551,0,e+ba+bw+lc/2+le,t

k,600,bk/2,e+ba+bw+lc/2+le+ll,0
k,601,0,e+ba+bw+lc/2+le+ll,0

k,650,bk/2,e+ba+bw+lc/2+le+ll,t
k,651,0,e+ba+bw+lc/2+le+ll,t

!Flächen
a,100,102,103,104,101		!Fläche 1
a,150,152,153,154,151		!Fläche 2
a,100,102,152,150		!Fläche 3
a,102,103,153,152		!Fläche 4
a,103,104,154,153		!Fläche 5
a,104,101,151,154		!Fläche 6
a,101,100,150,151		!Fläche 7

a,100,200,201,202,103,102	!Fläche 8
a,150,250,251,252,153,152	!Fläche 9
a,200,201,251,250		!Fläche 10
a,201,202,252,251		!Fläche 11
a,202,103,153,252		!Fläche 12
a,100,200,250,150		!Fläche 13	

a,200,201,202,301,300		!Fläche 14
a,250,251,252,351,350		!Fläche 15
a,200,300,350,250		!Fläche 16
a,301,202,252,351		!Fläche 17
a,300,301,351,350		!Fläche 18

a,400,300,301,401		!Fläche 19
a,450,350,351,451		!Fläche 20
a,400,300,350,450		!Fläche 21
a,401,301,351,451		!Fläche 22
a,400,401,451,450		!Fläche 23

a,400,500,501,401		!Fläche 24
a,450,550,551,451		!Fläche 25
a,400,500,550,450		!Fläche 26
a,401,501,551,451		!Fläche 27
a,500,501,551,550		!Fläche 28

a,600,500,501,601		!Fläche 29
a,650,550,551,651		!Fläche 30
a,600,500,550,650		!Fläche 31
a,601,501,551,651		!Fläche 32
a,600,601,651,650		!Fläche 33

!Volumen
va,1,2,3,4,5,6,7		!Volumen 1 SG
va,3,4,8,9,10,11,12,13		!Volumen 2 WEZ
va,10,11,14,15,16,17,18		!Volumen 3 GW,1
va,18,19,20,21,22,23		!Volumen 4 GW,2
va,23,24,25,26,27,28		!Volumen 5 GW,3
va,28,29,30,31,32,33		!Volumen 6 GW,4

cyl4,0,0,a/2,,,,t	!Volumen 7_Bohrung
cyl4,0,0,a/2,,,,t	!Volumen 8_Bohrung
cyl4,0,0,a/2,,,,t	!Volumen 9_Bohrung

cyl4,a+a/2+20,e+ba+bw+lc/2,20,,,,t	!Volumen 10_Ausrundung

vsbv,1,7
vsbv,2,8
vsbv,3,9
vsbv,5,10

vglue,all

!*******************************************************************
!Netzgenerierung

mshape,1,3D		!Netzart 
TYPE,1			!Elementtyp

mat,1			!Material 1 aktiv setzen
esize,nSG		!Elementgröße
vsel,s,VOLU,,5		!Volumen 1 aktiv setzen
vmesh,all

mat,2			
esize,nWEZ		
vsel,s,VOLU,,1		
vmesh,all


mat,3			
esize,nGW_l1		
vsel,s,VOLU,,7	
vmesh,all

esize,nGW_lc		
vsel,s,VOLU,,4		
vmesh,all

esize,nGW_le		
vsel,s,VOLU,,3	
vsel,a,VOLU,,6	
vmesh,all

!*******************************************************************
!Lagerungsbedingungen

asel,s,AREA,,53
DA,all,Uy

asel,s,AREA,,4
asel,a,AREA,,22
asel,a,AREA,,27
asel,a,AREA,,32
DA,all,UX

asel,s,AREA,,29
asel,a,AREA,,30
DA,all,UX
DA,all,UZ

!*******************************************************************
!Lasten
*if,Belastungsart,eq,1,then
	Da,29,uy,vy	
	Da,30,uy,vy
	AUTOTS,ON
	NSUBST,100,1000,30
	alls
*elseif,Belastungsart,eq,2,then
	asel,s,AREA,,33
	SFA,all,,Press,-q
	AUTOTS,ON
	NSUBST,100,1000,30
*endif
!*******************************************************************
ksel,s,KP,,all
lsel,s,LINE,,all
asel,s,AREA,,all
allsel
finish			!Preprozessor beenden
!*******************************************************************

/solu
antype,0
*if,NLGeometrie,eq,1,then
	NLGEOM,ON
	PRED,ON
*elseif,NLGeometrie,eq,0,then
	NLGEOM,OFF
*endif
outres,all,all
solve
finish

!*******************************************************************
/POST1