// Zeichnungs-Verwaltung 3.0 - 13.04.2003
zv:dialog {
  label = "  Zeichnungs-Verwaltung 3.0" ;
  initial_focus = "CANCEL";
//-------------------r 1
  : row {
//-------------------c 1
    : column {
//-------------------bc 1
      : boxed_column {
        width = 75;
        height = 12.88;
        fixed_height = true;
        fixed_width = true;
        label = "Neues Projekt-Verzeichnis anlegen";
        : row {
          label = "";
          : text {
            label = "Projekt-Name";
            width = 15;
            fixed_width = true;
          }
        }
        : row {
          : edit_box {
            label = "";
            key = "PROJ_NEU_NAME";
            edit_width = 52.5;
            fixed_width = true;
            fixed_width_font = true;//-----------------------
          }
          spacer;
        }
        : row {
          label = "";
          : text {
            label = "Projekt-Verzeichnis";
            width = 32;
            fixed_width = true;
          }
        }
        : row {
          : edit_box {
            label = "";
            key = "PROJ_NEU_PFAD";
            edit_width = 52.5;
            fixed_width = true;
            fixed_width_font = true;//------------------------
          }
          spacer;
        }
        : spacer {
          height = 0.10;
        }
        : row {
          : spacer {
            width = 18;
          }
          : button {
            label = "Ordner suchen";
            mnemonic = "O";
            key ="PROJ_NEU_PFAD_SUCHEN";
            width =25;
            fixed_width = true;
          }
          : button {
            label = "Projekt anlegen / OK";
            mnemonic = "P";
            key ="PROJ_ANLEGEN";
            width = 25;
            fixed_width = true;
          }
          spacer;
        }
        : row {
          : concatenation {
            : text_part {
              label = "Hinweis: ";
              width = 8;
              fixed_width = true;
            }
            : text_part {
              label = "";
              key = "hinweis1";
              width = 60;
              fixed_width = true;
              alignment = centered;
              is_error_tile = true;
            }
          }
          spacer;
        }
      }
//-------------------bc 1
//-------------------bc 2
      : boxed_column {
        label = "Projekt-Verzeichnis-Liste verwalten";
        width = 75;
        height = 30.2;
        fixed_height = true;
        fixed_width = true;
        : row {
          : edit_box {
            label = "";
            key = "PATHEDIT";
            width = 54;
            fixed_width = true;
            fixed_width_font = true;//-----------------------------
          }
        }
        : row {
          : text {
            label = "";
            key = "PATHV";
            width = 18;
            fixed_width = true;
          }
          : button {
            label = "Ordner suchen";
            mnemonic = "d";
            key ="PFAD-L";
            width =22;
            fixed_width = true;
          }
          : button {
            label = "Eintrag hinzufügen / OK";
            mnemonic = "u";
            key = "HINZUFUEGEN";
            width = 16.5;
            fixed_width = true;
          }
          spacer;
        }
        : row {
          : list_box {
            label = "Projekt-Verzeichnis-Liste";
            height = 16.0;
            width = 54;
            fixed_height = true;
            fixed_width = true;
            fixed_width_font = true;//---------------------
            key = "DLIST";
            multiple_select = false;
            allow_accept = false;
            tabs = "4.0";
            value = "0";
          }
        }
        : row {
          : column {
            : row {
               : button {
                 label = "Löschen";
                 mnemonic = "ö";
                 key = "LOESCHEN";
                 width = 18;
                 fixed_width = true;
               }
               : button {
                 label = "Nach oben";
                 mnemonic = "b";
                 key = "BEWEGEN";
                 width = 24;
                 fixed_width = true;
               }
               spacer;
            }
            : row {
              : button {
                label = "Liste wählen";
                mnemonic = "t";
                key = "NLIST";
                width = 18;
                fixed_width = true;
              }
              : button {
                label = "Verzeichnis öffnen";
                mnemonic = "r";
                key = "OEFFNEN";
                width = 24;
                fixed_width = true;
              }
              spacer;
            }
          }//col
          : column {
            : row {
              : button {
                label = "Verzeichnis setzen";
                mnemonic = "V";
                key = "SETZEN";
                height = 4.0;
                width = 24;
                fixed_width = true;
              }
            }
          }//col
        }//r
        : row {
          : text {
            key = "LFILE";
            width = 70;
          }
        }//r
      }
//-------------------bc 2
    }
//-------------------c 1
//-------------------c 2
    : column {
//-------------------bc 3
      : boxed_column {
        height = 2.4;
        width = 80;
        fixed_height = true;
        fixed_width = true;
        label = "Gesetztes Verzeichnis";
        is_bold = true;
        : row {
          : text {
            label = "";
            key = "FILEDIR1";
            height = 1.2;
            width = 58;
            fixed_width = true;
            fixed_width_font = true;
          }
        }
        : spacer {
          height = 0.50;
        }
      }
//-------------------bc 3
//-------------------bc 4
      : boxed_column {
        height = 8.10;
        width = 40;
        fixed_height = true;
        fixed_width = true;
        label = "Aktive Zeichnung";
        : row {
          : text {
            label = "";
            key = "FILEDIR2";
            is_bold = true;
            height = 1.2;
            width = 59;
            fixed_width = true;
            fixed_width_font = true;
          }
        }
        : spacer {
          height = 0.2;
        }
        : row {
          : text {
            label = "";
            key = "FILENAM";
            width = 78;
            fixed_width = true;
          }
        }
        : row {
          : text {
            label = "";
            width = 78;
            fixed_width = true;
            key = "FILEDIR3";
          }
        }
        : row {
          : spacer {
            width = 57.5;
          }
          : button {
            label = "Speichern";
            width = 18;
            fixed_width = true;
            mnemonic = "S";
            key = "SPEICHERN";
          }
          spacer;
        }
        : row {
          : spacer {
            height = 0.20;
          }
        }
      }
//-------------------bc 4
//-------------------bc 5

      : boxed_column {
        label = "Explorer";
        height = 15.0;
        width = 80;
        fixed_height = true;
        fixed_width = true;
        : row {
          : text {
            label = "Öffnen in:";
            width = 20;
            fixed_width = true;
          }
        }
        : row {
          : text {
            label = "";
            key = FILEDIR;
            width = 62.5;
            fixed_width = true;
          }
          : button {
            label = "Explorer";
            mnemonic = "E";
            key = "EXPLORER";
            width = 12;
            fixed_width = true;
          }
          spacer;
        }
        : spacer {
          height = 0.1;
        }
        : row {
          : text {
            label = "...nach Änderungen im Explorer:";
            width = 42.5;
            fixed_width = true;
          }
          : button {
            label = "Datei-Fenster aktualisieren";
            mnemonic = "F";
            key ="AKTUALISIEREN";
            width = 25;
            fixed_width = true;
          }
          spacer;
        }
        : spacer {
          height = 0.1;
        }
        : text {
          label = "Logdateien und Zeichnungen öffnen in";
          width = 60;
          fixed_width = true;
        }
        : row {
          : text {
            label = "..\\ AKTUELL";
            width = 19;
            fixed_width = true;
          }
          : spacer {
            width = 17;
          }
          : text {
            label = "..\\ VERTEILT";
            width = 19;
            fixed_width = true;
          }
          : text {
            label = "..\\ VERALTET";
            width = 18;
            fixed_width = true;
          }
          spacer;
        }
        : spacer {
          height = 0.10;
        }
        : row {
          : button {
            label = "Logdateien";
            mnemonic = "L";
            key ="LogAktuell";
            width = 19;
            fixed_width = true;
          }
          : spacer {
            width = 17;
          }
          : button {
            label = "Logdateien";
            mnemonic = "g";
            key ="LogVerteilt";
            width = 19;
            fixed_width = true;
          }
          : button {
            label = "Logdateien";
            mnemonic = "a";
            key = "LogVeraltet";
            width = 18;
            fixed_width = true;
          }
          spacer;
        }
        : row {
          : button {
            label = "Zeichnungen";
            mnemonic = "Z";
            key ="ZeichnungAktuell";
            width = 19;
            fixed_width = true;
          }
          : spacer {
            width = 17;
          }
          : button {
            label = "Zeichnungen";
            mnemonic = "i";
            key ="ZeichnungVerteilt";
            width = 19;
            fixed_width = true;
          }
          : button {
            label = "Zeichnungen";
            mnemonic = "n";
            key = "ZeichnungVeraltet";
            width = 18;
            fixed_width = true;
          }
          spacer;
        }
        : spacer {
          height = 0.1;
        }
      }
//-------------------bc 5
//-------------------bc 6
      : boxed_column {
        width = 80;
        height = 13.1;
        fixed_height = true;
        fixed_width = true;
        label = "Datei kopieren von AKTUELL nach VERTEILT";
        : text {
          label = "Die Datei muß geschlossen sein, Index wird geändert!";
          width = 60;
          fixed_width = true;
          alignment = left;
        }
        : row {
          : list_box {
            label = "Aktuell";
            key = "AKTUELL";
            height = 8;
            width = 19;
            fixed_width = true;
            fixed_height = true;
            multiple_select = false;
            allow_accept = true;
          }
          spacer;
          : column {
            : row {
              : spacer {
                height = 2.50;
              }
            }
            : row {
              : button {
                label = "Copy >>";
                mnemonic = "y";
                key ="COPY";
                height = 3;
                alignment = centered;
              }
            }
            : spacer {
              height = 1.50;
            }
          }
          spacer;
          : list_box {
            label = "Verteilt";
            key = "VERTEILT";
            height = 8;
            width = 19;
            fixed_width = true;
            fixed_height = true;
          }
          : list_box {
            label = "Veraltet";
            key = "VERALTET";
            height = 8;
            width = 18;
            fixed_width = true;
            fixed_height = true;
          }
          spacer;
        }
        : row {
          : concatenation {
            : text_part {
              label = "Hinweis: ";
            }
            : text_part {
              label = "";
              key = "hinweis2";
              width = 60;
              fixed_width = true;
            }
          }
        }
      }
//-------------------bc 6
    }
//-------------------c 2
  }
//-------------------r 1
  : spacer {
    height = 0.1;
  }
//-------------------r2 letzte Zeile
  : row {
    : spacer {
      width = 1;
    }
    : button {
      label = "Hilfe";
      mnemonic = "H";
      key = "HELP";
      width = 17;
      fixed_width = true;
    }
    : spacer {
      width = 113;
    }
    : button {
      label = "Schliessen";
      mnemonic = "c";
      key = "CANCEL";
      is_cancel = true;
      fixed_width = true;
    }
    spacer;
  }
//-------------------r2 letzte Zeile
}// ENDE zv:dialog
//
zvhinweis1 : dialog {
  label = "Hinzufügen";
  spacer_1;
  : text {
    label = "   Keine oder ungültige Zeichenkette.";
  }
  : text {
    label = "   Schreiben Sie bitte den vollständigen Verzeichnis-Pfad";
  }
  : text {
    label = "   oder wählen Sie ihn aus mit  <Ordner suchen>.";
  }
  : text {
    label = "   Syntax-Beispiel:   C:\\ACAD\\ZEICHNUNGEN";
  }
  spacer_1;
  ok_only;
}
zvhinweis2 : dialog {
  label = "Verzeichnis öffnen";
  spacer_1;
  : text {
    label = "    Bitte zuerst das Verzeichnis";
    alignment = centered;
  }
  : text {
    label = "    in der Verzeichnis-Liste markieren.";
    alignment = centered;
  }
  spacer_1;
  ok_only;
}
zvhinweis3 : dialog {
  label = "Löschen";
  height = 4;
  width = 50;
  fixed_height = true;
  fixed_width = true;
  spacer_1;
  : text {
    label = "Bitte den zu löschenden Verzeichniseintrag";
    alignment = centered;
  }
  : text {
    label = "zuerst in der Verzeichnis-Liste markieren.";
    alignment = centered;
  }
  spacer_1;
  ok_only;
}
zvhinweis4 : dialog {
  label = "Copy";
  spacer_1;
  : paragraph {
    height = 4;
    width = 50;
    fixed_height = true;
    fixed_width = true;
    : text {
      label = "Bitte die zu kopierende Datei";
      alignment = centered;
    }
    : text {
      label = "im Fenster AKTUELL markieren.";
      alignment = centered;
    }
  }
  spacer_1;
  ok_only;
}
zvhinweis5 : dialog {
  label = "Verzeichnis setzen";
  spacer_1;
  : text {
    label = "    Bitte zuerst das Verzeichnis";
    alignment = centered;
  }
  : text {
    label = "    in der Verzeichnis-Liste markieren.";
    alignment = centered;
  }
  spacer_1;
  ok_only;
}
invaldir : dialog {
  label = "Verzeichnis hinzufügen";
  spacer_1;
  : text {
    label = "Verzeichnis existiert nicht.  Bitte überprüfen Sie ihre Eingabe";
    alignment = centered;
  }
  spacer_1;
  ok_only;
}
save_project : dialog {
  label = "Neues Projekt anlegen";
  spacer_1;
  : paragraph {
    width = 120;
    fixed_width = true;
    : text_part {
      label = "          ";
      height = 10;
      alignment = centered;
    }
    : text_part {
      label = "Projekt anlegen?";
      height = 2;
      width = 20;
      fixed_width = true;
      alignment = centered;
      fixed_width_font = true;
    }
    : text_part {
      label = "          ";
      height = 2;
      alignment = centered;
    }
    : text_part {
      label = "";
      key = "pr_new";
      height = 3;
      width = 100;
      fixed_width = true;
      alignment = centered;
      fixed_width_font = true;
    }
    : text_part {
      label = "          ";
      height = 5;
      alignment = centered;
    }
  }
  spacer_1;
  : row {
    spacer_0;
    : button {
      label = "OK";
      mnemonic = "O";
      key = "pr_save";
      is_default = true;
      width = 15;
      fixed_width = true;
    }
    : button {
      label = "Abbrechen";
      mnemonic = "A";
      key = "pr_abort";
      is_cancel = true;
      width = 20;
      fixed_width = true;
    }
    spacer_0;
  }
}
del_dir : dialog {
  label = "Löschen";
  height = 15;
  width = 80;
  fixed_height = true;
  fixed_width = true;
  spacer_1;
  : text {
    label = "Eintrag löschen?";
    alignment = centered;
  }
  : text {
    label = "";
    key = "del_dir";
    height = 1.5;
    fixed_width_font = true;
    width = 75;
    alignment = centered;
  }
  spacer_1;
  : row {
    spacer_0;
    : button {
      label = "OK";
      mnemonic = "O";
      key = "pr_deldir";
      is_default = true;
      width = 10;
      fixed_width = true;
    }
    : button {
      label = "Abbrechen";
      key = "EintragLoeschen_abort";
      mnemonic = "A";
      is_cancel = true;
      width = 15;
      fixed_width = true;
    }
    spacer_0;
  }
}
copy_dat : dialog {
  label = "Copy";
  height = 10;
  width = 80;
  fixed_height = true;
  fixed_width = true;
  spacer_1;
  : text {
    label = "Datei in den Ordner VERTEILT kopieren?";
    alignment = centered;
  }
  : text {
    label = "";
    key = "copy_dat1";
    height = 1.5;
    fixed_width_font = true;
    alignment = centered;
  }
  spacer_1;
  : row {
    spacer_0;
    : button {
      label = "OK";
      mnemonic = "O";
      key = "copy_ok";
      width = 15;
      fixed_width = true;
    }
    : button {
      label = "Abbrechen";
      key = "CopyDatei_abort";
      mnemonic = "A";
      is_cancel = true;
      width = 20;
      fixed_width = true;
    }
    spacer_0;
  }
}