fini
/cle
/title, Kontaktproblem
/filename, contact

/prep7
cyl4,0,0,10,,20


mp, ex, 1, 210000	!E-Modul für Material1
mp, nuxy, 1, 0.3	!ny für Material 1



et,1,42			!Plane Stress
ET,2,21		!Massenknoten
KEYOPT,2,3,3	!2D Translation in X und Y und Drehung um Z möglich, damit Verschiebung und Torsion über Pilot node 10000
r,2,1e-10	!Masse gegen Null

mshkey, 0			!free meshing
ESIZE,2
type,1				!Plane42
amesh,all


n,10000,			!Massenknoten 
d,10000,uy            	!in x und y Richtung gehalten
d,10000,ux


type,2
real,2
e,10000			!MasseElement muss erzeugt werden

!Randbedingungen
csys,1
nsel,s,loc,x,20
d,all,all


!Kopplung kann per RB3 Elementen oder mittels MPC 184 erfolgen

ET,3,MPC184 
KEYOPT,3,1,1		!rigid beam


nsel,s,loc,x,10
cm,koppeln,node

type,3
*get,nanz,node,,count   	!Anzahl der Knoten
*get,nmin,node,,num,min 	!niedrigste Knotennummer
narb=nmin   	        	!Arbeits-Knoten
*do,i,1,nanz		 	!Schleife mit Nanz durchläufen  
e,10000,narb
narb=ndnext(narb)        	!Arbeitsknoten auf nächste Knotennummer
*enddo


alls

!RBE3,10000,ROTZ,koppeln,		!Kopplung per RBE-Elementen

F,10000,MZ,2
gplot


/solu
solve