fini
/cle
/title, Kontaktproblem
/filename, contact

!Einheiten:	!Weg/Länge	mm
		!Kraft		N
		!Moment		Nmm
		!E-Modul	N/mm²
		!Druck		MPa (N/mm²)

!-------------Geometriedaten
a=5		!breite
b=10		!höhe
c=20		!länge


!---Materialdaten---
e1=210000	!E-Modul [N/mm²]
e2=210000
v1=0.3		!Querkontraktionszahl definieren
v2=0.3

!--------------------PREP7----------------------
/prep7	!Preprocessor starten

!---Materialvereinbarung----
mp, ex, 1, e1	!E-Modul für Material1
mp, nuxy, 1, v1

mp, ex, 2, e2	!E-Modul für Material2
mp, nuxy, 2, v2

 !-----Contact-Reibungszahl
mp, mu, 3, 0.1

!---Elementvereinbarung---
et, 1, plane42
et, 2, targe169, ,1
KEYOPT,2,4,1			!Freiheit nur in ux
et, 3, conta171
KEYOPT,3,10,4			!Each Sub-Step
!keyopt, 3, 10, 4

r, 1
r, 2

!---Geometrievereinbarung----   
!---Quader 1
blc4, 0, 0, a, b,		!Xcorner Ycorner Width height Depth

!---Quader 2
blc4, 2, b, a/2, b,


!---Volumen vernetzen
type, 1
mat, 1
real, 1
mshky, 1
esize, 1
amesh, 1
eplo

type, 1
mat, 2
real, 1
mshky, 1
esize, 1
amesh, 2
eplo

!---Kontakte erstellen
!---die Kontakte werden doppelt definiert, aber mit vertauschtem Contact und Target
!dies ist wichtig um eine Übertragung in beide Richtungen gleichmäßig zu haben
!dabei bekommt jedes Paar eine eigene realkonstante

asel,s,,,1
lsel,s,,,3
NSLL,S,1
type, 2		!Target
mat, 3
real, 2
esurf
alls


!
asel, s, , ,2		!Quader 2 A9
lsel,s,,,5
NSLL,S,1
type, 3		!Contact
esurf
alls

asel,s,,,1
lsel,s,,,3
NSLL,S,1
type, 3		!Contact
mat, 3
real, 3
esurf
alls


!
asel, s, , ,2		!Quader 2 A9
lsel,s,,,5
NSLL,S,1
type, 2		!Contact
esurf
alls





!--------------------SOLU----------------------
/solu
!---nichtlineare Berechnung---
antype, static, new	!statische Analyse
eqslv, spar		!Specifies the type of equation solver
nlgeom, on		!nichtlineare Geometrie   
pred, -1		!Praediktor Method
			!chosen by Program for all DOFs

nsub, 10, 100, 10
outres, all, all

!---Randbedingungen---
lsel, s, , ,1
NSLL,S,1
d, all, all
alls	


!------1.Lastfall - Ini-Lastfall
time, 1
lsel, s, , , 7		!der kontakt wird initialisiert durch eine kleine Verschiebung
NSLL,S,1
d, all, uy, -0.05
allsel
lsel,s,,,8
nsll,s,1
d,all,ux,0
alls
lswrite,1


!------2.Lastfall

time, 2	
lsel, s, , , 7		!nach der ini wird die verschiebung gelöscht
NSLL,S,1
ddele, all, all
allsel


lsel, s, , , 7		!aufbringen von druck
NSLL,S,1
!d,all,uy,-0.2
cp,1,uy,all
NSEL,r,loc,x,2
*get,NN,node,0,count
F,all,Fy,-100000/NN
allsel
lsel,s,,,8
nsll,s,1
d,all,ux,0
alls

eplo
lswrite,2
lssolve,1,2

fini
/DSCALE,1,1.0 

!--------------------POST1----------------------
/post1
plnsol, s,eqv