@echo off
rem
rem File Name:  START_UGMANAGER.BAT
rem 
rem ************************************************************************
rem
rem This script will set the appropriate variables and then run UG/Manager
rem without workspace.
rem
rem Copyright (c) 1995-1999
rem Unigraphics Solutions, Cypress, CA 90630
rem All Rights Reserved
rem
rem Input Parameters:
rem
rem Command line parameters will be passed through to Unigraphics.
rem
rem NOTE: You MUST use a colon "" for key=value pairs
rem 
rem       For example:
rem       start_ugmanager test.bkm -opts "-u=tom" "-p=tom"
rem
rem ************************************************************************
rem Revision History:
rem
rem REV   AUTHOR      DATE      COMMENT
rem ===   ======      =======   =======
rem 31-Jul-2001  rupert                  Add UGII_BASE_DIR
rem 01-Oct-2001  brownch                 Fixed PR4338228.
rem 16-Dec-2005  yang                    4-tier NX Manager
rem 08-Jan-2006  Mathieu Sarrazy         Merge from CVG_P10.0.1.5
rem $HISTORY$
rem ************************************************************************

set IMAN_ROOT=C:\UGS\TEAMCE~1\ENGINE~1\2005SR1
set UGII_BASE_DIR=c:\UGS\nx5041patch
set UGII_ROOT_DIR=%UGII_BASE_DIR%\ugii
rem 4-tier only line set UGII_UGMGR_COMMUNICATION=HTTP

rem Check whether UGII_BASE_DIR is set
if NOT EXIST "%UGII_BASE_DIR%" goto :ug_error

rem Check whether IMAN_ROOT is set
if NOT EXIST "%IMAN_ROOT%" goto :iman_error

rem We have to append the path to the corba libraries.
rem As long as the IMAN Server is running on the local host
rem this will be IMAN_BIN.
set IMANLIBS=%IMAN_BIN%
if "%IMAN_BIN%"=="" set IMANLIBS=%IMAN_ROOT%\bin
set Path=%PATH%;%IMANLIBS%

rem Disable the flash
set UGII_DISABLE_FLASH=YES

rem Set the pdi corba library.
rem This expects this library to be found in UGII_LIB_PATH
set UGII_UGMGR_EXTERNAL_COMMS_LIB=pdi_corba_client

rem
rem Figure out the startup directory
rem The order of precedence is: API_DEFAULT_DIR, HOME, IMAN_TMP_DIR, UGII_TMP_DIR, TEMP
rem Otherwise we might end up in trouble if the current working
rem directory we were started up from is not writable.
rem
set START_DIR=%API_DEFAULT_DIR%
if "%START_DIR%"=="" set START_DIR=%HOME%
if "%START_DIR%"=="" set START_DIR=%IMAN_TMP_DIR%
if "%START_DIR%"=="" set START_DIR=%UGII_TMP_DIR%
if "%START_DIR%"=="" set START_DIR=%TEMP%

cd /d %START_DIR%

rem Start Unigraphics through the launcher program
%UGII_ROOT_DIR%\ugs_router -ugm -enable_cancel -version=V23.0 %*
goto :ENDOFFILE

:ug_error
echo UGII_BASE_DIR must be set
pause
goto :ENDOFFILE

:iman_error
echo IMAN_ROOT must be set
pause
goto :ENDOFFILE

:ENDOFFILE

@echo on