FINI
/CLEAR, NOSTART
/FILENAME, ohne_Reibung
/TITLE, ohne_Reibung

/prep7

! Elementtypen
	ET, 1, SOLID45

! Materialmodelle
  ! Sand
	MP, EX, 1, 26670
	MP, PRXY, 1, 0.333
	MP, DENS, 1, 1.8
	TB, DP, 1, , , , 1
	TBDATA, 0, , 0.1, 30, 0

! Keypoints
	K, 1, 0, 0, 0
	K, 2, 10, 0, 0
	K, 3, 0, 0, 1
	K, 4, 10, 0, 1
	K, 5, 0, 10, 0
	K, 6, 10, 10, 0
	K, 7, 0, 10, 1
	K, 8, 10, 10, 1

! Volumen erstellen
	V, 1, 2, 4, 3, 5, 6, 8, 7

! Vernetzen
  ! Volumen
	VSEL, S, VOLU, , 1 
	TYPE, 1 
	MAT, 1
	ESIZE, 0.5
	VMESH, 1

! Randbedingungen
	DA, 1, UY, 0
	DA, 2, UZ, 0
	DA, 4, UZ, 0
	DA, 3, UX, 0
	DA, 5, UX, 0

!=====================================Schleifenparameter========================================

! Zeitspanne und Interval bestimmen
	TM_START = 1E-61
	TM_END = 20
	TM_INCR = 1

! Wandneigung
	ALPHA = 0.171887596371

! max. Kopfpunktauslenkung
	*AFUN, DEG
	MAX_DISP = sin(ALPHA)*10

! Tabelle erstellen (1.Spalte: Höhe, 2.Spalte: Verschiebung)
	*DIM, DISP, TABLE, 2, 2, 1, Y
	 DISP(1,0) = 0 ,10
	 DISP(1,1) = 0, 0

! Kopfpunkt-Verschiebung pro Schleifendurchlauf
	DISP_INCR = MAX_DISP/TM_END

!=======================================SOLUTION=========================================

/solu

! Solution Controls
  ! BASIC
    ! Analysis Options
	ANTYPE, STATIC, NEW
      !Large Displacement Static
	!NLGEOM, ON			!derzeit nicht nötig
    ! Time Control
      !Substeps (NSUBST, NSBSTP, NSBMX, NSBMN, Carry)
	NSUBST, 1, 10, 1, OFF

  ! NONLINEAR
    !Line search 
	LNSRCH, ON

  ! ADVANCED NL
    ! Termination Criteria
      !Behavior upon nonconvergence
	NCNV, 2

! Einstellungen für nichtlienare Berechnung
	EQSLV, SPAR
	PRED, -1
	OUTRES, NSOL, LAST

!========================================SOLVE===========================================

! Erdbeschleunigung aufbringen
	TIME, TM_START
	ACEL, 0, 9.81, 0
	SOLVE
	RESCONTROL, NORESTART, NONE

! Schleife
	*DO,TM,TM_START+1,TM_END+1,TM_INCR
	   TIME,TM
	   DA, 5, UX, %DISP%
	   SOLVE
	   DISP(2,1) = -DISP_INCR*TM
	   RESCONTROL, NORESTART, NONE
	*ENDDO

!=======================================POSTPROC=========================================

/POST1

PLNSOL, U, X, 2