FINI
/CLEAR, NOSTART
/FILENAME, mit_Reibung
/TITLE, mit_Reibung

/prep7

! Elementtypen
	ET, 1, SOLID185
	ET, 2, SHELL181
	ET, 3, TARGE170, , 1
	ET, 4, CONTA173

! Realconstants
	R, 2, 0.1
	R, 3, , , 10

! Materialmodelle
  ! Sand
	MP, EX, 1, 26670
	MP, PRXY, 1, 0.333
	MP, DENS, 1, 1.8
	TB, DP, 1, , , , 1
	TBDATA, 0, , 0.1, 30, 0
  ! Wand
	MP, EX, 2, 210000
	MP, PRXY, 2, 0.333
  ! Kontakt
	MP, MU, 3, 0.4

! Keypoints
	K, 1, 0, 0, 0
	K, 2, 10, 0, 0
	K, 3, 0, 0, 1
	K, 4, 10, 0, 1
	K, 5, 0, 10, 0
	K, 6, 10, 10, 0
	K, 7, 0, 10, 1
	K, 8, 10, 10, 1

! Sand erstellen
	V, 1, 2, 4, 3, 5, 6, 8, 7

! Wand erstellen
	A, 1, 3, 7, 5

! Vernetzen
  ! Sand
	VSEL, S, VOLU, , 1 
	TYPE, 1 
	MAT, 1
	ESIZE, 0.5
	VMESH, 1
  ! Wand
	ASEL, S, , , 7  
	TYPE, 2
	MAT, 2
	REAL, 2
	ESIZE, 0.5
	AMESH, 7

!=====================================KONTAKTE========================================

! Kontakte
  ! Sand Target
	ASEL, S, , , 5
	NSLA, S, 1
	TYPE, 3
	MAT, 3
	REAL, 3
	ESURF
  ! Wand Contact
	ASEL, S, , , 7
	NSLA, S, 1
	TYPE, 4
	ESURF
	ALLSEL
  ! Sand Contact
	ASEL, S, , , 5
	NSLA, S, 1
	TYPE, 4
	MAT, 3
	REAL, 3
	ESURF
  ! Wand Target
	ASEL, S, , , 7
	NSLA, S, 1
	TYPE, 3
	ESURF
	ALLSEL

! Ausrichtung der Normalen (für "Kontakterkennung")
	ENORM, 841
	ENORM, 881

!=====================================RANDBEDINGUNGEN=================================

! Randbedingungen
	DA, 1, UY, 0
	DA, 2, UZ, 0
	DA, 4, UZ, 0
	DA, 3, UX, 0
!	DA, 5, UX, 0		! Kontaktfläche (Sand)
	DA, 7, UX, 0		! Kontaktfläche (Shell)
	DL, 4, , UX, 0
	DL, 4, , UY, 0
	DL, 4, , UZ, 0

!=====================================Schleifenparameter==============================

! Zeitspanne und Interval bestimmen
	TM_START = 1E-61
	TM_END = 20
	TM_INCR = 1

! Wandneigung
	ALPHA = 0.171887596371

! max. Kopfpunktauslenkung
	*AFUN, DEG
	MAX_DISP = sin(ALPHA)*10

! Tabelle erstellen (1.Spalte: Höhe, 2.Spalte: Verschiebung)
	*DIM, DISP, TABLE, 2, 2, 1, Y
	 DISP(1,0) = 0 ,10
	 DISP(1,1) = 0, 0

! Kopfpunkt-Verschiebung pro Schleifendurchlauf
	DISP_INCR = MAX_DISP/TM_END

!=======================================SOLUTION-EINSTELLUNGEN========================

/solu

! Solution Controls
  ! BASIC
    ! Analysis Options
	ANTYPE, STATIC, NEW
      !Large Displacement Static
	!NLGEOM, ON			!derzeit nicht nötig
    ! Time Control
      !Substeps (NSUBST, NSBSTP, NSBMX, NSBMN, Carry)
	NSUBST, 1, 10, 1, OFF

  ! NONLINEAR
    !Line search 
	LNSRCH, ON

  ! ADVANCED NL
    ! Termination Criteria
      !Behavior upon nonconvergence
	NCNV, 2

! Einstellungen für nichtlienare Berechnung
	EQSLV, SPAR
	PRED, -1
	OUTRES, NSOL, LAST

!========================================SOLVE=======================================

! Kontakte durch kleine Verschiebung initialisieren
	TIME, TM_START
	ASEL, S, , , 7
	NSLA, S, 1
	D, ALL, UX, -0.1
	ALLSEL
	SOLVE

	TIME, TM_START+1
	ASEL, S, , , 7
	NSLA, S, 1
	DDELE, ALL, ALL
	ALLSEL
	SOLVE

! Erdbeschleunigung aufbringen
	TIME, TM_START+2
	ACEL, 0, 9.81, 0
	SOLVE
	RESCONTROL, NORESTART, NONE

! Schleife
	*DO,TM,TM_START+3,TM_END+3,TM_INCR
	   TIME,TM
	   DA, 7, UX, %DISP%
	   SOLVE
	   DISP(2,1) = -DISP_INCR*TM
	   RESCONTROL, NORESTART, NONE
	*ENDDO

!=======================================POSTPROC=====================================

/POST1

PLNSOL, U, X, 2