Hot News:

Mit Unterstützung durch:

  Foren auf CAD.de (alle Foren)
  Inventor
  iLogic Regel aus Dokument in Externe Regeln verschieben?

Antwort erstellen  Neues Thema erstellen
CAD.de Login | Logout | Profil | Profil bearbeiten | Registrieren | Voreinstellungen | Hilfe | Suchen

Anzeige:

Darstellung des Themas zum Ausdrucken. Bitte dann die Druckfunktion des Browsers verwenden. | Suche nach Beiträgen nächster neuer Beitrag | nächster älterer Beitrag
  
Gut zu wissen: Hilfreiche Tipps und Tricks aus der Praxis prägnant, und auf den Punkt gebracht für Autodesk Produkte
Autor Thema:  iLogic Regel aus Dokument in Externe Regeln verschieben? (627 mal gelesen)
luziano
Mitglied



Sehen Sie sich das Profil von luziano an!   Senden Sie eine Private Message an luziano  Schreiben Sie einen Gästebucheintrag für luziano

Beiträge: 164
Registriert: 03.02.2005

IV 2016, 2018, 2020, 2023 2024
WIN10(64)
Q9450, 32GB
Quadro K4200

erstellt am: 26. Feb. 2021 18:13    Editieren oder löschen Sie diesen Beitrag!  <-- editieren / zitieren -->   Antwort mit Zitat in Fett Antwort mit kursivem Zitat    Unities abgeben: 1 Unity (wenig hilfreich, aber dennoch)2 Unities3 Unities4 Unities5 Unities6 Unities7 Unities8 Unities9 Unities10 Unities

Hallo zusammen,
ich bin noch nicht sehr tief in die iLogic-Thematik eingestiegen - und würde daher gerne endlich mal wissen, ob sich Regeln aus dem Dokument in "Externe Regeln" verschieben/kopieren lassen OHNE den Code zu kopieren und ihn dann extern zu speichern?
Und: Gibt es eine Möglichkeit sich anzeigen zu lassen in welchen Dateien welche (internen) Regeln liegen ohne jedes IAM, IPT, IDW zu öffnen?
Danke für eure Hilfe und ein gutes Wochenende! 

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

rkauskh
Moderator
Dipl.-Ing. (FH) Versorgungstechnik




Sehen Sie sich das Profil von rkauskh an!   Senden Sie eine Private Message an rkauskh  Schreiben Sie einen Gästebucheintrag für rkauskh

Beiträge: 2428
Registriert: 15.11.2006

Windows 10 x64, AIP 2023

erstellt am: 28. Feb. 2021 12:31    Editieren oder löschen Sie diesen Beitrag!  <-- editieren / zitieren -->   Antwort mit Zitat in Fett Antwort mit kursivem Zitat    Unities abgeben: 1 Unity (wenig hilfreich, aber dennoch)2 Unities3 Unities4 Unities5 Unities6 Unities7 Unities8 Unities9 Unities10 Unities Nur für luziano 10 Unities + Antwort hilfreich

Hallo

Frage 1:
Nein. Wie soll der Code denn sonst dahin kommen, außer das er kopiert wird? Falls du eine Exportfunktion meinst (auch ein Kopieren), die gibt es so nicht. Aber man kann sich was programmieren (s.u.).

Frage 2:
Nein. Egal ob Inventor oder ApprenticeServer, alle öffnen die Datei, um hinein zu sehen. Wenn du eine Übersicht willst, wirst du nicht drum herum kommen jede Datei einmal zu öffnen und die Namen der enthaltenen Regeln auszulesen. Danach kannst du die Namen in einer Meldung anzeigen, in eine Textdatei zu schreiben oder ... Die Frage ist, was du als Endziel hast.


Code:

Option Explicit

'Zielpfad für den Export
Const sTargetPath As String = "C:\Temp"

'Sollen im Zielpfad existierende, gleichnamige Regeln überschrieben werden?
Const bOverwriteExisting As Boolean = False    ' True = überschreiben
                                                ' False = nicht überschreiben, Export wird übersprungen

'Sollen erfolgreich exportierte Regeln deaktiviert, gelöscht oder belassen werden ?
Const iStatus As Integer = 3        ' 1 = löschen
                                    ' 2 = deaktivieren
                                    ' 3 = ignorieren

Private Sub iLogicRuleNames()

    Dim oApp As Inventor.Application
    Set oApp = ThisApplication
   
    Dim oDoc As Document
    Set oDoc = oApp.ActiveDocument
   
    Dim iLogicAuto As Object
    Set iLogicAuto = iLogicAddin(oApp)
   
    If (iLogicAuto Is Nothing) Then Exit Sub
   
    Dim oRule As Object
    Dim sName As String
    Dim sText As String
    Dim sFailedRules As String
   
    For Each oRule In iLogicAuto.Rules(oDoc)
        sName = oRule.Name
        sText = oRule.Text
       
        If ExportRule(sName, sText) = False Then
            sFailedRules = sFailedRules & vbCrLf & sName
        Else
            Select Case iStatus
                Case 1: Call iLogicAuto.DeleteRule(oDoc, oRule.Name)
                Case 2: oRule.isActive = False
                Case 3:
            End Select
        End If
    Next
   
    If Not sFailedRules = "" Then
        Call MsgBox("Der Export folgender Regeln ist fehlgeschlagen." & vbCrLf & "Die häufigste Ursache, eine gleichnamige Regel existiert bereits." & vbCrLf & sFailedRules, vbCritical, "Export Rules")
    End If
End Sub

Private Function iLogicAddin(oApp As Inventor.Application) As Object
    On Error GoTo NotFound
   
    Dim oAddIn As ApplicationAddIn
    Set oAddIn = oApp.ApplicationAddIns.ItemById("{3bdd8d79-2179-4b11-8a5a-257b1c0263ac}")
   
    If (oAddIn Is Nothing) Then GoTo NotFound
    If oAddIn.Activated = False Then oAddIn.Activate
   
    Set iLogicAddin = oAddIn.Automation
    Exit Function

NotFound:

End Function

Private Function ExportRule(ByVal sName As String, ByVal sText As String) As Boolean

On Error GoTo Fail

Dim oFs As FileSystemObject
Set oFs = CreateObject("Scripting.FileSystemObject")

If Not Right(sTargetPath, 1) = "\" Then sName = "\" & sName

Dim sFullFilename As String
sFullFilename = sTargetPath & sName & ".iLogicVb"

Dim oFile As TextStream
Set oFile = oFs.CreateTextFile(sFullFilename, False)

oFile.WriteLine (sText)
oFile.Close

ExportRule = True
Exit Function

Fail:

End Function


------------------
MfG
Ralf

RKW Solutions GmbH
www.RKW-Solutions.com

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

Anzeige.:

Anzeige: (Infos zum Werbeplatz >>)

Darstellung des Themas zum Ausdrucken. Bitte dann die Druckfunktion des Browsers verwenden. | Suche nach Beiträgen

nächster neuerer Beitrag | nächster älterer Beitrag
Antwort erstellen


Diesen Beitrag mit Lesezeichen versehen ... | Nach anderen Beiträgen suchen | CAD.de-Newsletter

Administrative Optionen: Beitrag schliessen | Archivieren/Bewegen | Beitrag melden!

Fragen und Anregungen: Kritik-Forum | Neues aus der Community: Community-Forum

(c)2024 CAD.de | Impressum | Datenschutz