---

Hallo

ich möchte eine Access - Verbindung erstellen um Daten aus eine Datenbank auszulesen und eine Zeichnung zu öffnen.
Wie ich Access öffne aus autocad habe ich schon gefunden, aber wie kann ich prüfen ob die MDB schon offen ist??

Set MyACCESS = GetObject(MAG_MDB, "access.application") '
       
    If Err.Number <> 0 Then
        msgi = MsgBox("Keine Datenbank gefunden" + MAG_MDB, , "Start MDB")
    End If

Auch würde ich gern ein bestimmtes Formular öffnen, wenn es noch nicht geöffnet ist

Ich Danke Euch schon jetzt !

------------------
Grüße
Jörg Lipphardt

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Hallo Jörg,

ich habs leider nicht mehr so genau in Erinnerung. Aber ungefähr so könnte es gehen.

Code:

---

Option Explicit

Sub Access()
Dim MyAccess As Access.Application
Dim vlst_DB As String

    vlst_DB = "C:\Temp\db1.mdb"
    On Error Resume Next
    Set MyAccess = GetObject(, "access.application") '
       
    If Err.Number <> 0 Then
        MsgBox "Keine Datenbank gefunden. Lade ...", , "Start MDB"
        On Error GoTo 0
        Set MyAccess = CreateObject("access.application")
        MyAccess.OpenCurrentDatabase "C:\Temp\db1.mdb"
        MyAccess.Visible = True
    End If
    On Error GoTo 0
    ''' Aufruf über Access Modul
    MyAccess.Run "openform", "Formular1" 
    ''' Direkter Aufruf
    MyAccess.DoCmd.OpenForm "Formular1", acNormal, , , , acWindowNormal

    MsgBox "Ergebnis:" & MyAccess.Run("addiere", 12, 20)
   
    MyAccess.Forms.Item("Formular1").Caption = "HALLO, geöffnet von AutoCAD"

End Sub

---

Und noch ein wenig Access Code

Code:

---

Sub OpenForm(vlst_Form As String)
    DoCmd.OpenForm vlst_Form
End Sub
Function Addiere(Wert1 As Double, Wert2 As Double) As Double
    Addiere = Wert1 + Wert2
End Function

---

Viel Erfolg

Wilfried Stelberg

------------------
Warum lisp'eln wenn's auch anders geht. 
www.ib-stelberg.de

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Hallo Wilfried

super, dass ist genau dass was ich suche !

Ein dickes Danke an dich!
   

------------------
Grüße
Jörg Lipphardt

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP