---

Hallo zusammen,

ich bin neu in diesem Geschäft (VBA ACAD) und habe ein gleich ein Problem.

Ich habe ein Serie von Zeichnungen in denen sich links unten ein MText befindet (Koordinaten 42.5,11,0). Diesen Text möchte ich auslesen und mit dem Zeichnungsnamen in eine txt schreiben lassen. Das mit dem Namen ist kein Problem aber das Selectieren des Textes erweist sich als würg. Wo liegt mein (der) Fehler? Ich habe das Exempel aus der „Hilfe“ genommen siehe unten.

Sub Example_SelectAtPoint()
    Dim ssetObj As AcadSelectionSet
    Set ssetObj = ThisDrawing.SelectionSets.Add("TEST_SSET2")
    Dim point(0 To 2) As Double
    point(0) = 42.5: point(1) = 11: point(2) = 0
    ssetObj.SelectAtPoint point
End Sub

MfGrüße
Armand

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Hi & welcome,

ja, sendcommand "_mtedit" und sendkeys "^a" und sendkeys "^c"
geht schonmal nicht, bzw. halt nur zu Fuss, da während der Texteditor aktiv ist, acadbefehle nicht ausgeführt werden.
Damit hättest Du wenigstens den Text in der Zwischenablage ohne Formatierungsmüll.
Na was soll's, is halt alles nich so einfach ...
Für 'einfache' Mtexte kannste den Textstring auslesen, also so in etwa:

Code:

---

Sub a()
  Dim sset As AcadSelectionSet
  Dim pnt#(2), i%, s$
  pnt(0) = 42.5: pnt(1) = 11
  With ThisDrawing
      Set sset = .SelectionSets.Add("newset")
      sset.SelectAtPoint pnt
      s = Replace(sset.Item(0).TextString, "\P", Chr(13))
      Open "d:\" & Left(.Name, Len(.Name) - 3) & "txt" For Output As #1
      Print #1, s
      Close #1
      sset.Delete
  End With
End Sub

---

Gruss Nancy 

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Hallo Armand,

hab gerade gesehen das schon eine Antwort da war.
Hatte das Beispiel gerade fertig gestückelt und schickst halt mal.
Ist aber der gleiche Ansatz wie bei Nancy.

Code:

---

Dim Ausgabedatei As String
Dim SelSet As AcadSelectionSet
Dim SelPkt(0 To 2) As Double
Dim MyText As AcadMText
Dim Text As String
Dim intAusgabe As Integer

Dim GpType(0 To 0) As Integer
Dim GpValue(0 To 0) As Variant
Dim FilterType As Variant
Dim FilterValue As Variant

On Error Resume Next
Err.Clear
' Versuch Zuweisung MySelSet
Set SelSet = ThisDrawing.SelectionSets("MySelSet")
If Err.Number <> 0 Then
  ' Selektionset war noch nicht da
  Set SelSet = ThisDrawing.SelectionSets.Add("MySelSet")
End If

On Error GoTo 0

' Punkt angeben
SelPkt(0) = 50: SelPkt(1) = 50
' Filter für Mtext
GpType(0) = 0
GpValue(0) = "MTEXT"
' Nach Variant
FilterType = GpType
FilterValue = GpValue
' Selektion an diesem Punkt holen
SelSet.Clear
SelSet.SelectAtPoint SelPkt, FilterType, FilterValue

If SelSet.Count = 0 Then
  MsgBox "Nichts gefunden"
ElseIf SelSet.Count > 1 Then
  MsgBox "Mehrere Texte gefunden"
Else
  ' Nur eins gefunden
  Set MyText = SelSet(0)
  Text = MyText.TextString
  intAusgabe = FreeFile
  Ausgabedatei = "C:\Temp\Zeichnungen.txt"
  Open Ausgabedatei For Append As #intAusgabe
  Print #intAusgabe, "Zeichnung: " & ThisDrawing.FullName & "  " & Text
  Close
End If

---

Gruß
Stelli1

------------------

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Hi Nancy,

hat super geklappt.
Warum findet man so etwas nicht in der Hilfe?

DANKE

Armand

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Zitat:

---

Original erstellt von Armand:
...Warum findet man so etwas nicht in der Hilfe?...

---

Weil in der Hilfe nur die einzelnen Funktionen und Objekte beschrieben sind, und nicht die für den Anwendungsfall sinnvolle Kombination dergleichen.

Grüße Holger

------------------
Holger Brischke
CAD on demand GmbH                              Autodesk User Group Central Europe
Individuelle Lösungen von Heute auf Morgen.              AUGCE Manager Deutschland

Jackpot on demand - Wir eröffnen den Spätsommer mit einer Verlosung!

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Hi Stelli1,

Auch das script hilft mir sehr weiter.

Gruß
Armand

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP