---

Acad3DSolid.jpg

Hallo Zusammen!

Ich versuchs mit meinem Problem mal in einem separaten Beitrag.
Wie kann man mehrere Objekte vom Typ Acad3DSolid von dem 1 Objekte vom Typ Acad3DSolid abziehen.

Dim solidobj1 As Acad3DSolid
Dim solidobj3 As Acad3DSolid

Dim retobj As Variant
retobj = solidobj3.ArrayRectangular(nor, noc, nol, dbr, dbc, dbl)

solidobj1.Boolean acSubtraction, retobj

So geht es leider nicht!

Ich habe ein Volumenkörper solidobj1 (Rechteckrohr).
Von diesem solidobj1 möchte ich nun alle solidobj3.ArrayRectangular Volumenkörper abziehen, so daß in dem Rechteckrohr die entsprechenden Löcher entstehen.

Wie müßte dafür der Code lauten?
Für Hilfe wäre ich sehr dankbar.

Gruß

Dirk

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Hi Dirk,
*uffz, schnauf, stöhn* ;-) - der code ist furchtbar mies,
auch wenn ich mich mit der Antwort nich grade mit Ruhm beklecker, keine andre Idee ...
Glaube ohne Schleife kannste das ArrayRectangular nicht vom eigentlichen Object abziehen.
Also nur ein schlechtes, wenn auch irgendwie komischerweise, laufendes Beispiel.
Lass' mich aber gerne von besserem überzeugen.
Gruss Nancy

Code:

---

Sub Example_AddBox()
    ' This example creates a box in model space.
    Dim boxObj1 As Acad3DSolid, boxObj2 As Acad3DSolid, retObj, test
    Dim length As Double, width As Double, height As Double
    Dim center(0 To 2) As Double
   
    ' Define & create box1
    center(0) = 0#: center(1) = 0#: center(2) = 5#
    length = 5#: width = 5#: height = 10#
    Set boxObj1 = ThisDrawing.ModelSpace.AddBox(center, length, width, height)
   
    ' Define & create box2
    center(0) = 0#: center(1) = 0#: center(2) = 2#
    length = 6#: width = 6#: height = 1#
    Set boxObj2 = ThisDrawing.ModelSpace.AddBox(center, length, width, height)
    ' Define the rectangular array
    retObj = boxObj2.ArrayRectangular(1, 1, 4, 1, 1, 2)
   
    'jetzt beginnen mit dem Substrahieren, genau in der Reihenfolge,
    'sonst geht u.U. in die Hose ;-)
    'first: das Ur-boxObj2 von BoxObj1 abziehen
    boxObj1.Boolean acSubtraction, boxObj2
   
    'jetze weiter scheibchenweise retobj() von boxObj1 abziehen
    Dim i%
    For i = LBound(retObj) To UBound(retObj)
      boxObj1.Boolean acSubtraction, retObj(i)
    Next

    ' Change the viewing direction of the viewport to better see the box
    Dim NewDirection(0 To 2) As Double
    NewDirection(0) = -1: NewDirection(1) = -1: NewDirection(2) = 1
    ThisDrawing.ActiveViewport.Direction = NewDirection
    ThisDrawing.ActiveViewport = ThisDrawing.ActiveViewport
    ZoomAll
End Sub

---

[Diese Nachricht wurde von startrek am 03. Jan. 2005 editiert.]

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Nachtrag:

versuchs mal zu erklären.

RetObj stellt ein Variant dar, das halt x-Objecte enthält,
um retobj auf einen Hieb vom boxObj1 abziehen zu können,
fehlt mir das Wissen, deswegen die Lösung via Schleife.

Denke mal, machbar wäre so ne Art:
set unionObject = Union(retobj)
damit wäre Unionobject wieder ein Object, das man von boxObj2 abziehen könnte,
aber sooo tief stecke ich in dem Proggie auch noch nicht drinne,
um zu sagen, hey - 'das geht so oder so' oder auch 'geht so besser'

Fakt ist, retobj muss/müsste ein [vereinigtes] Object darstellen, sonst gehts IMHO nicht abzuziehen ;-)

CU Nancy 

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Hallo Nancy!

Vielen Dank!
Ich hab es mit der Schleife probiert und auf anhieb hat es funktioniert.
Die andere Variante muß ich noch testen.

Gruß

Dirk

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Dirk, eh' Du dich an der 'andren' Variante vielleicht tot-testet ;-)
- die wird so never laufen!
Existierte diese ja nur in meinem Kopf, also sprich  - die gibts so einfach nicht!
Und wenn doch wundersamerweise, dann müssteste höchstwahrscheinlich das Unionobject genauso erstmal über ne Schleife aus retobj(i) erstellen, bevor mans von irgendwas überhaupt abziehen kann.
Is also gehüpft wie gesprungen ...
IMHO einfach mal nicht weiter - aber wirklich nicht weiter! - drüber nachdenken ;-)

Gruss Nancy

[Diese Nachricht wurde von startrek am 04. Jan. 2005 editiert.]

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP