---

Hallo zusammen,

ich habe ein Problem beim Öffnen von Baugruppen. Ich habe ein UserForm gebastelt mit dem wir in unsere Zeichnungen, Baugruppen und Bauteile öffnen können.
Das funktioniert auch alles gut, es fehlt leider nur noch das Zünglein an der Waage:
Wenn ich Baugruppen öffne werden diese seit dem Inventor 2011 immer in der Konstruktionsansichtsdarstellung "Hauptansicht" geöffnet. Dies ist in sofern eher unpraktisch, weil wir meistens eine andere Konstruktionsansichtsdarstellung verwenden.
Ich möchte also, wie beim "Offnen-Dialog" vom Inventor selber, beim öffnen der Datei gleich die zuletzt aktive Darstellung öffnen.
Aus der Programmierungshilfe habe ich zu den Design Views auch was gefunden, jedoch kann ich das nicht so umsetzen, dass ich das gewünschte Ziel erreiche.
Mein Ansatz war:
-anstatt ThisApplication.Open das ....OpenWithOptions zu nehmen. Dort kann man ja eine NameValueMap mitgeben beim Öffnen.
Dabei bekam ich leider immer ein "Type mismatch", weil ich etwas falsch deklariert habe.

-Aus der Programmierungshilfe hatte ich dann die Inventor.FileOpenOptions versucht, aber aufgrund meiner nicht so ausgereiften VBA Kenntnisse kam ich dort auch nicht weiter.

-Mit der Funktion "GetLastActiveDesignView" konnte ich zwar herausfinden welche Ansichtsdarstellung zuletzt aktiv war, aber konnte das beim Öffnen der Datei leider nicht einbinden.

-Beim Suchen in der Programmierungshilfe habe ich auch sowas wie "kLastactiveDesignView" gefunden mit dem Wert "57351" und auch bestimmte "Enums"...da verließen sie mich dann aber völlig.

Ich komme also an dieser Stelle nicht mehr weiter und hoffe Ihr könnt mir helfen.
Vielen Dank schon mal im Voraus.

Gruß
DB

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Hallo DB,

in der Zwischenzeit könnt ihr ja in den Anwendungsoptionen/Datei/Datei öffnen Optionen das Gewünschte einstellen.

------------------
Gruß Lothar

-----------------------------------------------------
Wir unterstützen die Arbeit der
- Rettungshundestaffel des DRK Viersen

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Hi Lothar,

zuerst vielen Dank für die schnelle Antwort.
Dieser Punkt war mir neu. Aber leider muss ich Dir sagen, dass die Baugruppe immernoch in der "Hauptansicht" geöffnet wird.
Der Punkt stand bei mir auch schon auf "zuletzt aktive". Das hat leider nicht geholfen.

Gruß
DB

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Hallo ?,

Code:

---

Public Sub OpenAssyInLastActiveState()
   
    Dim strFullFileName As String
    strFullFileName = "D:\InventorData15\LambdaSpect\Test1.iam"
       
    Dim oFileManager As FileManager
    Set oFileManager = ThisApplication.FileManager
   
    Dim strLastActiveDesignView As String
    strLastActiveDesignView = oFileManager.GetLastActiveDesignViewRepresentation(strFullFileName)
   
    Dim oDocOpenOptions As NameValueMap
    Set oDocOpenOptions = ThisApplication.TransientObjects.CreateNameValueMap
   
    Call oDocOpenOptions.Add("DesignViewRepresentation", strLastActiveDesignView)
   
    ' genau gleich geht es auch mit LOD + PosDarstellung
'    Call oDocOpenOptions.Add("LevelOfDetailRepresentation", hierStringFuerLetztenLOD)
'    Call oDocOpenOptions.Add("PositionalRepresentation", hierStringFuerLetztePosDarstellung)

    Dim oDoc As AssemblyDocument
    Set oDoc = ThisApplication.Documents.OpenWithOptions(strFullFileName, oDocOpenOptions, True)

End Sub

---

HTH

------------------
Grüsse, Paul

Inventor-Programmierung, Inventor-Tools und Inventor API-Schulung

Meine Tochter auf Youtube

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Hallo Paul,

das war es. Genau das habe ich gesucht. Funktioniert super.

Vielen Dank. Unities folgen sofort...

Gruß
DB

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP