---

Wir sortieren unsere Stücklisten in der IDW immer nach denselben Feldern. Leider hat diese Funktion immer noch kein Hirn und speicher die Einstellung nicht. Kann man da etwas in VBA machen?

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Hallo

Ja es gibt in der API eine PartsList.Sort Methode. Probiers mal so:

Code:

---

Private Sub PartsListTest()

Dim oDoc As DrawingDocument
Set oDoc = ThisApplication.ActiveDocument

Dim oPartsList As PartsList
Set oPartsList = oDoc.ActiveSheet.PartsLists.Item(1)

'die Werte in der Klammer natürlich entsprechend ersetzen.
Call oPartsList.Sort(PrimaryColumnTitle As String, ByRef PrimaryColumnAscending As [defaultvalue(-1)] Boolean, ByRef SecondaryColumnTitle As [defaultvalue("")] String, ByRef SecondaryColumnAscending As [defaultvalue(-1)] Boolean, ByRef TertiaryColumnTitle As [defaultvalue("")] String, ByRef TertiaryColumnAscending As [defaultvalue(-1)] Boolean)

End Sub

---

------------------
MfG
RK

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Super! Mit dem Tip konnte ich doch tatsächlich etwas beheben, das uns seit Jahren nervt.

Mein Makro im Moment:
---
Public Sub PartsListSort()

Dim oDoc As DrawingDocument
Set oDoc = ThisApplication.ActiveDocument

Dim oPartsList As PartsList
Set oPartsList = oDoc.ActiveSheet.PartsLists.Item(1)

Dim sPartsListSortString1 As String
    sPartsListSortString1 = "Norm"
Dim sPartsListSortString2 As String
    sPartsListSortString2 = "Artikel"
Dim sPartsListSortString3 As String
    sPartsListSortString3 = "Bem. /Lieferant"
   
Call oPartsList.Sort(sPartsListSortString1, True, sPartsListSortString2, True, sPartsListSortString3, True)

Call oPartsList.Renumber

End Sub
---

Ich habe nun gesehen, dass man per API ahnscheinend auch den Stücklistenstil auswählen kann. Kann ich per PartsList.Style den Stil umschalten? Und wenn ja wie?

Gibts ein gutes Lehrmittel für VBA im allgemeinen, ich habe manchmal wirklich Probleme die API Referenz zu verstehen.

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Hallo

Meines Wissens muß die Umstellung in der BOM der Baugruppe erfolgen. Teste mal das hier:

Code:

---

Private Sub SwitchBOMStructure()

Dim oAssDoc As AssemblyDocument
Dim oDrawDoc As DrawingDocument
Dim oPartsList As PartsList

Set oDrawDoc = ThisApplication.ActiveDocument
Set oPartsList = oDrawDoc.ActiveSheet.PartsLists(1)
If oPartsList.ReferencedDocumentDescriptor.ReferencedDocumentType = DocumentTypeEnum.kAssemblyDocumentObject Then
    Set oAssDoc = oPartsList.ReferencedDocumentDescriptor.ReferencedDocument
    If oAssDoc.ComponentDefinition.BOM.StructuredViewEnabled = False Then
        oAssDoc.ComponentDefinition.BOM.StructuredViewEnabled = True
    End If
    If oAssDoc.ComponentDefinition.BOM.StructuredViewFirstLevelOnly = True Then
        oAssDoc.ComponentDefinition.BOM.StructuredViewFirstLevelOnly = False
        MsgBox ("Die Stücklistenstruktur der Baugruppe wurde auf 'alle Ebenen' umgestellt.")
    Else
        oAssDoc.ComponentDefinition.BOM.StructuredViewFirstLevelOnly = True
        MsgBox ("Die Stücklistenstruktur der Baugruppe wurde auf 'nur Bauteile' umgestellt.")
    End If
End If
End Sub

---

Lehrmittel im Sinne von Büchern ect. speziell für Inventor gibt es nicht. Für VBA gibt's Tutorials im Internet, die man durcharbeiten kann, um die Basics zu lernen. Frag mal Google.
Immer hilfreich sind Breakpunkte und die Überwachung der Variablen. Notfalls mit F8 schrittweise durch den Code stapfen.
Im SDK-Ordner deiner Inventorinstallation gibt es noch eine Übersicht über das Inventor Objektmodell. Ich hatte das anfangs in A0 an der Wand hängen, da ich so schneller suchen konnte.

------------------
MfG
RK

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP