Hi Arpi....
Hab zu diesem Thema mal ein bißchen gewühlt....
Der folgende Code ist vollständig (beinhaltet also auch das speichern!):
Bei Bedarf mußt du Dir die benötigten Zeilen hier raus fischen und in deinen fertigen Code einbauen.
Viel Spaß.. Und Gruß aus Kiel .......
Andreas
++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
Private Sub DWGTEST()
'Aufruf der Funktion "Export2DWG" - Zeichnungsname ohne .dwg
Call Export2DWG("TestDWG", "C:\")
End Sub
++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
Public Function Export2DWG(ByVal strFN As String, ByVal strFP As String)
Dim oApp As Application
Set oApp = ThisApplication
Dim oDoc As DrawingDocument
Set oDoc = ThisApplication.ActiveDocument
Dim bSaveAsCopyOptions As Boolean
Dim oAppAddIns As ApplicationAddIns
Dim oDataMedium As DataMedium
Dim oDWGTransl As TranslatorAddIn
Dim oTransObjs As TransientObjects
Dim oTranslCntxt As TranslationContext
Dim oNameValMap As NameValueMap
Dim intIndex As Integer
Set oAppAddIns = oApp.ApplicationAddIns
For intIndex = 1 To oAppAddIns.Count
If oAppAddIns(intIndex).ShortDisplayName = "Autodesk DWG-Translator" Then
Set oDWGTransl = oAppAddIns.Item(intIndex)
Exit For
End If
Next intIndex
'Translation Objekte setzen
Set oTransObjs = oApp.TransientObjects
Set oNameValMap = oTransObjs.CreateNameValueMap
Set oTranslCntxt = oTransObjs.CreateTranslationContext
Set oDataMedium = oTransObjs.CreateDataMedium
oTranslCntxt.Type = kFileBrowseIOMechanism
bSaveAsCopyOptions = oDWGTransl.HasSaveCopyAsOptions(oDataMedium, oTranslCntxt, oNameValMap)
oDataMedium.FileName = strFP & strFN & ".dwg"
'Hier Pfad und Dateiname angeben wo die .ini Datei sich befindet!!!
oNameValMap.Value("Export_Acad_IniFile") = "c:\test.ini"
oDWGTransl.SaveCopyAs oDoc, oTranslCntxt, oNameValMap, oDataMedium
Set oAppAddIns = Nothing
Set oDataMedium = Nothing
Set oDWGTransl = Nothing
Set oTransObjs = Nothing
Set oTranslCntxt = Nothing
Set oNameValMap = Nothing
End Function
+++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP